               JOB  PRINT WORD MARKS                                       1010B
               ctl  6611
     *
     * Stuff in the preamble
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357bcont     b    421
  361          cs   reload,80
  368          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
               org  377
  377          BCE  switch,1261,1  USE WHEN TESTS ARE RUN FROM TAPE
  385          B    taperd           ,,
  389switch    NOP  0                ,,
  393          MCW  bcont&3,switch&3 ,,
  400begin     CS   332            START TEST
  404          CS
  405          LCA  bloop&4,nohead&4  MODIFY TITLE PRINT TO SKIP HEADINGS
  412          BCE  titlpr,titlsw,1   BR TO TITLE PRINT ROUTINE IF 1 IN S52
  420loop      SW   200            SET WORD MARK IN 200
  424          MN   cw,332         MOVE LOZENGE INTO 332
  431          MCW  332,331        MOVE LOZENGE INTO ALL PRINT POSITIONS
  438          MCW  kab1,sw1&6     MOVE 201234 TO START A & B OF INSTR 466
  445          MCW  kab2,sw2&6     MOVE 267300 TO START A & B OF INSTR 473
  452wm        WM                  PRINT WORD MARKS
  454          BSS  452,B          B ON TO SCOPE
  459cw        CW   467,474        CLEAR WORD MARKS IN 467 AND 474
  466sw1       SW   201,234        SET TWO WORD MARKS IN PRINT AREA
  473sw2       SW   267,300        SET TWO WORD MARKS IN PRINT AREA
  480          C    sw2&6,endsw    COMPARE LAST POSITION SET WITH 333
  487          BU   inc            UNEQUAL-BRANCH TO SET WM IN 467 AND 474
  492          B    clr            EQUAL-BRANCH TO BEGIN REMOVING WMS
  496inc       SW   sw1&1,sw2&1    SET WORD MARKS IN 467 AND 474
  503          A    incab,sw1&6    ADD 1001 TO INCREMENT AB OF INSTR 466
  510          A    incab,sw2&6    ADD 1001 TO INCREMENT AB OF INSTR 473
  517          B    wm             LOOP TO PRINT WORD MARKS
  521clr       MCW  kab1,cw2&6     MOVE 201234 TO START A & B OF INSTR 542
  528          MCW  kab2,cw3&6     MOVE 267300 TO START A & B OF INSTR 549
  535cw1       CW   cw2&1,cw3&1    CLEAR WORD MARKS IN 543 AND 550
  542cw2       CW   201,234        CLEAR TWO WORD MARKS IN PRINT AREA
  549cw3       CW   267,300        CLEAR TWO WORD MARKS IN PRINT AREA
  556scope     WM   skiph          PRINT UNCLEARED WORD MARKS & BRANCH
  561          H                   ERROR STOP IF NO BRANCH
  562skiph     BSS  scope,B        B ON TO SCOPE
  567          C    cw3&6,endcw    COMPARE LAST POSITION CLEARED WITH 332
  574          BU   inc2           UNEQUAL-BRANCH TO SET WM IN 543 AND 550
  579          BSS  loop,D         EQUAL-D ON TO REPEAT TEST
  584          B    detail         BRANCH TO READ NEXT RECORD
  588inc2      SW   cw2&1,cw3&1    SET WORD MARKS IN 543 AND 550
  595          A    incab,cw2&6    ADD 1001 TO INCREMENT AB OF INSTR 542
  602          A    incab,cw3&6    ADD 1001 TO INCREMENT AB OF INSTR 549
  609          BIN  cw1,           LOOP TO PRINT UNCLEARED WORD MARKS
               ORG  650
  650bloop     BIN  loop,          BRANCH INSTRUCTION TO MODIFY TITLE PRINT
  655kab1      DCW  @201234@       CONSTANT TO START AB FIELDS
  661kab2      DCW  @267300@       CONSTANT TO START AB FIELDS
  667endsw     DSA  333            CONSTANT TO END SET WM LOOPS
  670endcw     DSA  332            CONSTANT TO END CLEAR WM LOOPS
  673incab     DCW  @1001@         CONSTANT TO INCREMENT AB FIELDS
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218nohead    cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&69,270  Load second line.
 1236          w                 Print second line.
 1237          cs   270          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
               end  start
