                                                                              /MACRO COMPILER
                     /SYMBOLIC ASSEMBLY LISTER
                     /
                     /PAGE 3600
                     *3600
                     TYCAR
                     /
          LSTSYM,    0
                     TAD Z ITEM
                     TAD M212
                     SZA
                     JMP .+10
                     /
                     TAD Z CHARAC
                     SNA CLA
                     JMP I LSTSYM          /SYMBOLIC BUFFER EMPTY
                     /
                     TAD M14
                     JMS I Z SKIP          /SPACE 12 CHARACTERS
                     JMS EMPTY             /EMPTY BUFFER
                     JMP I LSTSYM
                     /
                     TAD Z M3
                     SNA CLA
                     JMP I LSTSYM
                     /
                     TAD Z CHARAC
                     TAD Z SEND
                     DCA EMPTY             /ADDRESS TO STORE CHAR
                     TAD EMPTY
                     CIA
                     TAD Z MACEND
                     SMA CLA
                     JMP I LSTSYM          /NO ROOM FOR CHAR
                     /
                     CLA CMA
                     TAD Z CHARAC
                     DCA Z CHARAC          /UPDATE COUNTER/POINTER
                     TAD Z ITEM
                     DCA I EMPTY           /STORE CHARACTER
                     JMP I LSTSYM
                     /
          EMPTY,     0
                     TAD Z CHARAC
                     SNA CLA
                     JMP .+12              /NO CHARACTERS IN BUFFER
                     /
                     TAD Z SEND
                     JMP .+3
                     /
                     CLA CMA
                     TAD LT2
                     DCA LT2               /ADDR OF CHAR.
                     TAD I LT2
                     JMS I Z DECOUT
                     ISZ Z CHARAC
                     JMP .-6
                     /
                     JMS I LSTSYM-1
                     JMP I EMPTY
                     /
          LT2,       0
                     TAD Z C7600
                     DCA EMPTY
                     TAD Z C200
                     JMS I Z DECOUT
                     ISZ EMPTY
                     JMP .-3
                     /
                     JMP I LT2
                     /
                     FIRST+6
                     JMP I Z 1
                     /
          FIRST,     0
                     TAD FIRST-1
                     DCA DISMS
                     TAD FIRST-2
                     DCA Z 1
                     NOP
                     CLA
                     TAD DELCNT-1
                     NOP
                     DCA DELCNT            /60 CPS DELAY FACTOR
                     RFC                   /READ FROM 750
                     DCA DELCNT+2          /NOT READY FOR THIS CHAR
                     DCA DELCNT+1          /READ GOING ON
                     ION
                     JMP I FIRST
                     /
                     NOP
                     0-723                 /PDP 5 DELAY FACTOR
          DELCNT,    0
                     0                     /7777 IF NO READ GOING ON
                     0                     /7777 IF PREV CHAR PROCESSED
                     0
                     /
          INTHAN,    DCA DELCNT+3
                     RSF
                     JMP .+10
                     /
                     RRB
                     ISZ DELCNT+2
                     JMP DISMS+1           /PREV CHAR NOT PROCESSED
                     /
                     RFC
                     DCA FIRST
                     DCA DELCNT+1
                     JMP DISMS-2
                     /
                     PCF
                     MMCF
                     DCF                   /LT PEN
                     ADRB                  /A-D
                     PLCF                  /PLOTTER
                     MTS                   /MAG 57A
                     KCC
                     TCF
                     NOP
                     NOP
                     NOP
                     NOP
                     NOP
                     TAD DELCNT+3
                     ION
          DISMS,     JMP I Z 1
                     /
                     DCA FIRST
                     TAD DELCNT
                     DCA DELCNT+1          /DELAY TO INSURE 60 OP
                     ISZ DELCNT+1          /LESS CPS
                     JMP .-1
                     /
                     CLA CMA               /NOW GO
                     JMP INTHAN+10
                     /
          HSGET,     0
                     CLA CMA
                     IOF
                     DCA DELCNT+2
                     ISZ DELCNT+1
                     JMP .+6
                     /
                     RFC
                     DCA DELCNT+2
                     TAD FIRST
                     ION
                     JMP I HSGET
                     /
                     RSF
                     JMP .-1
                     ION
                     JMP .-7
                     /
                     HLT
                     HLT
                     /
          M14,       0-14
          M212,      0-212
                     PAUSE
                                                                                                                                                                              