*         COPYRIGHT, (C) HONEYWELL INFORMATION SYSTEMS INC., 1979
*
          SYSTEM SIG7FDP
              SYSTEM         BPM
              SYSTEM         FORTLIB
************************************************************************
*                                                                      *
*            SUBROUTINE RDDISC         J. A. LANGFORD@1978 11 01       *
*                                                                      *
*     READS A PAGE FROM A DATABASE AREA, FINDS THE DCB ADDRESS OF      *
*     THE SPECIFIED UNIT NUMBER, AND THEN DOES AM M:READ TO GET        *
*     THE REQUIRED PAGE.                                               *
*                                                                      *
************************************************************************
              DEF            RDDISC,V#RDDISC
              REF            9SETUPN,7UNITADR
              CSECT          0
V#RDDISC      EQU            $
UNIT          RES            1
BLK           RES            1
PGADDR        RES            1
RETN          RES            1
              CSECT          1
RDDISC        EQU            $
*
*   HAND THE PARAMETERS THROUGH, THE PARAMETERS ARE AS FOLLOWS:
*
*     1)THE UNIT NUMBER TO BE READ.
*     2)THE BLOCK TO BE READ (ORIGIN 0 PAGE NUMBER)
*     3)THE ADDRESS OF THE PAGE BUFFER
*
              LI,5           3
              BAL,6          9SETUPN
              INTG           UNIT
              INTG           BLK
              INTG           PGADDR
*
*   STORE THE RETURN ADDRESS
*
              STW,15         RETN
*
*   7UNITADR WANTS THE UNIT NUMBER IN REGISTER 9, AND
*
              LW,9           *UNIT
              BAL,6          7UNITADR
*
*  M:READ WANTS A BLOCK NUMBER, RATHER THAN THE ADDRESS OF
*  A BLOCK NUMBER FIELD, SO PUT THE ADDRESS IN REGISTER 6
*
              LW,6           *BLK
*
*  DO THE READ
*
              M:READ         *4,(BLOCK,*6),(BUF,*PGADDR),(SIZE,2048),;
                             (WAIT)
*
*  THATS ALL
*
              B              *RETN
              END
