ASMB,R,L
      NAM .XSA,6 XSA SYSTEM INDEPENDENT INSTRUCTION 780512 (DLB)
      ENT .XSA
      EXT .ZPRV 
      SPC 1 
BPA3  EQU 1744B     FWA OF DISC RESIDENT BASE PAGE FOR DMS SYSTEMS
XSA   OCT 101725
      SPC 1 
*  PURPOSE: 
*   THIS CODE WILL ALLOW PROGRAMS THAT GENERALLY WILL GO AFTER
*   DATA THAT IS IN A SYSTEM MAP FOR RTE-IV SYSTEMS, BUT ALLOW
*   THE SAME PROGRAMS TO WORK IN AN RTE-III & RTE-II SYSTEM.
      SPC 1 
.TMP1 NOP 
.TMP2 NOP 
      SPC 1 
.XSA  NOP           ENTRY TO EXECUTE THE XLA INSTRUCTION
      JSB .ZPRV 
      DEF LIBX
      STA .TMP1     SAVE A-REG CONTENTS 
      LDA O2        CHECK IF A MAPPING SYSTEM?
      CPA BPA3      (RTE-2?)
      JMP .XSA1     NO, MUST BE A MAPPING SYSTEM
      LDA .XSA,I    GET OPERAND ADDRESS 
      STA .TMP2     SAVE IT 
      LDA .TMP1     RESTORE A-REG 
      STA .TMP2,I   AND PUT THE CONTENTS
      ISZ .XSA      BUMP TO P+2 RETURN
LIBX  JMP .XSA,I    AND EXIT
      DEF .XSA
      SPC 1 
.XSA1 LDA .XSA      GET P+1 ADDRESS 
      CMA,INA       DECREMENT WITHOUT DISTURBING
      CMA           THE E-REG 
      STA .XSA      AND PUT BACK P+0 ADDRESS
      LDA XSA       GET THE REAL INSTRUCTION
      STA .XSA,I    AND CHANGE THE JSB TO XSA 
      LDA .TMP1     RESTORE A-REG 
      JMP LIBX      AND GO EXECUTE THE INSTRUCTION
      SPC 1 
O2    OCT 2 
      END 
                                                                                                                                                            