                                                            
         /D-BUG, MK. 2.
         /180867/1

         /PAGE ZERO AND ODD CONSTANTS

         *5

         7400
         7200
         5600


         *177

         ANAL


         *6563

         FPLINK


         TYPER=7344
  

 

         /MAIN ROUTINE

         *3600

OBLEQU,  334
INIT,    TLS
         JMS I TYNUL
         DCA   55
         DCA   FIXFLT
         DCA   BPSWIT
RESET,   TAD   PIM5
         DCA   ADDIG
         DCA   PACK
READ,    JMS I RTY
         JMS   SORTB
         CHARLS
         LOOKUP-CHARLS
         TAD   M270
         SMA
         JMP   QUPT
         TAD   K10
         SPA
         JMP   QUPT
         DCA   DTEM
         TAD   PACK
         CLL RAL
         RTL
         TAD   DTEM
         DCA   PACK
         ISZ   ADDIG
         JMP   READ
QUPT,    CLA
         TAD   K277
         JMS I TYER
         JMS I TYNUL
         JMP   RESET
 
TYNUL,   TYNULN
PIM5,    -5
RTY,     RETY
M270,    -270
K10,     10
K277,    277
BPSWIT,  0
ADDIG,   0
PACK,    0
DTEM,    0
SLASH,   TAD   MI2
         JMS I SPAC
         TAD   FIXFLT
         SNA CLA
         JMP I FIXD
         JMS I SAVR
         JMS I 7
         FGET I PACK
         FEXT
         JMS I 6
         TAD   MI2
         JMS I SPAC
         JMS I 5
         TAD   57
         TAD   PIM212
         SNA
         JMP   FIXIT
         TAD   PIM3
         SZA
         JMP   QUPT
         TAD   60
         SNA CLA
 
         JMP   RESET
         JMS I 7
         FPUT I PACK
         FEXT
         JMS I GFAC
         JMP   RESET
FIXFLT,  0
MI2,     -2
SPAC,    SPACE
FIXD,    FIX
SAVR,    SAVPUT
PIM212,  -212
PIM3,    -3
GFAC,    GETFAC
SORTB,   00
         DCA   DTEM
         TAD I SORTB
         DCA   ADDIG
         ISZ   SORTB
         SKP
         ISZ   ADDIG
         TAD I ADDIG
         SPA
         JMP   SEX
         CIA
         TAD   DTEM
         SZA CLA
         JMP   .-7
         TAD   ADDIG
         TAD I SORTB
         DCA   SORTB
         TAD I SORTB
 
         DCA   SORTB
         JMP I SORTB
SEX,     ISZ   SORTB
         CLA
         TAD   DTEM
         JMP I SORTB
FIXIT,   TAD   60
         SNA CLA
         JMP   ISLFA
         JMS I 7
         FPUT I PACK
         FEXT
ISLFA,   JMS I GFAC
ISLF,    TAD   K215
         JMS I TYP
         JMS I TYER
         TAD   FIXFLT
         SNA CLA
         TAD   MI2
         TAD   K3
         TAD   PACK
         DCA   PACK
         TAD   PACK
         JMS I OCTP
         TAD   OBLEQU
         JMS I TYER
         JMP   SLASH
K215,    215
TYP,     TYPE
TYER,    TYPER
K3,      3
OCTP,    OCTPRT
 
         /SECTION 2
         *4000

STAR,    KCC
         CMP
         JMP I .+1
         INIT
ISB,     ISZ I BPSWIH
         JMP   NO
         TAD   ORDER
         DCA I ORDADD
NO,      JMS   GET
         DCA   ORDER
         TAD I PACKI
         DCA   ORDADD
         TAD I FIXX
         SNA CLA
         TAD   CONT
         TAD   FLTLNK
         JMS   PUT
         CMA
         DCA I BPSWIH
         JMP I QUPTR
ORDER,   0
ORDADD,  0
CONT,    5560
FLTLNK,  0017
ISK,     ISZ I BPSWIH
         JMP I QUP
         TAD   ORDER
         DCA I ORDADD
         JMP I QUPTR
BPSWIH,  BPSWIT
PACKI,   PACK
FIXX,    FIXFLT
QUPTR,   QUPT+3
QUP,     QUPT
ISC,     TAD I BPSWIH
         SNA CLA
 
         JMP I QUP
         TAD   ORDADD
         IAC
         DCA I NEXA
         TAD I FIXX
         JMP I ISCT
NEXA,    NEXADD
ISCT,    ISCC
ISG,     JMS I TYN
         JMS   GET
         CLA
         JMP I CLC
TYN,     TYNULN
FIX,     JMS   GET
         JMS I OCTT
         TAD   MY2
         JMS I SPCE
         DCA   IPREG
         TAD   MY5
         DCA   CNTR
FIXLOP,  JMS I RETI
         TAD   MY212
         SNA
         JMP   LF
         TAD   MY56
         SMA
         JMP I QUP
         TAD   KY10
         SPA
         JMP   ADDIT
         DCA   TEMP
         TAD   IPREG
 
         CLL RAL
         RTL
         TAD   TEMP
         DCA   IPREG
         ISZ   CNTR
         JMP   FIXLOP
         JMP I QUP
OCTT,    OCTPRT
MY2,     -2
SPCE,    SPACE
MY5,     -5
RETI,    RETY
MY212,   -212
MY56,    -56
KY10,    10
TEMP,    0
IPREG,   0
CNTR,    0
ADDIT,   TAD   KY43
         SZA
         JMP I QUP
         TAD   CNTR
         TAD   KY5
         SNA CLA
         JMP I QUPTR
         TAD   IPREG
         JMS   PUT
         JMP I QUPTR
