100  REM GENERAL PURPOSE REGISTER RTE-B VERIFICATION TEST 
110  REM
120  REM            SOURCE TAPE:   09601-18006
130  REM            ERS:         A-09601-18006-1
140  REM            LISTING:     A-09601-18006-2
150  REM
200  PRINT  
210  PRINT "GENERAL PURPOSE REGISTER RTE-BASIC VERIFICATION TEST" 
220  PRINT  
270  PRINT "MOUNT TEST CONNECTOR BEFORE BEGINNING"
320  PRINT  
1005  GOSUB 9000
1010  PRINT "**CHECKING SINGLE-BIT CALLS**" 
1020  FOR I=0 TO B-1
1030  GPRSB(U,2,I,1)
1040  GPRSB(U,0,I,S)
1050  IF S=1 THEN 1070
1060  PRINT "BIT ";I;" FAILED S/B FALSE, IS TRUE" 
1070  GPRSB(U,2,I,0)
1080  GPRSB(U,0,I,S)
1090  IF S=0 THEN 1110
1100  PRINT "BIT ";I;" FAILED S/B TRUE,  IS FALSE"
1110  NEXT I
1200  PRINT "**CHECKING BCD OUTPUT/INPUT USING GPRMB**" 
1201  IF B=16 THEN 1205 
1202  PRINT "DECIMAL VALUES (0-99), USE 0 TO STOP"
1203  GOTO 1210 
1205  PRINT "DECIMAL VALUES (0-9999) , USE 0 TO STOP" 
1210  PRINT "VALUE OUT";
1220  INPUT V1
1230  GPRMB(U,3,V1) 
1240  GPRMB(U,2,V2) 
1250  PRINT "VALUE IN="V2 
1260  IF V1=0 THEN 1300 
1270  GOTO 1210 
1300  PRINT "**CHECKING BCD OUTPUT/INPUT USING GPRIO**" 
1301  IF B=16 THEN 1305 
1302  PRINT "DECIMAL VALUES (0-99), USE 0 TO STOP"
1303  GOTO 1310 
1305  PRINT "DECIMAL VALUES (0-9999) , USE 0 TO STOP" 
1310  PRINT "VALUE OUT";
1320  INPUT V1
1330  GPRIO(U,3,V1,V2)
1340  PRINT "VALUE IN=";V2
1350  IF V1=0 THEN 1400 
1360  GOTO 1310 
1390  LET K=1 
1400  PRINT "**CHECKING WORD OUT/IN USING GPRMB**"
1410  FOR I=0 TO B-1
1420  LET K=2^I 
1430  GPRMB(U,1,K)
1440  GPRMB(U,0,L)
1450  IF K=L THEN 1470
1460  PRINT "ERROR, VALUE OUT = ";OCT(K);" VALUE IN= ";OCT(L);" OCTAL"
1470  NEXT I
1500  PRINT "**CHECKING WORD OUT/IN USING GPRIO**"
1510  FOR I=0 TO B-1
1520  LET K=2^I 
1530  GPRIO(U,0,K,L)
1550  IF K=L THEN 1570
1560  PRINT "ERROR, VALUE OUT = ";OCT(K);" VALUE IN= ";OCT(L);" OCTAL"
1570  NEXT I
1600  GOTO 1005 
9000  PRINT 
9005  PRINT "UNIT NUMBER";
9010  INPUT U 
9015  IF U=0 THEN 9100
9020  PRINT "8 OR 16-BIT CARD"; 
9030  INPUT B 
9040  IF B=8 OR B=16 THEN 9060
9050  GOTO 9020 
9060  RETURN  
9100  PRINT 
9110  PRINT "END OF TEST" 
9120  STOP  
9130  END 
                                                                                            