               JOB  RIPPLE PRINT                                           1020A
               ctl  6611
     *
     * Stuff in the preamble
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357bcont     b    cont&1  Cont is in a different place now
  361          cs   reload,80
  368          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
               org  377
  377          bce  switch,1261,1  USE WHEN TESTS ARE RUN FROM TAPE
  385          b    taperd
  389switch    nop  0
  393          mcw  bcont&3,switch&3
  400begin     cs   332
  404          cs
  405          lca  bcont2&4,1222  MODIFY TITLE PRINT TO SKIP HEADINGS
  412          bce  titlpr,titlsw,1  BR TO TITLE PRINT ROUTINE IF 1 IN S52
  420cont      cw   table-39,table-19  EXPAND TABLE 701-760 TO 701-940
  427          lca  table,tab2       ,,
  434          cw   table&1          ,,
  438          lca  tab2,tab5        ,,
  445          cw   tab2&1           ,,
  449          sw   201            SET WM IN PRINT AREA
  453repeat    lca  kbeg,lctr      LOAD LINE COUNTER
  460line      mcw  lctr,*&4       MOVE LINE CTR INTO NEXT INSTRUC
  467          mcw  tab3,332       MOVE TABLE INTO PRINT AREA
  474scope     w                   PRINT
  475          bss  scope,B        B ON TO SCOPE
  480          c    kend,lctr      COMPARE LINE COUNTER WITH 891
  487          bu   bump           BRANCH TO ADD 1 IF NOT 891
  492          bss  repeat,D       D ON TO REPEAT TEST
  497          b    detail         BRANCH TO READ NEXT RECORD
  501bump      a    k1,lctr        ADD 1 TO LINE COUNTER
  508          bin  line,          BRANCH TO PRINT NEXT LINE
     *
     * Constants and data areas
     *
               org  600
  600bcont2    bin  cont,          BRANCH INSTRUCTION TO MODIFY TITLE PRINT
  605kbeg      dsa  tab3           CONSTANT TO START LINE COUNTER
  608k1        dcw  1              CONSTANT TO INCREMENT LINE COUNTER
  609kend      dsa  tab4           CONSTANT TO STOP LINE COUNTER
  612lctr      dcw  @XXX@                    LINE COUNTER
               org  701
  701          dcw  @AKT4 BLU5 CMV6"DNW7 @   TABLE TO BE RIPPLE PRINTED
  721          dcw  @EOX8 FPY9_GQZ0 HR'# @     ,,
  741table     dcw  @I-,@+&$%1 .*/2 )JS3(@     ,,
     tab2      ds   60
     tab3      ds   12
     tab4      ds   59
     tab5      ds   49
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218          cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&69,270  Load second line.
 1236          w                 Print second line.
 1237          cs   270          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
               end  start
