               job  LOAD COMPARE                                           0110B
     *
     * Halts (in addition to common part):
     *
     * 534 in A-star and 538 in I-star: Column 72 of detail is neither
     *     L nor M.  Start-reset and then Start assumes L.  Start just
     *     loops on the halt.
     *
     * Equates for common code.
     *
     start     equ  347
     detail    equ  start   Here to read detail or chain next program.
     headct    equ  336     Count of headers read.  Usually zero.
     *                      Change to one to print only one header.
     worked    equ  453     Here for success.
     failed    equ  470     Here for failure.
     repeat    equ  495     Here to reload print area and repeat test.
               org  518     Test starts here
     *
     *
     * Continue here after reading detail
     *
               bce  load1,72,L     Test Load
               bce  move,72,M      Test Move
     badinp    h    badinp         Bad input -- neither L nor M
     load1     sw   210,241
               b    load2
     move      sw   241,270
               mcw  210,270
               mcw
               b    btest
     load2     lca  210,270        LOAD OP WITH CHAINING
               lca                   ,,
     btest     bss  repeat,B
               cw   270            TEST FOR ERROR
               c    270,250          ,,
               bu   failed         BRANCH TO ERROR PRINT ROUTINE IF UNEQ
     bump      a    *-6,count      Bump counter
               bce  clear,count-1,9  Ninety times yet?
               b    repeat
     clear     s    count          Clear counter
               b    worked
     count     dcw  000
               dcw  @"@            GMWM
               end  start
