job  MOVE & ZERO SUPPRESS                                   0230A
               ctl  6611
     *
     * Stuff in the preamble -- not in one-field-per-card format
     *
               org  333
     *
     * Set up for one-field-per-card format and begin loading
     *
  333start     sw   8,12
  340reload    sw   1
  344          r    1
     *
     * Look for next program -- A in column 80
     *
  348detail    r
  349tptest    bce  *&5,80,a
  357bcont     b    cont
  361          cs   reload,80
  368          dcw  #1
               org  377
  377          B    switch       USE WHEN TESTS ARE RUN FROM TAPE
  381          dc   #4          
  385          B    1288           ,,
  389switch    NOP  0              ,,
  393          MCW  bcont&3,switch&3
  400begin     CS   332          START TEST
  404          CS
  405          B    titlpr,titlsw,1  BR TO TITLE PRINT ROUTINE IF 1 IN S5
  413          CS   80           CLEAR READ AREA
  417next      B    detail       BRANCH TO PROGRAM CHAINING ROUTINE
  421cont      SW   1,78         LOAD PRINT AREA
  428          LCA  80,299         ,,
  435          LCA  72,272         ,,
  442          SW   241,265        ,,
  449          BCE  scope2,10,   BR TO MOVE 1 POS FLD IF BLANK IN 010
  457scope1    MCS  210,270      MOVE & ZERO SUPPRESS 10 POS FIELD
  464          BSS  scope1,B     B ON TO SCOPE
  469          C    270,250      TEST FOR ERROR
  476          B    test           ,,
  480scope2    MCS  201,261      MOVE & ZERO SUPPRESS 1 POS FIELD
  487          BSS  scope2,B     B ON TO SCOPE
  492          C    261,241      TEST FOR ERROR
  499test      BU   errprt       BRANCH TO ERROR PRINT ROUTINE IF UNE
  504          BSS  corr,C       C ON TO CORRECT PRINT ROUTINE
  509          B    loop         BRANCH TO SENSE D
  513          dc   #1           
               org  900          
  900errprt    LCA  error,285      BEGIN ERROR PRINT ROUTINE
  907          BSS  errhlt,E       E ON TO ERROR STOP
  912          W    loop           ERROR PRINT
  916errhlt    H    loop           ERROR STOP
  939          DCW  @                    @   WORD MARK
               ORG  950
  950corr      LCA  blanks,285     CORRECT PRINT ROUTINE
  957          W                     ,,
  958loop      BSS  cont,d         D ON TO REPEAT
  963          BIN  next,          BRANCH TO READ NEXT RECORD
  967          dc   #1
               org  1110
 1114error     DCW  @ERROR@      CONSTANTS
 1119blanks    DCW  @     @        ,,
 1139          DCW  @A FIELD             @  ,,
 1159          DCW  @B FIELD             @  ,,
 1170          DCW  @RESULT SHOULD BE    @  ,,
 1199          DCW  @RESULT IS           @  ,,
     *
     * Title print routine.  Notice that in the original format,
     * the title and ID are in CC 49-77 of the last card -- the one
     * that transfers control to the program.
     *
     titlsw    equ  1252   1 to use title print routine
     hdrs      equ  1120   All programs put headers in 1120-1199
     titlex    equ  413    All routines must return here after title
     *
               org  1200
 1200titlpr    w                 Print (space).
 1201          sw   49           Set WM for Title and Block No.
 1205          lca  77,277       Load Title and Block No. in Print Area.
 1212          w                 Print Title and Block No.
 1213          cs   277          Clear Print Area
 1217          w                 Print (space).
 1218          cw   hdrs&20,hdrs&40  Clear Word Marks in second
 1225          cw   hdrs&60      line stored information.
 1229          lca  hdrs&69,270  Load second line.
 1236          w                 Print second line.
 1237          cs   270          Clear Print Area.
 1241          w    titlex       Print (space) and branch to main program.
 1245          dcw  #1
     *
     tapes1    equ  1268   blank indicates the tape loader
     taperd    equ  1288   tape read routine?
     tapes2    equ  1398   GM indicates the tape loader
               end  start