      JMP X21       NO SKIP EXPECTED
      ISZ A 
      HLT 0         ISZ A FAILED - DID NOT SKIP 
      SZA 
      HLT 0         ISZ FAILED - A NOT 0
      JMP X22         END OF LOOP 
X21   ISZ A 
      RSS 
      HLT 0         ISZ A FAILED - UNEXPECTED SKIP
      CPA B 
      JMP X20 
      HLT 0         ISZ A FAILED - BAD CONTENTS IN A
      JMP X20 
* 
      CLA 
      CLB 
X22   INA           A_A+1: NEXT EXPECTED B CONTENTS 
      SZA           EXPECT ISZ TO CAUSE SKIP IF 0 
      JMP X23       NO SKIP EXPECTED
      ISZ B 
      HLT 0         ISZ B FAILED - DID NOT SKIP 
      SZB 
      HLT 0         ISZ FAILED - B NOT 0
      JMP X24         END OF LOOP 
X23   ISZ B 
      RSS 
      HLT 0         ISZ B FAILED - UNEXPECTED SKIP
      CPB A 
      JMP X22 
      HLT 0         ISZ B FAILED - BAD CONTENTS IN B
      JMP X22 
* 
X24   LDA EVEN1 
      CPA A 
      RSS 
      HLT 0         CPA A FAILED
* 
      LDB ODD1
      CPB B 
      RSS 
      HLT 0         CPB B FAILED
* 
      LDA ODD1
      LDA A 
      CPA A 
      RSS 
      HLT 0         LDA A/CPA A FAILED
* 
      LDB EVEN1 
      LDB B 
      CPB B 
      RSS 
      HLT 0         LDB B/CPB B FAILED
* 
      CCA 
      STA A 
      CPA M1
      RSS 
      HLT 0         STA A FAILED
* 
      LDB ODD1
      STB B 
      CPB ODD1
      RSS 
      HLT 0         STB B FAILED
* 
      LDA EVEN1 
      ADA A         052525 + 052525 = 125252
      CPA ODD1
      RSS 
      HLT 0         ADA A FAILED
* 
      LDB ODD1      125252 + 125252 = 052524
      ADB B 
      CPB K1
      RSS 
      HLT 0         ADB B FAILED
* 
      CCA 
      IOR A 
      CPA M1
      RSS 
      HLT 0         IOR A FAILED
* 
      CCA 
      AND A 
      CPA M1
      RSS 
      HLT 0         AND A FAILED
* 
      CCA 
      XOR A 
      SZA 
      HLT 0         XOR A FAILED
* 
      NOP ***** MODULE LOOP 
      HED E AND OV REGISTER CHECKS
      CLE 
      SEZ 
      HLT 0         CLE/SEZ FAILED
* 
      CLE 
      SEZ,RSS 
      RSS 
      HLT 0         CLE/SEZ,RSS/RSS FAILED
* 
      CCE 
      SEZ,RSS 
      HLT 0         CCE/SEZ,RSS FAILED
* 
      CCE 
      SEZ 
      RSS 
      HLT 0         CCE/SEZ/RSS FAILED
* 
      CLO 
      SOC 
      HLT 0         CLO/SOC FAILED
* 
      CLO 
      SOS 
      RSS 
      HLT 0         CLO/SOS/RSS FAILED
* 
      STO 
      SOS 
      HLT 0         STO/SOS FAILED
* 
      STO 
      SOC 
      RSS 
      HLT 0         STO/SOC/RSS FAILED
* 
      STO 
      SOS C 
      HLT 0         STO/SOS C FAILED
      SOC 
      HLT 0         SOS,C DID NOT CLEAR OV
* 
* CHECK E & OV RESULTS FOR ADA INSTRUCTION
* 
      CLE 
      CLO 
      LDA PMAX      ADD 077777 + 000001 
      ADA .1
      CPA BIT15 
      RSS 
      HLT 0         SUM NOT 100000
      SEZ 
      HLT 0         E NOT 0 
      SOS 
      HLT 0         OV NOT 1
* 
      CLE 
      CLO 
      LDA M1        ADD 177777 + 177777 
      ADA M1
      CPA M2
      RSS 
      HLT 0         SUM NOT 177776
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOC 
      HLT 0         OV NOT 0
* 
      CLE 
      CLO 
      LDA M1        ADD 177777 + 000001 
      ADA .1
      SZA 
      HLT 0         SUM NOT 000000
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOC 
      HLT 0         OV NOT 0
* 
      CLE 
      CLO 
      CLA 
      ADA .0        ADD 000000 + 000000 
      SZA 
      HLT 0         SUM NOT 000000
      SEZ 
      HLT 0         E NOT 0 
      SOC 
      HLT 0         OV NOT 0
* 
      CLE 
      CLO 
      LDA PMAX      ADD 077777 + 0777777
      ADA PMAX
      CPA M2
      RSS 
      HLT 0         SUM NOT 177776
      SEZ 
      HLT 0         E NOT 0 
      SOS 
      HLT 0         OV NOT 1
