ASMB,R,L
      NAM .XLB,6 XLB SYSTEM INDEPENDENT INSTRUCTION 780417 (DLB)
      ENT .XLB
      EXT .ZPRV 
      SPC 1 
BPA3  EQU 1744B     FWA OF DISC RESIDENT BASE PAGE FOR DMS SYSTEMS
XLB   OCT 105724
      SPC 1 
*  PURPOSE: 
*   THIS CODE WILL ALLOW PROGRAMS THAT GENERALLY WILL GO AFTER
*   DATA THAT IS IN A SYSTEM MAP FOR RTE-IV SYSTEMS, BUT ALLOW
*   THE SAME PROGRAMS TO WORD IN AN RTE-III & RTE-II SYSTEM.
      SPC 1 
.TMP1 NOP 
.TMP2 NOP 
      SPC 1 
.XLB  NOP           ENTRY TO EXECUTE THE XLB INSTRUCTION
      JSB .ZPRV     MAKE CALLABLE FROM TYPE 6 CODE
      DEF LIBX
      STA .TMP1     SAVE A-REG CONTENTS 
      LDA O2        CHECK IF A MAPPING SYSTEM?
      CPA BPA3      (RTE-2?)
      JMP .XLB1     NO, MUST BE A MAPPING SYSTEM
      LDA .XLB,I    GET OPERAND ADDRESS 
      STA .TMP2     SAVE IT 
      LDA .TMP1     RESTORE A-REG 
      LDB .TMP2,I   AND GET THE CONTENTS
      ISZ .XLB      BUMP TO P+2 RETURN
LIBX  JMP .XLB,I    AND EXIT
      DEF .XLB
      SPC 1 
.XLB1 LDA .XLB      GET P+1 ADDRESS 
      CMA,INA       DECREMENT WITHOUT DISTURBING
      CMA           THE E-REG 
      STA .XLB      AND PUT BACK P+0 ADDRESS
      LDA XLB       GET THE REAL INSTRUCTION
      STA .XLB,I    AND CHANGE THE JSB TO XLB 
      LDA .TMP1     RESTORE A-REG 
      JMP LIBX      AND GO EXECUTE THE INSTRUCTION
      SPC 1 
O2    OCT 2 
      END 
                                                                                                                          