               ctl  6611                                                   1060B
     *
     * Stuff in the preamble -- not in one-field-per-card format
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348nxprog    r
  349tptest    bce  *&5,80,a
  357          b    cont2
  361rel1      cs   reload,80
  368          dcw  #1
     *
     tapesw    equ  1261   1 indicates not the tape loader
     tapes3    equ  1263   1 indicates tape loader after all
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
     *
     * Stuff that is in one-field-per-card format
     *
               org  377
  377tptst2    bce  tests3,tapesw,1
  385btaprd    bin  taperd,  Chain next program from tape
               org  393
  393tapmod    mcw  btaprd&3,tptst2&3  Change so tapesw is 1 for tape
  400begin     cs   332
  404          cs
  405          bce  titlpr,titlsw,1  BR TO TITLE PRINT ROUTINE IF 1 IN S52
  413          bin  cont,
               org  420
  420cont      cs   80             CLEAR READ AREA
  424          sw   1              SET WM IN READ AREA
  428          r                   READ
  429cont2     mcw  80,280         LOAD PRINT AREA
  436          bwz  wrb,1,2        BRANCH IF NO ZONE IN 001
  444loop1     wr                  PRINT-READ
  445          bss  loop1,B        B ON TO SCOPE
  450          b    dtest          BRANCH TO TEST SWITCH D
  454wrb       wr   btest          PRINT-READ AND BRANCH
  458          h                   ERROR STOP IF NO BRANCH
  459btest     bss  wrb,B          B ON TO SCOPE
  464dtest     bss  cont,D
  469          bce  lctest,nxprog,B  Program loaded from tape?
  477          bce  rel1,80,A      Chain from cards?
  485lctest    blc  nocard
  490          b    cont2
  494tests3    bce  tapmod,tapes3,1
  502          b    nxprog    Read detail or chain next program 
  506nxdetl    cs   80
  510          sw   1
  514          b    nxprog    Read detail or chain next program 
  518nocard    mcw  80,280
  525          w    nxdetl    Write
  529          dcw  #1
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w    cont         Print (space).
 1221          dcw  #1
               end  start
