ASMB,R,L
      NAM .XSB,6 XSB SYSTEM INDEPENDENT INSTRUCTION 780512 (DLB)
      ENT .XSB
      EXT .ZPRV 
      SPC 1 
BPA3  EQU 1744B     FWA OF DISC RESIDENT BASE PAGE FOR DMS SYSTEMS
XSB   OCT 105725
      SPC 1 
*  PURPOSE: 
*   THIS CODE WILL ALLOW PROGRAMS THAT GENERALLY WILL GO AFTER
*   DATA THAT IS IN A SYSTEM MAP FOR RTE-IV SYSTEMS, BUT ALLOW
*   THE SAME PROGRAMS TO WORK IN AN RTE-III & RTE-II SYSTEM.
      SPC 1 
.TMP1 NOP 
.TMP2 NOP 
      SPC 1 
.XSB  NOP           ENTRY TO EXECUTE THE XLA INSTRUCTION
      JSB .ZPRV 
      DEF LIBX
      STB .TMP1     SAVE B-REG CONTENTS 
      LDB O2        CHECK IF A MAPPING SYSTEM?
      CPB BPA3      (RTE-2?)
      JMP .XSB1     NO, MUST BE A MAPPING SYSTEM
      LDB .XSB,I    GET OPERAND ADDRESS 
      STB .TMP2     SAVE IT 
      LDB .TMP1     RESTORE B-REG 
      STB .TMP2,I   AND PUT THE CONTENTS
      ISZ .XSB      BUMP TO P+2 RETURN
LIBX  JMP .XSB,I    AND EXIT
      DEF .XSB
      SPC 1 
.XSB1 LDB .XSB      GET P+1 ADDRESS 
      CMB,INB       DECREMENT WITHOUT DISTURBING
      CMB           THE E-REG 
      STB .XSB      AND PUT BACK P+0 ADDRESS
      LDB XSB       GET THE REAL INSTRUCTION
      STB .XSB,I    AND CHANGE THE JSB TO XSB 
      LDB .TMP1     RESTORE B-REG 
      JMP LIBX      AND GO EXECUTE THE INSTRUCTION
      SPC 1 
O2    OCT 2 
      END 
                                                                                                                                                            