               job  Edit                                                   0370D
               ctl  6611
     *
     * Skip tests with zone in 72 unless 1260 is 1.
     * Zone in 72 means "Test expanded print edit."
     * Otherwise run each test 90 times.
     *
     * Sense switches:
     * B on to repeat inner test -- for scoping
     * C on to print correct results
     * D on to repeat test without reading new detail
     * E on to halt on errors
     *
     * Halts: 920 in I-star and A-star if fail with E on.
     *
               org  333
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357bcont     b    cont
  361          cs   reload,80
  368          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
               org  377
  377          b    switch
               org  385
  385          b    taperd
  389switch    nop  0
  393          mcw  bcont&3,switch&3
  400begin     cs   332
  404          cs
  405          b    titlpr,titlsw,1
  413          cs   80
  417          b    detail
  421cont      sw   1,78
  428          lca  80,299
  435          lca  70,270
  442          b    move
  446          dc   #3
  449loop2     lca  237,277
  456          mce  208,277
  463          bss  scope,B
  468          c    277,257
  475          bu   errprt
  480          b    bump
  484test2     bwz  again,72,2
  492          bce  again,flag,1
  500          b    detail
  504again     sw   221,241
  511          b    loop2
  515          dcw  #1
               org  900
  900errprt    lca  error,287      BEGIN ERROR PRINT ROUTINE
  907          bss  errhlt,E       E ON TO ERROR STOP
  912          w    bump           ERROR PRINT
  916errhlt    h    bump           ERROR STOP
  920bump      a    *-6,count      Bump count
  927          bce  clear,count-1,9  Ninety times?
  935scope     cs   332
  939          cs
  940          b    cont
  944clear     s    count
  948          bss  corr,C
  953          b    loop
  957corr      w
  958loop      bss  cont,D
  963          b    detail
  970count     dcw  @000?@
  971move      sw   71
  975          mcw  72,281
  982          b    test2
  986          dcw  #1
               org  1110
 1114error     dcw  @ERROR@
 1119          dcw  @     @
 1139          dcw  @A FIELD             @
 1159          dcw  @B FIELD             @
 1179          dcw  @RESULT SHOULD BE    @
 1199          dcw  @RESULT IS           @
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218          cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&69,270  Load second line.
 1236          w                 Print second line.
 1237          cs   270          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
               org  1260
 1260flag      dc   1
               end  start
