               JOB  PRINT-PUNCH                                            1050A
               CTL  6611
     *
     * Stuff in the preamble -- not in one-field-per-card format
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348nxprog    r
  349tptest    bce  *&5,80,a
  357          b    421    What's going to be at 421?
  361          cs   reload,80
  368          dcw  #1
               ORG  400
  400          CS   332            START TEST
  404          CS
  405          LCA  bcont&4,titlp2&4  MODIFY TITLE PRINT TO SKIP HEADINGS
  412          BCE  titlpr,titlsw,1  BR TO TITLE PRINT ROUTINE IF 1 IN S52
  420cont      CW   d1&1,d2&1      EXPAND TABLE FROM 701-760 TO 701-820
  427          LCA  d3,d6            ,,
  434          CW   d3&1,d3&1        ,,
  441          CS   180            CLEAR PUNCH
  445          SW   101,201        SET WM IN PUNCH AND PRINT AREAS
  452repeat    LCA  first,count    LOAD 780 INTO CARD COUNTER
  459next      MCW  count,move1&3  MOVE CARD COUNTER INTO LOCATION 474-476
  466          MCW  count,move2&3  MOVE CARD COUNTER INTO LOCATION 481-483
  473move1     MCW  5777&X1,280    MOVE TABLE INTO PRINT AREA
  480move2     MCW  5777&X1,180    MOVE TABLE INTO PUNCH AREA
  487          BWZ  wpbr,101,2     BR TO PRINT-PUNCH & BR IF NO ZONE IN 101
  495scope     WP                  PRINT-PUNCH
  496          BSS  scope,B        B ON TO SCOPE
  501          B    test           BRANCH TO TEST FOR LAST CARD
  505wpbr      WP   btest          PRINT-PUNCH & BRANCH
  509          H                   ERROR STOP IF NO BRANCH
  510btest     BSS  wpbr,B         B ON TO SCOPE
  515test      C    last,count     COMPARE CARD COUNTER WITH 799
  522          BU   bump           BRANCH TO ADD 1 IF NOT 799
  527          BSS  repeat,D       D ON TO REPEAT TEST
  532          B    nxprog         BRANCH TO READ NEXT RECORD
  536bump      A    k1,count       ADD 1 TO CARD COUNTER
  543          BIN  next,          BRANCH TO PRINT-PUNCH NEXT CARD
               ORG  600
  600bcont     BIN  cont,          BRANCH INSTRUCTION TO MODIFY TITLE PRINT
  607first     DSA  d4             CONSTANT TO START CARD COUNTER
  608k1        dcw  1              CONSTANT TO INCREMENT CARD COUNTER
  611last      DSA  d5             CONSTANT TO STOP CARD COUNTER
  614count     DCW  @XXX@          CARD COUNTER
               ORG  701
  720d1        DCW  @AKT4 BLU5"CMV6 DNW7_@   TABLE TO BE PRINT-PUNCHED
  740d2        DCW  @EOX8 FPY9+GQZ0 HR'#(@     ,,
  760d3        DCW  @I-,@ &$%1?.*/2 )JS3!@     ,,
  780d4        ds   20
  799d5        ds   19
  820d6        ds   21
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218titlp2    cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&69,270  Load second line.
 1236          w                 Print second line.
 1237          cs   270          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
               org  titlsw
 1252          dcw  1
               end  start
