job  List tests with word marks
               ctl  6611
     *
     * 1-6   Lengths of up to six instructions in test
     * 7-45  Instructions to implement test
     * 46-55 A field or D modifier
     * 56-65 B field
     * 66-75 Correct result
     * 76-80 Test ID
     *
     * Print a page heading
     *
     start     mcw  @code@,210
               mcw  @A/D@,253
               mcw  @B@,263
               mcw  @Expect@,290
               w
               cs
               cs
               mcw  @..10...15...20...25...30...35...40...45@,245
               mcw  @...50..@,257
               mcw  @.55...60...65.@,276
               mcw  @..70...75...80@,295
     writit    w
     loop      blc  done
               cs   333
               cs
               cs   80
               r
               bce  listit,1,*
               sw   46,53
               sw   67
               mcw  @07@,sw&3    Refresh changed instructions
               mcw  @1@,add&3
               sw   6
               chain5
     sw        sw   0-0          Set word mark under instruction
               sw   sw&1
     add       a    0-0,sw&3     Bump where to set word mark
               cw   sw&1
               bce  donesw,add&3,7  Done setting word marks?
               a    *-6,add&3    Bump instruction width counter
               b    sw           Go set another word mark
     *
     * List comment cards
     *
     listit    sw   1
               mcw  80,287
               b    writit
     *
     * Done setting word marks
     *
     donesw    bce  try5,6,0
               lca  45,245
               chain6
               b    loaded
     try5      bce  try4,5,0
               lca  45,245
               chain5
               b    loaded
     try4      bce  try3,4,0
               lca  45,245
               chain4
               b    loaded
     try3      bce  try2,3,0
               lca  45,245
               chain3
               b    loaded
     try2      bce  try1,2,0
               lca  45,245
               chain2
               b    loaded
     try1      bce  just1,1,0
               lca  45,245
               lca
     just1     lca  45,245
     *
     * Code is loaded into print area.  Load the other fields
     *
     loaded    mcw  52,257  Move A
               mcw  66,276  Move B
               mcw  80,295  Move Expect
               w
               wm   loop
     *
     done      nop  99
               h
               b    loop
               end  start