               JOB  MOVE COMPARE                                           0200A
               ctl  6611
     *
     * Stuff in the preamble -- not in one-field-per-card format
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357bcont     b    cont
  361          cs   reload,80
  368          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
     *
     * Stuff that is in one-field-per-card format
     *
               ORG  377
  377          BIN  389,           USE WHEN TESTS ARE RUN FROM TAPE
               ORG  385
  385          b    taperd
  389switch    nop  0
  393          mcw  bcont&3,switch&3
  400BEGIN     CS   332            START TEST
  404          CS
  405          BCE  TITLPR,TITLSW,1  BR TO TITLE PRINT ROUTINE IF 1 IN S52
  413          CS   80             CLEAR READ AREA
  417repeat    B    detail         BRANCH TO PROGRAM CHAINING ROUTINE
  421cont      SW   1,78           LOAD PRINT AREA
  428          LCA  80,299           ,,
  435          LCA  72,272           ,,
  442          SW   241,270          ,,
  449SCOPE     MCW  210,270        MOVE OP WITH CHAINING
  456          MCW                   ,,
  457          BSS  SCOPE,B        B ON TO SCOPE
  462          CW   270            TEST FOR ERROR
  466          C    270,250          ,,
  473          BU   UNEQ           BRANCH TO ERROR PRINT ROUTINE IF UNEQ
  478          BSS  CORR,C         C ON TO CORRECT PRINT ROUTINE
  483          BIN  LOOP,          BRANCH TO SENSE D
               ORG  900
  900UNEQ      LCA  ERROR,285      BEGIN ERROR PRINT ROUTINE
  907          BSS  ERRHLT,E       E ON TO ERROR STOP
  912          W    LOOP           ERROR PRINT
  916ERRHLT    H    LOOP           ERROR STOP
  920          DCW  @                    @   WORD MARK
               ORG  950
  950CORR      LCA  BLANK,285      CORRECT PRINT ROUTINE
  957          W                     ,,
  958LOOP      BSS  cont,D         D ON TO REPEAT
  963          BIN  repeat,        BRANCH TO READ NEXT RECORD
               ORG  1110
 1110ERROR     DCW  @ERROR@        CONSTANTS
 1115BLANK     DCW  @     @          ,,
 1120          DCW  @A FIELD             @     ,,
 1140          DCW  @B FIELD             @     ,,
 1160          DCW  @RESULT SHOULD BE    @     ,,
 1180          DCW  @RESULT IS           @     ,,
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218          cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&69,270  Load second line.
 1236          w                 Print second line.
 1237          cs   270          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
               END  start
