!JOB
!LIMIT (TIME,5),(ACCOUNT),(CORE,40),(LO,300),(ACCOUNT)
!TITLE EXAMPLE EDMS VALIDATION RUN
!ASSIGN F:1,(FILE,EXSUB-2),(IN)
!ASSIGN F:2,(FILE,%EXCSGP),(OUT),(SAVE)
!ASSIGN F:3,(DEVICE,LP)
!.
!.CSGP DCBS:  F:1  IS THE EDMS SUBSCHEMA FILE
!.            F:2  IS THE CONSECUTIVE SCHEMA
!.            F:3  IS FOR ERROR MESSAGES
!.
!RUN (LMN,EVAL_RU1)
!ASSIGN F:SORTIN,(FILE,%EXCSGP)
!ASSIGN F:SORTOUT,(FILE,%EXCSGP)
!ASSIGN M:SI,(FILE,%SORT-CSGP)
!SORT
!ASSIGN F:1,(FILE,%EXCSGP),(IN)
!ASSIGN F:3,(FILE,%EX-EG),(OUT),(SAVE)
!ASSIGN F:4,(FILE,%EX-PT),(OUT),(SAVE)
!ASSIGN F:5,(DEVICE,CR)
!ASSIGN F:6,(DEVICE,LP)
!ASSIGN F:7,(DEVICE,LP)
!ASSIGN F:11,(FILE,EXAREA-1D),(IN)
!ASSIGN F:12,(FILE,EXAREA-2D),(IN)
!.
!.EXTRACTION DCBS:  F:1  IS THE CONSECUTIVE SCHEMA
!.                  F:3  IS THE EG FILE
!.                  F:4  IS THE PT FILE
!.                  F:5  IS USER INPUT(BLOCKING FACTORS
!.                       FOR EG AND PT FILES)
!.                  F:6  IS USER OUTPUT
!.                  F:7  IS DIAGNOSTIC OUTPUT
!.                  F:11 IS AREA 1
!.                  F:12 IS AREA 2
!.
!RUN (LMN,EVAL_RU2)
!ASSIGN F:SORTIN,(FILE,%EX-PT)
!ASSIGN F:SORTOUT,(FILE,%EX-PT)
!ASSIGN M:SI,(FILE,%SORT-PT)
!.SORT MUST KNOW THE BLOCKING FACTOR OF THE PT FILE....
!SORT
!ASSIGN F:3,(FILE,%EX-EG),(IN)
!ASSIGN F:4,(FILE,%EX-PT),(IN)
!.
!.VALIDATION DCBS:  F:1  IS THE CONSECUTIVE SCHEMA
!.                  F:3  IS THE EG FILE
!.                  F:4  IS THE PT FILE
!.                  F:6  IS USER OUTPUT
!.                  F:7  IS DIAGNOSTIC OUTPUT
!RUN (LMN,EVAL_RU3)
!.
!.XEQ THE FILE -REPAIR
