000       job  convert address in autocoder listing
               ctl  6611
               org  5000
     ct        equ  7
               bce  *&5,326, 
               b    nogm
               bce  *&5,303,}           Q. group mark in O. modifier
               b    nogm
               mlc  @gmark@,327
     nogm      c    ct,@2@              Q. A address
               bl   hasa
               b    exit 
     hasa      bce  aodd,295,%          A add not to be converted
               mlc  297,decode
               b    cnvrt
               mlc  rslt,312
     aodd      c    ct,@6@              Q. B address
               bl   hasb
               b    exit
     hasb      mlc  301,decode
               b    cnvrt
               mlc  rslt,321
     exit      bce  1637,293,           Q. Blank op, B badop
               b    1156                             B setlit
     *
     * decode 3 char addr to 5 char and index reg
     *     3 char addr in decode
     *     8 char result in rslt
     *
     cnvrt     sbr  cnvrtx&3            store exit
               mlc  bk8#8,rslt#8        set rslt to blanks
               bce  cnvrtx,decode-1,#   Q. no address
               bwz  noix,decode-1,2     Q. any index reg
               mlc  @*x@,rslt
               bwz  hx1,decode-1,s      Q. X1?
               bwz  hx2,decode-1,k      Q. X2?
               mlc  @3@,rslt            Set X3
               b    noix
     hx1       mlc  @1@,rslt            Set X1
               b    noix
     hx2       mlc  @2@,rslt            Set X2
     noix      mn   decode#3,rslt-3     Move hundreds digits
               mn
               mn
               mlc  @  @,thou#2
               bwz  t1,decode-2,s       Test for 1-2-3 thousand 
               bwz  t2,decode-2,k
               bwz  t3,decode-2,b
               b    try12
     t1        mlc  @1@,thou
               b    try12
     t2        mlc  @2@,thou
               b    try12
     t3        mlc  @3@,thou
     try12     bwz  t4,decode,s         Test for 4-8-12 thousand
               bwz  t8,decode,k
               bwz  t12,decode,b
               b    no12
     t4        a    @4@,thou
               b    no12
     t8        a    @8@,thou
               b    no12
     t12       a    @12@,thou
     no12      mcs  thou,tmp3#3
               mlc  tmp3,rslt-6
     cnvrtx    b    *
               ltorg*
               end  0