               JOB  Branch Overflow                                        0360
               ctl  6611
     *
     * Stuff in the preamble
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357bcont     b    cont
  361          cs   reload,80
  368          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
               org  377
  377          b    switch
  381          dc   #4
  385          b    taperd
  389switch    nop  0
  393          mcw  bcont&3,switch&3
  400begin     cs   332
  404          cs
  405          bce  titlpr,titlsw,1
  413          cs   80
  417next      b    detail         BRANCH TO PROGRAM CHAINING ROUTINE
  421cont      sw   1,78           LOAD PRINT AREA
  428          lca  80,299           ,,
  435          lca  72,272           ,,
  442          sw   221              ,,
  446          bav  scope          RESET OVERFLOW LATCH
  451scope     lca  222,262        LOAD B FIELD
  458          a    202,262        ADD
  465          bav  ovfl           BRANCH IF OVERFLOW
  470          bss  scope,B        B ON TO SCOPE
  475          bce  test,6,N       NO ERROR IF N IN 006
  483          b    errprt         BRANCH TO ERROR PRINT ROUTINE
  487ovfl      bss  scope,B        B ON TO SCOPE
  492          bce  test,6,        NO ERROR IF BLANK IN 006
  500          b    errprt         BRANCH TO ERROR PRINT ROUTINE
  504test      bss  corr,C         C ON TO CORRECT PRINT ROUTINE
  509          b    loop           BRANCH TO SENSE D
               dc   #1
               org  900
 0900errprt    lca  error,285      BEGIN ERROR PRINT ROUTINE
 0907          bss  errhlt,E       E ON TO ERROR STOP
 0912          w    loop           ERROR PRINT
 0916errhlt    h    loop           ERROR STOP
 0939          dcw  #1             WORD MARK
               org  950
 0950corr      lca  blanks,285     CORRECT PRINT ROUTINE
 0957          w                     ,,
 0958loop      bss  cont,d         D ON TO REPEAT
 0963          bin  next,          BRANCH TO READ NEXT RECORD
               org  1110
 1114error     dcw  @ERROR@        CONSTANTS
 1119blanks    dcw  @     @          ,,
 1120          dcw  @A FIELD             @
 1140          dcw  @B FIELD             @
 1160          dcw  @RESULT SHOULD BE    @
 1180          dcw  @RESULT IS           @
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218          cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&69,270  Load second line.
 1236          w                 Print second line.
 1237          cs   270          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
               end  start
