               job  COMPARE & BR UNEQUAL                                   0100A
               ctl  6611
     *
     * Stuff in the preamble -- not in one-field-per-card format
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357          b    cont
  361          cs   reload,80
  368          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
     *
     * Stuff that is in one-field-per-card format
     *
               org  377
               bin  389,           USE WHEN TESTS ARE RUN FROM TAPE
               org  385
 0385          b    1288             ,,
 0389          nop  0                ,,
 0393          mcw  360,392          ,,
 0400begin     cs   332            START TEST
 0404          cs
 0405          bce  1200,1252,1    BR TO TITLE PRINT ROUTINE IF 1 IN S52
 0413          cs   80             CLEAR READ AREA
 0417next      b    detail         BRANCH TO PROGRAM CHAINING ROUTINE
 0421cont      sw   2,78           LOAD PRINT AREA
 0428          lca  80,299           ,,
 0435          lca  72,272           ,,
 0442          bce  larger,46,L    BR TO MAKE B FIELD LARGER IF L IN 046
 0450          sw   222            SET B FLD WM IF NO L IN 046
 0454          b    scope          BRANCH TO COMPARE
 0458larger    sw   221            SET B FLD WM IF L IN 046
 0462scope     c    203,223        COMPARE & BRANCH UNEQUAL
 0469          bu   uneq             ,,
 0474          bss  scope,B        B ON TO SCOPE
 0479          bce  ok,41,         NO ERROR IF BLANK IN 041
 0487          b    errprt         BRANCH TO ERROR PRINT ROUTINE
 0491uneq      bss  scope,B        B ON TO SCOPE
 0496          bce  ok,41,U        NO ERROR IF U IN 041
 0504          b    errprt         BRANCH TO ERROR PRINT ROUTINE
 0508ok        sw   241            LOAD RESULT COMMENT
 0512          lca  260,280          ,,
 0519          bss  corr,C         C ON TO CORRECT PRINT ROUTINE
 0524          bin  loop,          BRANCH TO SENSE D
               org  900
 0900errprt    lca  error,285      BEGIN ERROR PRINT ROUTINE
 0907          bss  errhlt,E       E ON TO ERROR STOP
 0912          w    loop           ERROR PRINT
 0916errhlt    h    loop           ERROR STOP
 0939          dcw  @                    @   WORD MARK
               org  950
 0950corr      lca  blanks,285     CORRECT PRINT ROUTINE
 0957          w                     ,,
 0958loop      bss  cont,d         D ON TO REPEAT
 0963          bin  next,          BRANCH TO READ NEXT RECORD
               org  1110
 1114error     dcw  @ERROR@        CONSTANTS
 1119blanks    dcw  @     @          ,,
 1139          dcw  @A FIELD             @     ,,
 1159          dcw  @B FIELD             @     ,,
 1179          dcw  @RESULT SHOULD BE    @     ,,
 1199          dcw  @RESULT IS           @     ,,
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218          cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&79,280  Load second line.
 1236          w                 Print second line.
 1237          cs   280          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
               end  start
