job  PRINT-READ-PUNCH                                       1080A
               ctl  6611
     *
     * Stuff in the preamble -- not in one-field-per-card format
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357mod       b    421    What's going to be at 421?
  361          cs   reload,80
  368          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
     *
               org  400
  400begin     cs   332            START TEST
  404          cs
  405          lca  bcont&4,titlpx&4  MODIFY TITLE PRINT TO SKIP HEADINGS
  412          bce  titlpr,titlsw,1  BR TO TITLE PRINT ROUTINE IF 1 IN S52
  420cont      cs   80             CLEAR READ AREA
  424          sw   1              SET WM IN READ AREA
  428          r                   READ
  429repeat    lca  80,180         LOAD PUNCH AREA
  436          lca  80,280         LOAD PRINT AREA
  443          bwz  wrpb,1,2       BRANCH IF NO ZONE IN 001
  451scope1    wrp                 PRINT-READ-PUNCH
  452          bss  scope1,B       B ON TO SCOPE
  457          b    loop           BRANCH TO MODIFY CHAIN. ROUTINE
  461wrpb      wrp  btest          PRINT-READ-PUNCH AND BRANCH
  465          h                   ERROR STOP IF NO BRANCH
  466btest     bss  wrpb,B         B ON TO SCOPE
  471loop      mn   bloop&3,mod&3  MODIFY B421 IN CHAINING ROUTINE TO B429
  478          bss  cont,D         D ON TO REPEAT TEST
  483bloop     bin  tptest,        BRANCH TO TEST FOR NEXT PROGRAM
               org  600
  600bcont     bin  cont,          BRANCH INSTRUCTION TO MODIFY TITLE PRINT
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218titlpx    cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&69,270  Load second line.
 1236          w                 Print second line.
 1237          cs   270          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
               end  start