                                                            /MACRO COMPILER
                     /
                     /PAGE 4400
                     *4400
          FINALL,    0
                     CLA CMA
                     DCA PRSW
                     JMS I DPCV1
                     CLA
                     TAD PRSW
                     SNA CLA
                     JMP FK2
                     /
                     TAD Z CHARX2
                     TAD Z M72
                     SZA CLA
                     JMP FK2+1
                     /
                     DCA I MSGN-1
                     DCA PRSW
                     JMP I DPCV1+1
                     /
          FK2,       TAD I MSGN-1
                     CMA IAC
                     DCA SEXP
                     TAD I INDIC2
                     SZA CLA
                     JMP NOWNEG
                     /
                     TAD C27
                     DCA Z BEXP
                     JMS FLNR
                     TAD Z CHARX2
                     TAD M5
                     SZA CLA
                     JMP CVRT
                     /
                     JMS I Z IDX1
                     TAD I SIGN2
                     DCA FLNR
                     TAD Z HIC
                     DCA AMT
                     TAD Z LWC
                     DCA PRSW
                     JMS I DPCV1
                     JMS MSGN
                     TAD Z HIC
                     SPA
                     CMA
                     SZA CLA
                     JMP EXTOO
                     /
                     TAD Z LWC
                     TAD SEXP
                     DCA SEXP
                     TAD FLNR
                     DCA I SIGN2
                     TAD AMT
                     DCA Z HIC
                     TAD PRSW
                     DCA Z LWC
          CVRT,      TAD SEXP
                     SNA
                     JMP NOWNEG
                     /
                     SMA CLA
                     JMP NOWNEG+2
                     /
                     JMS I DPCV1+2
                     TEN+2
                     ISZ SEXP
                     JMP CVRT
                     /
          NOWNEG,    JMS MSGN
                     JMP I FINALL
                     /
                     JMS I DPCV1+2
                     /
                     TEN-1
                     /
                     CLA CMA
                     TAD SEXP
                     DCA SEXP
                     JMP CVRT
                     /
          EXTOO,     TAD Z C3777
                     DCA Z BEXP
                     DCA Z LWC
                     TAD C2000
                     DCA Z HIC
                     JMP I FINALL
                     /
          PRSW,      0
          SEXP,      0
          DPCV1,     DPCV
                     DPCS
                     FLMY
                     /
          FLNR,      0          /NORMALIZE FLOATING POINT
                     CLA CLL
                     DCA AMT
                     TAD Z HIC
                     SZA CLA
                     JMP .+4
                     /
                     TAD Z LWC
                     SNA CLA
                     JMP EXPN+3
                     /
                     TAD Z HIC
          LOP,       RAL CLL
                     SPA CLA
                     JMP EXPN
                     /
                     TAD Z LWC
                     RAL
                     DCA Z LWC
                     TAD Z HIC
                     RAL
                     DCA Z HIC
                     ISZ AMT
                     JMP LOP-1
                     /
          EXPN,      TAD AMT
                     CIA
                     TAD Z BEXP
                     DCA Z BEXP
                     JMP I FLNR
                     /
          AMT,       0
                     RTDIG
                     /
          MSGN,      0
                     CLA CLL
                     TAD I SIGN2
                     SMA CLA
                     JMP I MSGN
                     /
                     TAD Z LWC
                     CMA IAC
                     DCA Z LWC
                     TAD Z HIC
                     CMA
                     SZL
                     IAC
                     DCA Z HIC
                     JMP I MSGN
                     /
          INDIC2,    INDIC
          SIGN2,     SIGN
                     HLT
                     HLT
          C2000,     2000
          M5,        0-5
          C27,       27
                     PAUSE
                                                                                                                                               }