LF,      TAD   KY5
         TAD   CNTR
         SNA CLA
         JMP I ISLFX
 
         TAD   IPREG
         JMS   PUT
         JMP I ISLFX
ISL,     CLA CMA
ISX,     DCA I FIXX
         JMP I QUPTR
GET,     00
         TAD I PACKI
         DCA   CLC
         TAD I CLC
         JMP I GET
PUT,     00
         DCA   GET
         TAD I PACKI
         DCA   CLC
         TAD   GET
         DCA I CLC
         JMP I PUT
TYPE,    00
         TSF
         JMP   .-1
         TLS
         JMP I TYPE
KY43,    43
KY5,     5
ISLFX,   ISLF
CLC,     0
 
         /SECTION 3
         *4200

RETY,    00
         KSF
         JMP   .-1
         KRB
         JMS I TY
         JMP I RETY
TYNULN,  00
         CLA
         TAD   B
         JMS I TYPX
         TAD   A
         JMS I TYPX
         JMP I TYNULN
SPACE,   00
         DCA   TYNULN
         TAD   KX240
         JMS I TYPX
         ISZ   TYNULN
         JMP   .-3
         JMP I SPACE
OCTPRT,  00
         CLL RAL
         DCA   TYNULN
         TAD   MX4
         DCA   SPACE
OCTLOP,  TAD   TYNULN
         RTL
         RAL
         DCA   TYNULN
         TAD   TYNULN
         AND   MX7
         TAD   MX260
 
         JMS I TYPX
         ISZ   SPACE
         JMP   OCTLOP
         JMP I OCTPRT
ANAL,    JMS   STORIT
         TAD   MX314
         JMS I TYPX
         TAD   MX275
         JMS I TYPX
         TAD   LST
         TAD   MX260
         JMS I TYPX
         TAD   MX2
         JMS   SPACE
         TAD   MX301
         JMS I TYPX
         TAD   MX275
         JMS I TYPX
         TAD   ACST
         JMS   OCTPRT
         JMP I C
ACST,    0
LST,     0
TY,      TYPE
TYPX,    TYPER
KX240,   240
MX4,     -4
MX7,     7
MX260,   260
MX314,   314
MX275,   275
MX2,     -2
 
MX301,   301
STORIT,  00
         DCA   ACST
         RAL
         DCA   LST
         JMS   TYNULN
         JMP I STORIT
FPLINK,  00
         JMS   STORIT
         TAD   MX306
         JMS I TYPX
         TAD   MX275
         JMS I TYPX
         JMS   SAVPUT
         JMS I 6
         JMS   GETFAC
         JMP I C
SAVPUT,  00
         TAD   44
         DCA   SFAC
         TAD   45
         DCA   SFAC+1
         TAD   46
         DCA   SFAC+2
         JMP I SAVPUT
SFAC,    0
         0
         0
MX306,   306
GETFAC,  00
         CLA
         TAD   SFAC
 
         DCA   44
         TAD   SFAC+1
         DCA   45
         TAD   SFAC+2
         DCA   46
         JMP I GETFAC
CHARLS,  0
A,       212
         257
         302
         303
         307
         313
         314
         330
B,       215
         -1
LOOKUP,  READ
         ISLF
         SLASH
         ISB
         ISC
         ISG
         ISK
         ISL
         ISX
C,       QUPT+3
RESTOR,  00
         TAD   LST
         CLL RAR
         TAD   ACST
         JMP I RESTOR
 
         /SECTION 4
         *4400

ISCC,    SNA CLA
         JMP   ISFIXD
         TAD I ORD
         SNA
         JMP   ISFEXT
         JMS   ROUTA
         JMS   ROUTB
         DCA   FLTXIT
         JMS I REST
         JMS I 7
FLTXIT,  0
         FEXT
         TAD   NEXADD
         DCA I 7
         JMP I J5601
J5601,   5601
ISFEXT,  JMS I REST
         JMP I NEXADD
REST,    RESTOR
ISFIXD,  TAD I ORD
         JMP   MQ
         SPA CLA
         JMP   NOTMEM
         TAD I ORD
         JMS   ROUTA
         TAD   MQ4000
         SZA CLA
         JMP   NOTJMS
         TAD   NEXADD
         DCA I REFCON
         JMS I REST
         ISZ   REFCON
 
         JMP I REFCON
NOTJMS,  TAD I ORD
         AND   KQ7000
         JMS   ROUTB
         DCA   .+2
         JMS I REST
         0
         JMP I NEXADD
         ISZ   NEXADD
         JMP I NEXADD
NEXADD,  0
REFCON,  0
ORD,     ORDER
MQ6000,  -6000
MQ4000,  -4000
KQ7000,  7000
NOTMEM,  TAD I ORD
         JMP   NOTJMS+3
ROUTA,   00
         AND   K177
         DCA   TSTOR
         TAD I ORAD
         AND   KQ7600
         TAD   TSTOR
         DCA   REFCON
         TAD I ORD
         AND   KQ400
         SNA CLA
         JMP   .+3
         TAD I REFCON
         DCA   REFCON
 
         TAD I ORD
         AND   KQ7000
         JMP I ROUTA
K177,    177
TSTOR,   0
ORAD,    ORDADD
KQ7600,  7600
KQ400,   400
ROUTB,   00
         TAD   KQ600
         DCA   TSTOR
         TAD   REFADD
         AND   K177
         TAD   TSTOR
         JMP I ROUTB
KQ600,   600
REFADD,  REFCON
MQ,      CLL RAL
       SZL
         JMP   ISFIXD+2
         CLA
         JMP   ISFIXD+4


$

 

