########## TRANSYLVANIA TAPE PRINT, 1401 SOURCE                                 
01010          JOB  TRANSYLVANIA TAPE PRINT - PRINT LEGEND                 TRANS
01020          CTL  6611                                                   TRANS
01030          INDEX                                                       TRANS
01040          ORG  2700                                                   TRANS
01050TAPE      DA   1X11200,G                                              TRANS
01060INT       CC   1                                                      TRANS
01070          SBR  X1,LINE                                                TRANS
01080MOVE      BCE  OVLAY,0&X1,&                                           TRANS
01090          MCM  0&X1,201                                               TRANS
01100          SAR  X2                                                     TRANS
01110          MCM  0&X1,201                                               TRANS
01120          MCW  @  @                                                   TRANS
01130          WCSCS,,,260                                                 TRANS
01140          MCW  X2,X1                                                  TRANS
01150          B    MOVE                                                   TRANS
01160OVLAY     CC   1                                                      TRANS
01170          OVLAY                                                       TRANS
01180LINE      EQU  *&1                                                    TRANS
01190          DCW  @         TRANSYLVANIA TAPE PRINT\@                    TRANS
01191          DCW  @\@                                                    TRANS
01200          DCW  @          SWITCH- ACTION IF ON\@                      TRANS
01210          DCW  @            A   - SELECT DRIVE 1\@                    TRANS
01220          DCW  @            B   -              2\@                    TRANS
01230          DCW  @            C   -              3\@                    TRANS
01240          DCW  @            D   -              4\@                    TRANS
01250          DCW  @            E   -              5\@                    TRANS
01260          DCW  @            F   - SKIP FORWARD\@                      TRANS
01270          DCW  @            G   - BACKSPACE\@                         TRANS
01271          DCW  @\@                                                    TRANS
01280          DCW  @NOTE -1. TO LABEL PRINTOUT, LOAD PROGRAM & CARD\@          
01290          DCW  @TO BE LISTED 80-80, WITH G ON. SET SWITCHES AS \@     TRANS
01300          DCW  @INDICATED ABOVE WHEN LABEL MESSAGE APPEARS.\@         TRANS
01310          DCW  @      2. PROGRAM STOPS IF A THRU E ARE OFF.\@         TRANS
01320          DCW  @      3. READER MUST BE EMPTY TO SELECT DRIVE 1.\@    TRANS
02100          DCW  @&&&&@                                                 TRANS
02101          LTORG*                                                      TRANS
02110          EX   INT                                                    TRANS
02120          JOB  TRANSYLVANIA MAIN SECTION                              TRANS
02130          ORG  INT                                                    TRANS
02131BEGIN     H                                                           TRANS
02160          BSS  *&5,G                                                  TRANS
0217081        DCW  @!@                                                    TRANS
02180          B    DS                                                     TRANS
02181          R                                                           TRANS
02200          WCSCSA,,@ TURN G OFF. LABEL HAS BEEN READ.@,236             TRANS
02201          H                                                           TRANS
03010DS        BSS  CHOOSE,A           DRIVE SELECTOR                      TRANS
03020          DCW  @N1@                                                   TRANS
03030          BSS  CHOOSE,B                                               TRANS
03040          DCW  @N2@                                                   TRANS
03050          BSS  CHOOSE,C                                               TRANS
03060          DCW  @N3@                                                   TRANS
03070          BSS  CHOOSE,D                                               TRANS
03080          DCW  @N4@                                                   TRANS
03090          BSS  CHOOSE,E                                               TRANS
03100          DCW  @N5@                                                   TRANS
03110          H    DS                                                     TRANS
03120CHOOSE    SBR  X3                                                     TRANS
03130          MN   1&X3,DRIVE#1                                           TRANS
03140          C    DRIVE,OLD#1        ARE DRIVES SWITCHED.                TRANS
03150          BE   AF2                                                    TRANS
03160          MN   DRIVE,OLD                                              TRANS
03170          CC   1                                                      TRANS
03180          MN   DRIVE,208                                              TRANS
03190          MCW  @TAPE # @          LABEL NEW DUMP.                     TRANS
03200          MCM  1,210                                                  TRANS
04010          WCSCSS                                                      TRANS
04020          S    RECNT#5                                                TRANS
04030          MN   DRIVE,DNO                                              TRANS
04031          SBR  ENDLOC,*&9                                             TRANS
04040          B    CTAPE                                                  TRANS
04050          NOP  CALL                                                   TRANS
04051          SBR  ENDLOC,EOF                                             TRANS
04060          MN   DRIVE,*&4                                              TRANS
04070          BSP  0                                                      TRANS
04071          CW   TRL#1                                                  TRANS
04080          C    TAPE&3,@1HDR@      IS 1ST RECORD A HEADER.             TRANS
04090          BU   AF2                                                    TRANS
04100          SW   TRL                                                    TRANS
04110AF2       BSS  *&5,G                                                  TRANS
04120          B    AG2                                                    TRANS
04130          S    @1@,RECNT                                              TRANS
04140          MN   DRIVE,*&4                                              TRANS
04150          BSP  0                                                      TRANS
04151          BM   *&5,RECNT                                              TRANS
04152          B    DS                                                     TRANS
04153          S    RECNT                                                  TRANS
04160          B    DS                                                     TRANS
04170AG2       A    @1@,RECNT                                              TRANS
04180          B    CTAPE                                                  TRANS
04190          NOP  CALL                                                   TRANS
04200          BSS  DS,F               IS NO-PRINT SELECTED.               TRANS
05010          B    PS                 PRINT                               TRANS
05020EOF       WCSCS,,@TM@,202                                             TRANS
05021* IF THERE WAS AHEADER, PRINT TRAILER.                                TRANS
05022          BW   AJ3,TRL                                                TRANS
05030AH4       CC   J                  TRAILER.                            TRANS
05040          S    @1@,RECNT                                              TRANS
05041          MCW  @END OF FILE.@,212                                     TRANS
05042          MCS  RECNT,218                                              TRANS
05043          WCSCSA,,@RECORDS. HIT START TO CONTINUE.@,250               TRANS
05044          S    RECNT                                                  TRANS
05050          H    DS                                                     TRANS
05060AJ3       SBR  ENDLOC,*&9                                             TRANS
05061          B    CTAPE                                                  TRANS
05070          NOP  CALL                                                   TRANS
05071          SBR  ENDLOC,EOF                                             TRANS
05080          MN   DRIVE,*&4                                              TRANS
05090          BSP  0                                                      TRANS
05100          C    TAPE&2,@1EO@       IS RECORD AFTER TM A TRAILER.       TRANS
05110          BU   AH4                                                    TRANS
05120          SW   0&X2               IF SO PRINT.                        TRANS
05130          MCW  @*@,201                                                TRANS
05140          MCM  TAPE,202                                               TRANS
05150          CW   0&X2                                                   TRANS
05160          WCSCS,AH4                                                   TRANS
05170* PRINT SECTION                                                       TRANS
05180PS        SW   0&X2,FIRSTM#1      X2 HAS ADDR OF GM.                  TRANS
05190          MA   -TAPE,X2           DECODE BLOCK LENGTH.                TRANS
05200          MCW  @00000@,LENGTH#5                                       TRANS
06010          MN   X2,LENGTH                                              TRANS
06020          MN                                                          TRANS
06030          MN                                                          TRANS
06040          BWZ  NOUNIT,X2,2                                            TRANS
06050          BWZ  K4,X2,S                                                TRANS
06060          BWZ  K8,X2,K                                                TRANS
06070          A    @4@,LENGTH-3       4X3 FOR & ZONE                      TRANS
06080K8        A    @4@,LENGTH-3       4X2 FOR -                           TRANS
06090K4        A    @4@,LENGTH-3       4X1 FOR 0                           TRANS
06100NOUNIT    BWZ  NOHUN,X2-2,2       NOTHING FOR NO-ZONE                 TRANS
06110          BWZ  K1,X2-2,S                                              TRANS
06120          BWZ  K2,X2-2,K                                              TRANS
06130          A    @1@,LENGTH-3                                           TRANS
06140K2        A    @1@,LENGTH-3                                           TRANS
06150K1        A    @1@,LENGTH-3                                           TRANS
06160NOHUN     SBR  X1,TAPE            INITIALIZE TAPE ADDRESS             TRANS
06161* THIS THE MAIN PRINT-OUT LOOP                                        TRANS
06170BC1       MCW  NPC,302            SET TEST CHARACTERS                 TRANS
06180          MCW  NPC,TAPE-1                                             TRANS
06200          MCW  @*@,201                                                TRANS
07010          MCM  0&X1,202      X1 CONTAINS ADDRESS OF NEXT LINE.        TRANS
07020          SAR  X2                                                     TRANS
07030          BCE  BE2,302,'                                              TRANS
07040          BCE  BH1,TAPE-1,'                                           TRANS
07050          CS   332                                                    TRANS
07060          CS                                                          TRANS
07070          MCW  @ RECORD GREATER THAN 2500 CHARACTERS.@,268            TRANS
07080          MCW  @PROGRAM CANNOT HANDLE A LOGICAL@                      TRANS
07090          WCSCSA                                                      TRANS
07100          H    DS                                                     TRANS
07110BH1       SW   GR100#1            RECORD GREATER THAN 100             TRANS
07120          MCW  B31#31,332                                             TRANS
07130          MA   @100@,X1           BUMP INDEX BY 100.                  TRANS
07140          B    BF2                                                    TRANS
07150BE2       CW   GR100              RECORD LQ 100.                      TRANS
07160          MCW  X2,X1              SET  INDEX NEXT ADDRESS.            TRANS
07170BF2       BW   *&5,FIRSTM         TEST 1ST LINE OF RECORD.            TRANS
07180          B    BG2                                                    TRANS
07190          CW   FIRSTM                                                 TRANS
07200          MCW  @RECD       HAS      CHARACTERS@,332                   TRANS
08010          MCS  RECNT,312                                              TRANS
08020          MCS  LENGTH,321                                             TRANS
08021BG2       BW   BJ2,GR100                                              TRANS
08030          BCE  BH3,0&X2,!         TEST FOR EOREC GM.                  TRANS
08040          BCE                                                         TRANS
08050BJ2       WCSCS,BC1               GO BACK FOR ANOTHER LINE            TRANS
08060BH3       CW   0&X2               CLEAR WM UNDER \< OR <B.            TRANS
08070          CW                                                          TRANS
08080          S    @101@,LENGTH                                           TRANS
08090          BM   BK4,LENGTH         SINGLE SPACE FOR SHORT RECORDS      TRANS
08100          CC   S                  DOUBLE SPACE AFTER LONG RECORDS.    TRANS
08110BK4       WCSCS,DS                                                    TRANS
08010CALL      DCW  @K@                                                    TRANS
08020          DCW  @49@                                                   TRANS
08021ENDLOC    DCW  EOF                ADDRESS OF EOF LOCATION.            TRANS
08030DNO       EQU  *&4                DRIVE #                             TRANS
08040          RT   0,TAPE                                                 TRANS
08060NPC       DCW  @'@                NON-PRINT CHAR '                    TRANS
01010*COMBINATION READ/WRITE ROUTINE                                            
01020*                                                                          
01030CTAPE     SBR  CCONPR&3                                                    
01040          MCW  99,CIDX                                                     
01050          SW   97                                                          
01060          MCW  CCONPR&3,99                                                 
01070          MCW  3&X3,CIR3          AND                                      
01080          MCW  13&X3,CTAPEC&7     READ/WRITE                               
01090          MCW  5&X3,CEORC&3       COMMAND                                  
01100          SW   CCOMPR&4                                                    
01110          MCW  12&X3,CCOMPR&6     NOISE RECORD                             
01120          MA   @012@,CCOMPR&6                                              
01130          CW   CCOMPR&4                                                    
01140          A    C1,0&X3            NOISE REC CNT                            
01150          MCW  C9,CERRCT                                                   
01160CTAPEC    MCW  %U0,0,R            DUMMY COMMAND                            
01170CSTORE    SBR  CCLEAR&6           STORE ADDR OF GM&1                       
01180* INSERT CARDS LABELED CSTA AND CSTB TO PUT ADDRESS OF GM IN XR2.          
04100CSTA      SBR  94                 SAVE ADDR OF GM FOR MAIN PROGR           
04110CSTB      MA   M1,94                                                       
01190* CARDS ARE INCLUDED AT END OF THIS ROUTINE.                               
01200          BCE  CORKS,CTAPEC&7,W   TEST COMMAND                             
01210          BEF  *&5                                                         
01220CEORC4    B    CCOMPR                                                      
01230          MCW  CIDX,CIR3                                                   
01240CEORC     B    *                                                           
01250CCOMPR    BCE  CCLEAR,*,!    D-MOD IS GROUP MARK.TEST FOR                  
02010          CHAIN12                                                          
02020CORKS     BER  CRWRED             ERROR TEST                               
02030          BEF  CEORC4&4                                                    
02040          MCW  CIDX,99                                                     
02050CCONPR    B    *                  CON PROGRAM                              
02060*COMBINATION READ/WRITE REDUNDANCY ROUTINE                                 
02070CRWRED    BCE  CADDRR,CERRCT,9                                             
02080CCONRR    S    C1,CERRCT          SUB 1 FROM ERROR COUNT                   
02090          MN   CTAPEC&3,*&4       BACKSPACE                                
02100          CU   %U0,B                                                       
02110          BCE  CTROW,CERRCT,G     BRANCH IF 2 WRITES                       
02120CTSTVC    BWZ  CCLEAN&4,CERRCT,K  BR IF 10 REREADS                         
02130          B    CTAPEC             READ/WRITE                               
02140CADDRR    BCE  CTSTTM,CTAPEC&7,R    IF WRITE                               
02150          S    C1,2&X3            SUB 1 FROM                               
02160          BWZ  CPERR2,2&X3,K      TOTAL ERRORS                             
02170          B    CCONRR                                                      
02180*STATISTICS                                                                
02190CTSTTM    S    C1,2&X3                                                     
02200          BWZ  CPERR1,2&X3,K                                               
02210          B    CCONRR                                                      
02220CCLEAR    MN   C1,CCLEAR&6        IF NOISE REC                             
02230          MN                      CLEAR GM                                 
02240          ZS   C1,0&X3            READ NEXT                                
02250          B    CTAPEC             RECORD                                   
03010CTROW     BCE  CTSTVC,CTAPEC&7,R     IF WRITE                              
03020          BEF  CHEOR              EOR TEST                                 
03030          MN   CTAPEC&3,*&4                                                
03040          CU   %U0,E              ERASE TAPE                               
03050CCLEAN    B    CTAPEC-7                                                    
03060*VACUUM CLEANING                                                           
03070          BWZ  CPERR0,0&X3,K      IF PERMANENT                             
03080CPERR0    MCW  CTAPEC&6,*&7       REREAD RECORD                            
03090          MCW  %U0,0,R                                                     
03100*FIFTY READ REDUNDANCIES                                                   
03110CPERR1    MCW  C49,2&X3           RESTORE COUNT                            
03120          NOP  50                 AFTER 50 READ                            
03130          H                       ERRORS AND                               
03140          B    CCONRR             HALT                                     
03150*30 WRITE REDUNDANCIES                                                     
03160CPERR2    MCW  C29,2&X3           RESTORE COUNT                            
03161          NOP  30                 AFTER 30 WRITE                           
03162          H                      ERRORS                                    
03170          B    CCONRR             ERROR HALT                               
03180*END OF REEL WHILE WRITING                                                 
03190CHEOR     MCW  C29,2&X3           RESTORE COUNT                            
03200          MN   CTAPEC&3,*&4       WRITE                                    
03210          CU   %U0,M              TAPE MARK                                
03220          NOP  888                                                         
03230          H                       HALT                                     
03240          B    CTAPEC-7                                                    
03250*CONSTANTS                                                                 
04010CIR3      EQU  99                                                          
040200099      DCW  #3                                                          
04030CERRCT    DCW  @9@                                                         
04040C1        DCW  @1@                                                         
04050C9        DCW  @9@                                                         
04060C49       DCW  @49@                                                        
04070C29       DCW  @2I@                                                        
04080CIDX      DCW  #3                                                          
04090M1        DSA  15999                                                       
08070          END  BEGIN                                                  TRANS
