               job  List tests with word marks
               ctl  6611
     *
     * 1-5   Lengths of up to five instructions in test
     * 6-40  Instructions to implement test
     * 41-45 A field
     * 46-50 B field
     * 51-55 Correct result
     * 56-75 Description
     * 76-80 Test ID
     *
     * Print a page heading
     *
     start     sw   41,46
               sw   51,56
               sw   76
               mcw  @code@,204
               mcw  @A/D@,243
               mcw  @B@,251
               mcw  @Expect@,266
               mcw  @Description@,281
               mcw  @id@,297
               w
               cs
               cs
               mcw  @6..10...15...20...25...30...35...40@,235
               mcw  @...45@,245
               mcw  @...50@,255
               mcw  @...55@,265
               mcw  @...60...65...70...75@,290
               mcw  @...80@,300
               w
     loop      blc  done
               cs   333
               cs
               cs   40
               r
               mcw  @006@,sw&3   Refresh changed instructions
               mcw  @001@,add&3
               sw   5
               chain4
     sw        sw   0-0          Set word mark under instruction
               sw   sw&1
     add       a    0-0,sw&3     Bump where to set word mark
               cw   sw&1
               bce  donesw,add&3,6  Done setting word marks?
               a    *-6,add&3    Bump instruction width counter
               b    sw           Go set another word mark
     sw6       sw   6            Set WM under first instruction
     add1      a    1            Add count in column 1
     *
     * Done setting word marks
     *
     donesw    bce  try4,5,0
               lca  40,235
               chain5
               b    loaded
     try4      bce  try3,4,0
               lca  40,235
               chain4
               b    loaded
     try3      bce  try2,3,0
               lca  40,235
               chain3
               b    loaded
     try2      bce  try1,2,0
               lca  40,235
               chain2
               b    loaded
     try1      bce  just1,1,0
               lca  40,235
               lca
     just1     lca  40,235
     *
     * Code is loaded into print area.  Load the other fields
     *
     loaded    mcw  45,245  Move A
               mcw  50,255  Move B
               mcw  55,265  Move Expect
               mcw  75,290  Move Description
               mcw  80,300  Move ID
               w
               wm   loop
     *
     done      nop  99
               h
               b    loop
               end  start
