ASMB,R,L,C
      NAM LUDV,7 09580-16020 REV.A 770101 
* 
*---------------------------------------------------------------
* 
*     RELOC.     09580-16020
*     SOURCE     09580-18020
* 
*     M.KAESSNER    REV.A   770101
* 
*     HP 92425A TEST SYSTEM SOFTWARE IS THE PROPRIETARY 
*     MATERIAL OF THE HEWLETT-PACKARD COMPANY.  USE AND 
*     DISCLOSURE THEREOF ARE RESTRICTED BY WRITTEN AGREEMENT. 
* 
*     (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977. 
*     ALL RIGHTS RESERVED.  NO PART OF THIS PROGRAM 
*     MAY BE PHOTOCOPIED, REPRODUCED OR TRANSLATED
*     TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR 
*     WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY. 
* 
*---------------------------------------------------------------
* 
* 
*     LUDV(STN,TYPE,NUMBER) 
*     LUDV(STN,TYPE)
* 
*                    WHERE  STN = STATION # (LUN OF CRT)
*                           TYPE= DEVICE TYPE 
*                           NUMB= UNIT NUMBER 
* 
*     RETURNS LUN OF DEVICE 
* 
*          THE DRTXX WORD CONTAINS    TYPE   IN BITS 15 - 7 
*                                     NUMBER IN BITS  6 - 3 
*                                     FAKE STN  BITS  2 - 0 
* 
* 
      ENT LUDV
      EXT DRTXX,.ENTR 
* 
A     EQU 0 
B     EQU 1 
* 
AISN  NOP 
ATYP  NOP 
ANUM  DEF D1        POINT TO DEFAULT VALUE
LUDV  NOP 
      JSB .ENTR 
      DEF AISN
      LDA AISN,I    .A. = LU OF CRT 
      SZA,RSS       LU=0 ?
      JMP NONE        YES! EXIT 
      SSA             NO, IS IT NEGATIVE? 
      JMP NONE        YES! EXIT 
      LDB DRTXX,I   CHECK IF LU > SIZE OF DRTXX 
      CMB,INB 
      ADB A 
      SSB,RSS 
      JMP NONE        GREATER THAN TABLE SIZE, EXIT!
      LDB DRTXX 
      ADB A         CREATE ADDRESS OF CRT'S ENTRY 
      LDA B,I       GET ENTRY 
      AND D7        GET PHONY STATION # FROM ENTRY
      LDB ATYP,I    GET TYPE #
      BLF 
      ADB ANUM,I    ADD IN UNIT NUMBER
      BLF,BRS       POSTION TYPE AND UNIT NUMBER
      ADB A         .B. CONTAINS WORD TO SEARCH FOR 
      SPC 2 
      LDA DRTXX     GET ADDRESS OF STARTING LOCATION
      STA ADDR
      CLA 
      SPC 1 
LOOP  INA           INCREMENT LUN COUNTER 
      CPA D64       DONE? 
      JMP NONE      YES,GET OUT -- NONE FOUND 
      ISZ ADDR      GET ADDRESS 
      CPB ADDR,I    FOUND IT? 
       JMP DONE     YES, GET OUT -- FOUND 
      JMP LOOP      NO, KEEP GOING
* 
NONE  CLA           NONE FOUND, RETURN ZERO 
DONE  LDB AD1       RESTORE 2ND PARM DEFAULT VALUE
      STB ANUM
      JMP LUDV,I
* 
AD1   DEF D1
D1    DEC 1 
D7    DEC 7 
D64   DEC 64
ADDR  BSS 1 
      END 
                                                                                                                                                        