                                                                   *7600
/REVISED OCTAL DUMP SUBROUTINE       -HAMMOND- 16/10/65
ODUM,     CLA
          OSR
          DCA LOCK
          HLT
          OSR
             CMA
             TAD LOCK
             DCA LIM     /INITIALIZE RANGE COUNTER
             JMP .+3
DUM2,     ISZ LPCN   /END OF LINE
            JMP DUM3
             TAD CONS+3   /-3
             DCA LPCN    /RESET ITEM COUNTER
            JMS CRLF    /CARR,RET. AND LINE FEED
             TAD LOCK
          JMS PNUM
          TAD PCON   /4 SPACES
             DCA CRLF
             TAD CONS+2   /240 (SPACE)
             JMS TYPN
             ISZ CRLF
             JMP .-3
DUM3,        CLA
             TAD I LOCK
          JMS PNUM
             TAD CONS+2   /240 (SPACE)
             JMS TYPN
             ISZ LOCK     /INDEX LOCTIO N POINTER
             ISZ LIM       /END OF RANGE
             JMP DUM2
             JMS CRLF
          HLT
          JMP ODUM   /RETURN TO MAIN PROGRAM
TYPN,        0
             TSF
             JMP .-1
             TLS
             CLA
             JMP I TYPN
CRLF, 0
             CLA
             TAD CONS+1
             JMS TYPN
             TAD CONS                  /212 (LINE FEED)
             JMS TYPN
             JMP I CRLF
LOCK,        0
LIM,         0
LPCN,        0
CONS,        212         /CONSTANTS
             215
             240
          7763

PNUM,        0
             DCA PTEM
             TAD PCON      /7774
             DCA DCN       /INITIALIZE DIGIT COUNTER
             TAD PTEM
             RAL
PNU2,        RAL
             RTL
             DCA PTEM
             TAD PTEM
             AND PCON+1   /7
             TAD PCON+2   /260
          JMS TYPN   /TYPN TYPE A DIGIT
          TAD PTEM
             ISZ DCN
             JMP PNU2
             CLA
             JMP I PNUM
DCN,         0             /DIGIT COUNTER
PTEM,        0
PCON,        7774        /CONSTANTS
             7
             260
$
                                                                                                                         