
	.ABS
	.LOC 100
SKPDN=701041
CLNF=701044
LD4=701024
LD16=701004
RD16=701072
RD4=701052
PPA=700204
PSF=700201
PCF=700202
IORS=700314
RSF=700101
RCF=700102
RSA=700104
RRB=700112
/
START	SKPDN
	JMP .-1
	CLNF	/CLEAR FLAG
	RD16
	LD16	/ECHO
	SAD (600
	JMP REW
	AND (17	/MASK FOR DEV. CODE
	SAD (2
	JMP MTO
	SAD (3
	JMP MTI
	SAD (7
	JMP PTP
	SAD (10
	JMP PTR
	HLT
PTP	JMS IDATA
	JMP START	/END OF XMISSION
	DAC CHAR
	RAL
	SWHA
	JMS PNCH	/UPPER 8 BITS
	LAC CHAR
	JMS PNCH
	JMP PTP
/
/
PTR	JMS PTRD
	SWHA
	RAR
	DAC CHAR
	JMS PTRD
	XOR CHAR
	JMS ODATA
	JMP START	/END OF XMISSION
	JMP PTR
EORD	JMS EOX
	JMP START	/END OF TAPE
CHAR	0
/
EOX	0
	LAC (2
	LD4
	LD16
	SKPDN
	JMP .-1
	CLNF
	JMP* EOX
/
PNCH	0
	PPA
	PSF
	JMP .-1
	PCF
	JMP* PNCH
/
PTRD	0
	IORS
	AND (1000
	SZA
	JMP EORD
	RSA
	RSF
	JMP .-1
	RCF
	RRB
	JMP* PTRD
/
IDATA	0
	SKPDN
	JMP .-1
	CLNF
	RD4
	SZA
	JMP ENDD
	RD16
	ISZ IDATA	/INCR RET. POINTER
ENDD	LD16	/ECHO
	JMP* IDATA
/
ODATA	0
	DAC TEMP
	CLA
	LD4
	LAC TEMP
	LD16
	SKPDN
	JMP .-1	/WAIT FOR ACKN.
	CLNF
	RD4
	AND (3
	SNA
	ISZ ODATA	/NORM. RET.
	JMP* ODATA
TEMP	0
/
EBA=707764
MTLC=707304
MTGO=707344
MTRS=707352
MTSF=707301
/
MTO	JMS MTCLR
MTOLP	JMS IDATA
	JMP MTOE	/END OF DATA
	DAC* MTPT
	ISZ MTPT
	ISZ MTCNT
	JMP MTOLP
	LAC (200	/WRITE A BUFFER
	DAC MTBCNT
	LAC MTWRT
	JMS MTXFER
	JMP MTO
MTOE	LAC MTCNT	/END OF DATA
	ADD (200
	DAC MTBCNT
	LAC MTWRT
	JMS MTXFER
	JMP START
/
MTI	LAC MTIF	/CHECK IF BUF. PRESENT
	SZA
	JMP BFPR	/YES
	CLA
	JMS MTXFER	/GET ONE
	LAW 16000
	IAC
	SZA
	JMP .-2	/LOOP TO DELAY
	LAC MTBCNT
	CMA
	DAC MTCNT
	LAC (MTBUF
	DAC MTPT
	CLA!CMA
	DAC MTIF	/SET BUF. PRESENT FLAG
BFPR	ISZ MTCNT
	JMP MTCON
	DZM MTIF	/SET FLAG TO GET NEW BF.
	LAC MTBCNT
	SAD (200	/CHECK IF A FULL BUF
	JMP MTI	/GO FOR ANOTHER BUF
	JMS EOX
	JMP START
MTCON	LAC* MTPT
	JMS ODATA
	JMP START	/PDP SIGNALS END OF DATA
	ISZ MTPT
	JMP MTI
/
/
MTCL=707302
MTSE=707341
/
MTCLR	0
	LAC (200
	CMA
	DAC MTCNT
	LAC (MTBUF
	DAC MTPT
	JMP* MTCLR
/
MTXFER	0
	MTCL
	MTLC
	EBA
	LAC (-202
	DAC 17762
	LAC MTBFA
	DAC 17763
	MTGO
	MTSE
	JMP .+2
	HLT
	MTSF
	JMP .-1
	JMP* MTXFER
/
MTERR	DZM MTIF
	JMS EOX
	JMP START
/
REW	LAC (4000
	MTLC
	MTRS
	AND (20000
	SNA
	JMP .-3
	DZM MTIF
	JMP START
/
/
MTIF	0
MTWRT	40000
MTCNT	0
MTPT	0
MTBFA	.+0
MTBUF	.BLOCK 201
MTBCNT	0
/
/
	.END START
