*         RT   1,TAPEIN
     *         BER  TAPERR
     * OR
     *         WT   1,TAPEOT
     *         BER  TAPERR
     *
     * TAPE ERROR ROUTINE
     * THE B TAPERR MUST BE PRECEEDED BY AN 8 CHARACTER TAPE I/O COMMAND
     *  OR A COPY OF IT.
     TAPERR    SBR  TAPERX&3            STORE EXIT
               SBR  *&4                 INIT ADDR TO ERROR COMMAND&13
               C    *,TAPERC&13         USE COMPARE TO DECREMENT ADDRESS
               C                         TO ERROR COMMAND.
               MLC                      MOVE ERROR COMMAND TO ROUTINE
               MLC  @7@,TAPERX&4        SET ERROR COUNT TO 7.
               MN   TAPERC&3,TAPERB&3   SET DRIVE IN BACKSPACE.
               MN   TAPERC&3,TAPERB-2   SET DRIVE IN SKIP
     TAPERP    A    *-6,TAPERX&4        ADD 1 TO COUNT.
               C    TAPERX&4,@7@        COMPARE COUNT TO 7
               BU   TAPERB              Q. IO REPEATS.
               B    WLR
     TAPERB    BSP  0                   BACKSPACE FOR ANOTHER TRY.
               BCE  TAPERC,TAPERC&7,R   Q. READ COMMAND
               BL   TAPERC              NO, Q. TWO REWRITES IN SME PLACE
               SKP  0                   YES, SET SKIP SWITCH
     TAPERC    NOP  *,*,*               REPEAT TAPE I/O COMMAND.
               BER  TAPERP              Q. ERROR AGAIN
     TAPERX    B    *                   NO, EXIT
               DCW  #1                  ERROR COUNT, NEVER OVERFLOW BITS
     *
     WLR       MLC  @BAD TAPE ON SELECTED DRIVE, REPLACE & RESTART@,260
               W
               CS
               CS
               H    WLR
               B    WLR