* 
      CLE 
      CLO 
      LDA BIT15     ADD 100000 + 100000 
      ADA BIT15 
      SZA 
      HLT 0         SUM NOT 000000
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOS 
      HLT 0         OV NOT 1
* 
      CLE 
      CLO 
      LDA BIT15     ADD 100000 + 077777 
      ADA PMAX
      CPA M1
      RSS 
      HLT 0         SUM NOT 177777
      SEZ 
      HLT 0         E NOT 0 
      SOC 
      HLT 0         OV NOT 0
* 
      CCE           E _ 1 
      STO           OV _ 1
      LDA .1
      ADA .1
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOS 
      HLT 0         OV NOT 1
* 
* CHECK E & OV RESULTS FOR ADB INSTRUCTION
* 
      CLE 
      CLO 
      CLB 
      ADB .0        ADD 000000 + 000000 
      SZB 
      HLT 0         SUM NOT 000000
      SEZ 
      HLT 0         E NOT 0 
      SOC 
      HLT 0         OV NOT 0
* 
      CLE 
      CLO 
      LDB PMAX      ADD 077777 + 077777 
      ADB PMAX
      CPB M2
      RSS 
      HLT 0         SUM NOT 177776
      SEZ 
      HLT 0         E NOT 0 
      SOS 
      HLT 0         OV NOT 1
* 
      CLE 
      CLO 
      LDB PMAX      ADD 077777 + 000001 
      ADB .1
      CPB BIT15 
      RSS 
      HLT 0         SUM NOT 100000
      SEZ 
      HLT 0         E NOT 0 
      SOS 
      HLT 0         OV NOT 1
* 
      CLE 
      CLO 
      LDB M1        ADD 177777 + 177777 
      ADB M1
      CPB M2
      RSS 
      HLT 0         SUM NOT 177776
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOC 
      HLT 0         OV NOT 0
* 
      CLE 
      CLO 
      LDB M1        ADD 177777 + 000001 
      ADB .1
      SZB 
      HLT 0         SUM NOT 000000
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOC 
      HLT 0         OV NOT 0
* 
      CLE 
      CLO 
      LDB BIT15     ADD 100000 + 100000 
      ADB BIT15 
      SZB 
      HLT 0         SUM NOT 000000
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOS 
      HLT 0         OV NOT 1
* 
      CLE 
      CLO 
      LDB BIT15     ADD 100000 + 077777 
      ADB PMAX
      CPB M1
      RSS 
      HLT 0         SUM NOT 177777
      SEZ 
      HLT 0         E NOT 0 
      SOC 
      HLT 0         OV NOT 0
* 
      CCE           E _ 1 
      STO           OV _ 1
      LDB .1
      ADB .1
      SEZ,RSS 
      HLT 0         E NOT 1 
      SOS 
      HLT 0         OV NOT 1
* 
      NOP ***** MODULE LOOP 
      HED INDIRECT ADDRESSING TESTS 
* CHECK JMP INDIRECT
* 
      JMP IA1,I     IA1 = DEF IR1 
      HLT 0         JMP,I FAILED - 1 INDIRECT LEVEL 
* 
IR1   JMP IA2,I 
      HLT 0         JMP,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK JSB INDIRECT
* 
IR2   CLA 
      STA RA3       RA3 _ NOP 
      JSB IA3,I     IA3 = DEF RA3 
      HLT 0         JSB,I FAILED - 1 INDIRECT LEVEL 
RA3   NOP 
      LDA RA3 
      CPA ADDR2     ADDR2 = DEF RA3-1 
      RSS 
      HLT 0         JSB,I FAILED - BAD RETURN ADDR. 
* 
      CLA 
      STA RA4       RA4 _ NOP 
      JSB IA4,I 
      HLT 0         JSB,I FAILED - 2 INDIRECT LEVELS
RA4   NOP 
      LDA RA4 
      CPA ADDRY     ADDRY = DEF RA4-1 
      RSS 
      HLT 0         JSB,I FAILED - BAD RETURN ADDR. 
* 
* CHECK LDA INDIRECT
* 
      CLA 
      LDA IA5,I     IA5 = DEF M1,  M1 = 177777
      CPA M1
      RSS 
      HLT 0         LDA,I FAILED - 1 INDIRECT LEVEL 
* 
      CLA 
      LDA IA6,I     IA6 = DEF IA5,I 
      CPA M1
      RSS 
      HLT 0         LDA,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK LDB INDIRECT
* 
      CLB 
      LDB IA5,I     IA5 = DEF M1, M1 = 177777 
      CPB M1
      RSS 
      HLT 0         LDB,I FAILED - 1 INDIRECT LEVEL 
* 
      CLB 
      LDB IA6,I     IA6 = DEF IA5,I 
      CPB M1
      RSS 
      HLT 0         LDB,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK CPA INDIRECT
* 
      LDA EVEN1     EVEN1 = 052525
      CPA IA7,I     IA7 = DEF EVEN1 
      RSS 
      HLT 0         CPA,I FAILED - 1 INDIRECT LEVEL 
