JOB  PRINT-READ-PUNCH                                       1080B
               ctl  6611
     *
     * Stuff in the preamble -- not in one-field-per-card format
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348nxprog    r
  349tptest    bce  *&5,80,a
  357          b    repeat
  361rel1      cs   reload,80
  368          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     s1        equ  1261
     s2        equ  1262
     s3        equ  1263
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
     *
               org  377
  377tptst1    bce  tests2,s1,1
  385btaprd    bin  taperd,
               org  393
  393tapmod    mcw  btaprd&3,tptst1&3
  400begin     cs   332            START TEST
  404          cs
  405          bce  titlpr,titlsw,1  BR TO TITLE PRINT ROUTINE IF 1 IN S52
  413          bin  cont,
               org  420
  420cont      cs   80             CLEAR READ AREA
  424          sw   1              SET WM IN READ AREA
  428          r                   READ
  429repeat    lca  80,180         LOAD PUNCH AREA
  436          mcw  80,280         LOAD PRINT AREA
  443          bwz  wrpb,1,2       BRANCH IF NO ZONE IN 001
  451scope1    wrp                 PRINT-READ-PUNCH
  452          bss  scope1,B       B ON TO SCOPE
  457          b    loop           BRANCH TO MODIFY CHAIN. ROUTINE
  461wrpb      wrp  btest          PRINT-READ-PUNCH AND BRANCH
  465          h                   ERROR STOP IF NO BRANCH
  466btest     bss  wrpb,B         B ON TO SCOPE
  471loop      bss  cont,D         D ON TO REPEAT TEST
  476          bce  lctest,nxprog,B  Program loaded from tape?
  484          bce  rel1,80,A      Chain from cards?
  492lctest    blc  nocard
  497          b    repeat
  501tests2    bce  tests3,s2,1
  509          b    nxprog    Read detail or chain next program 
  513tests3    bce  tapmod,s3,1
  521          b    nxprog    Read detail or chain next program 
  525nxdetl    cs   180
  529          cs   80
  533          sw   1
  537          b    348
  541nocard    lca  80,180
  548          mcw  80,280
  555          wp   525
  559          dcw  #1
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w    cont         Print (space).
 1221          dcw  #1
               end  start