ASMB,R,L,C
      HED "GTSTB" ROUTINE TO GET SESSION TABLE ENTRY 5-78 (DLB) 
      NAM GTSTB,6 PRE-REL 780512 (DLB) 15:25
      ENT GTSTB 
      EXT .ENTP,.XLA,.XLB,.ZPRV 
      EXT TBLH#,TBLE# 
      SPC 1 
A     EQU 0 
B     EQU 1 
      SPC 1 
* PURPOSE:  TO GET THE SESSION TABLE ENTRY AND ADDRESS
*           GIVEN AN LU NUMBER
* 
* CALLED: 
*         JSB GTSTB 
*         DEF *+4 
*         DEF LU     LOGICAL UNIT OF SESSION
*         DEF PNAME  RETURNED 8 WORD BUFFER (SESSION ENTRY) 
*         DEF SYSAD  RETURNED SESSION TABLE ENTRY IN SYSTEM MAP 
*         <RETURN>   A-REG = 0 IF NO SESSION ENTRY
*                    A-REG BIT 15 = 1 IF TERMINAL DISABLED
      SPC 1 
LU    NOP 
PNAME NOP 
SYSAD NOP 
GTSTB NOP           ENTRY 
      JSB .ZPRV 
      DEF LIBX
      JSB .ENTP 
      DEF LU
      JSB .XLB      GET THE STARTING ADDRESS OF SESSION TABLE 
      DEF TBLH#+0 
MORE  ADB O2        BUMP TO THE LU WORD 
      JSB .XLA      AND GET THE CONTENTS
      DEF B,I 
      AND O77       MASK TO JUST LU 
      CPA LU,I      CHECK IF SAME AS CALLERS? 
      JMP FOUND     YES, GOT IT 
      ADB O6        NO, BUMP TO NEXT ENTRY
      JSB .XLA      GET END ADDRESS OF SESSION TABLE
      DEF TBLE#+0 
      CPB A         CHECK IF END? 
      JMP MISSG     YES, EXIT NOT FOUND 
      JMP MORE      NO, CONTINUE
      SPC 1 
FOUND ADB OM2       BACK UP THE START ADDRESS 
      STB TABLE     SAVE THE STARTING TABLE ADDRESS 
      STB SYSAD,I   AND SEND BACK TO CALLER 
      JSB .XLA      GET 1ST WORD
      DEF B,I 
      STA SAVA      SAVE FOR EXIT 
      RAL,CLE,ERA   STRIP OFF BIT 15
      LDB DM8       GET COUNTER 
      JMP FOUN2 
FOUN1 JSB .XLA      GET NEXT WORD FROM TABLE
TABLE DEF * 
FOUN2 STA PNAME,I   AND SENT BACK TO CALLER 
      ISZ TABLE     BUMP TO NEXT WORD 
      ISZ PNAME 
      INB,SZB       CHECK IF END OF TABLE?
      JMP FOUN1     NO, CONTINUE
      LDA SAVA
LIBX  JMP GTSTB,I   AND RETURN
      DEF GTSTB 
      SPC 1 
MISSG CCA           ERROR RETURN
      STA PNAME,I   SET NAME BAD
      INA           SET E-REG AND EXIT A=0
      STA SYSAD,I   SET ADDRESS TO 0
      JMP LIBX      AND RETURN TO CALLER
      SPC 1 
O2    OCT 2 
O6    OCT 6 
O77   OCT 77
OM2   OCT -2
DM8   DEC -8
SAVA  NOP 
      END 
                                                                                                                                                                                                                                          