ASMB,A,B,L,T,C
      ORG 100B
MAIN  NOP
      JSB READ
      JSB NUMB
      SLB,RSS
      JMP RUBCK
      JSB RESET
NCHAR JSB PUSH
      JSB READ
      JSB NUMB
      SLB
      JMP NCHAR
      JSB PUSH
      LDA POINT
      STA EBUFF
      ISZ EBUFF
      LDB BADDR
      CMB,INB
      ADA BREG
      CPA TWO
      JMP OUTBF
      JSB RESET
DEL   EQU *
      LDA POINT,I
      ISZ POINT
      STA DATA
      CPA ZERO
      JMP DEL
BFOUT JSB PUNCH
      JSB POP
      JMP BFOUT
OUTBF JSB RESET
      JSB POP
      JMP BFOUT
RUBCK LDA DATA
      CPA OUTRU
      JMP MAIN
      JSB PUNCH
      JMP MAIN
*
READ  NOP
      STC PTR,C
      SFS PTR
      JMP *-1
      LIA PTR
      STA DATA
      JMP READ,I
*
NUMB  NOP
      CLB
      LDA DATA
      AND MASK
      ADA M72
      SSA,RSS
      JMP NUMB,I
      LDA DATA
      AND MASK
      ADA M60
      SSA,RSS
      INB
      JMP NUMB,I
*
PUNCH NOP
      LDA DATA
      OTA PUN
      STC PUN,C
      SFS PUN
      JMP *-1
      JMP PUNCH,I
*
PUSH  NOP
      LDA DATA
      STA POINT,I
      ISZ POINT
      JMP PUSH,I
*
POP   NOP
      LDA POINT,I
      STA DATA
      ISZ POINT
      LDB EBUFF
      CPB POINT
      JMP MAIN
      JMP POP,I
*
RESET NOP
      LDA BADDR
      STA POINT
      JMP RESET,I
*
AREG  EQU 0
BREG  EQU 1
PTR   EQU 10B
PUN   EQU 12B
DATA  NOP
M72   OCT -72
POINT NOP
M60   OCT -60
EBUFF NOP
TWO   DEC 2
OUTRU OCT 377
ZERO  OCT 60
MASK  OCT 177
BADDR DEF BUFFR
BUFFR BSS 10
*
      END
                                                                        