job  RIPPLE PRINT                                           1020B
               ctl  6611
     *
     * Stuff in the preamble
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357bcont     b    cont    Cont is in a different place now
  361          cs   reload,80
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
               org  377
  377          bce  begin,1261,1   USE WHEN TESTS ARE RUN FROM TAPE
  385          b    taperd
               org  400
  400begin     cs   332
  404          cs
  405          bce  titlpr,titlsw,1  BR TO TITLE PRINT ROUTINE IF 1 IN S52
  413          cs   80
  417          b    cont
  421cont      cs   dat11
  425          cs
  426          lca  tab1,dat3      EXPAND
  433          mcw  dat3,dat5       THE
  440          mcw  dat5,dat11       DATA
  447rep1      lca  tab3,332
  454          w
  455          mcw  adat6,scope1&3  Set the starting print address
  462loop1     mcw  scope1&3,count  Bump
  469          a    *-6,count         the print
  476          mcw  count,scope1&3      address
  483scope1    mcw  dat6,332       MOVE TABLE INTO PRINT AREA
  490          w                   PRINT
  491          bss  scope1,B       B ON TO SCOPE
  496          c    count,adat9    Done?
  503          bu   loop1          No, do it again
  508          cc   J
  510          bss  rep1,D         Repeat same test
  515          bin  test2,
               org  539
  539test2     mcw  adat6,scope2&3  Set the print address
  546          mz   cont,tab2-1
  553          lca  tab2,dat1      Expand
  560          mcw  dat1,dat2        the
  567          mcw  dat2,dat4          data
  574          mcw  dat4,dat7
  581          mcw  dat2,dat10
  588loop2     mcw  scope2&3,count  Bump
  595          a    *-6,count         the print
  602          mcw  count,scope2&3      address
  609scope2    mcw  dat6,332       MOVE TABLE INTO PRINT AREA
  616          w                   PRINT
  617          bss  scope2,B       B ON TO SCOPE
  622          c    count,adat8    Done?
  629          bu   loop2          No, do it again
  634          cc   J
  636          bin  testd,
               org  647
  647testd     bss  test2,D
  652          b    detail
     *
     * Constants and data areas
     *
  658adat6     dsa  dat6
  661adat9     dsa  dat9
  664adat8     dsa  dat8
  712tab1      dcw  @1234567890#@/STUVWXYZ?,%JKLMNOPQR!$*ABCDEFGHI&.)@
  730tab2      dcw  @[] :? <;\>! "_+(  @
  733count     dcw  @XXX@
  780          ds   108
  880          dcw  @1  2  3  4  5  6  7  8  9  10 11 12 13 @
  919          dc   @14 15 16 17 18 19 20 21 22 23 24 25 26 @
  958          dc   @27 28 29 30 31 32 33 34 35 36 37 38 39 @
  973tab3      dc   @40 41 42 43 44 @
  999          dc   #26
               org  1000
 1018dat1      ds   19
 1036dat2      ds   18
 1048dat3      ds   12
 1072dat4      ds   24
 1096dat5      ds   24
 1131dat6      ds   35
 1144dat7      ds   13
 1149dat8      ds   5
 1179dat9      ds   30
 1180dat10     ds   1
 1192dat11     ds   12
 1199          ds   7
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     *
               org  1200
 1200titlpr    w
 1201          sw   49
 1205          lca  77,277
 1212          w
 1213          cs   277
 1217          w    cont
 1221          dcw  #1
               end  start