* 
      LDA EVEN1 
      CPA IA8,I     IA8 = DEF IA7,I 
      RSS 
      HLT 0         CPA,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK CPB INDIRECT
* 
      LDB EVEN1     EVEN1 = 052525
      CPB IA7,I     IA7 = DEF EVEN1 
      RSS 
      HLT 0         CPB,I FAILED - 1 INDIRECT LEVEL 
* 
      LDB EVEN1 
      CPB IA8,I     IA8 = DEF IA7,I 
      RSS 
      HLT 0         CPB,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK STA INDIRECT
* 
      CCA           A _ 177777
      STA IA9,I     IA9 = DEF T1
      CPA T1
      RSS 
      HLT 0         STA,I FAILED - 1 INDIRECT LEVEL 
* 
      CLA           A _ 000000
      STA IA10,I    IA10 = DEF IA9,I
      CPA T1
      RSS 
      HLT 0         STA,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK STB INDIRECT
* 
      CCB           B _ 177777
      STB IA9,I     IA9 = DEF T1
      CPB T1
      RSS 
      HLT 0         STB,I FAILED - 1 INDIRECT LEVEL 
* 
      CLB           B _ 000000
      STB IA10,I    IA9 = DEF T1
      CPB T1
      RSS 
      HLT 0         STB,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK ADA INDIRECT
* 
      LDA EVEN1     EVEN1 = 052525
      ADA IA7,I     IA7 = DEF EVEN1 
      CPA ODD1      EXPECT A = 125252 
      RSS 
      HLT 0         ADA,I FAILED - 1 INDIRECT LEVEL 
* 
      LDA EVEN1 
      ADA IA8,I     IA8 = DEF IA7,I 
      CPA ODD1
      RSS 
      HLT 0         ADA,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK ADB INDIRECT
* 
      LDB EVEN1     EVEN1 = 052525
      ADB IA7,I     IA7 = DEF EVEN1 
      CPB ODD1      EXPECT B = 125252 
      RSS 
      HLT 0         ADB,I FAILED - 1 INDIRECT LEVEL 
* 
      LDB EVEN1 
      ADB IA8,I     IA8 = DEF IA7,I 
      CPB ODD1
      RSS 
      HLT 0         ADB,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK AND INDIRECT
* 
      CCA 
      AND IA7,I     IA7 = DEF EVEN1 
      CPA EVEN1 
      RSS 
      HLT 0         AND,I FAILED - 1 INDIRECT LEVEL 
* 
      CCA 
      AND IA8,I     IA8 = DEF EVEN1 
      CPA EVEN1 
      RSS 
      HLT 0         AND,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK IOR INDIRECT
* 
      CLA 
      IOR IA7,I     IA7 = DEF EVEN1 
      CPA EVEN1 
      RSS 
      HLT 0         IOR,I FAILED - 1 INDIRECT LEVEL 
* 
      CLA 
      IOR IA8,I     IA8 = DEF IA7,I 
      CPA EVEN1 
      RSS 
      HLT 0         IOR,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK XOR INDIRECT
* 
      CCA 
      XOR IA7,I     IA7 = DEF EVEN1 
      CPA ODD1
      RSS 
      HLT 0         XOR,I FAILED - 1 INDIRECT LEVEL 
* 
      CCA 
      XOR IA8,I     IA8 = DEF IA7,I 
      CPA ODD1
      RSS 
      HLT 0         XOR,I FAILED - 2 INDIRECT LEVELS
* 
* CHECK ISZ INDIRECT
* 
      CCA 
      STA T1        T1 _ 177777 
      ISZ IA9,I     IA9 = DEF T1
      HLT 0         ISZ,I FAILED - 1 INDIRECT LEVEL 
      LDA T1
      SZA 
      HLT 0         ISZ,I FAILED - 1 INDIRECT LEVEL 
* 
      CCA 
      STA T1        T1 _ 177777 
      ISZ IA10,I    IA10 = DEF IA9,I
      HLT 0         ISZ,I FAILED - 2 INDIRECT LEVELS
      LDA T1
      SZA 
      HLT 0         ISZ,I FAILED - 2 INDIRECT LEVELS
* 
      NOP ***** MODULE LOOP 
      HED INDIRECT ADDRESSING TO PAGE 1 
      LDA .P1,I     .P1 = DEF TBL.1,  TBL.1 = 015366
      CPA K10       K10 = 015366
      RSS 
      HLT 0         LDA,I FAILED
* 
      LDB .P2,I     .P2 = DEF TBL.2,  TBL.2 = 051463
      CPB K11       K11 = 051463
      RSS 
      HLT 0         LDB,I FAILED
* 
      LDA K11       K11 = 051463
      CPA .P2,I     .P2 = DEF TBL.2,  TBL.2 = 051463
      RSS 
      HLT 0         CPA,I FAILED
* 
      LDB K10       K10 = 015366
      CPB .P1,I     .P1 = DEF TBL.1,  TBL.1 = 015366
      RSS 
      HLT 0         CPB,I FAILED
* 
      CCA 
      STA T2A,I     T2A = DEF T2
              