000       job  convert address in autocoder listing
               ctl  6611
               org  5000
     ct        equ  7
               bce  *&5,326, 
               b    nogm
               bce  *&5,303,}           Q. group mark in D. modifier
               b    nogm
               mlc  @gmark@,327
     nogm      c    ct,@3@              Q. A address
               bh   exit
               bce  aodd,295,%          A add not to be converted
               mlc  297,decode
               b    cnvrt
               mlc  rslt,312
     aodd      c    ct,@7@              Q. B address
               bh   exit
               mlc  301,decode
               b    cnvrt
               mlc  rslt,321
     exit      bce  1637,293,           Q. Blank op, B badop
               b    1156                             B setlit
     *
     * decode 3 char addr to 5 char and index reg
     *     3 char addr in decode
     *     8 char result in rslt
     *
     cnvrt     sbr  cnvrtx&3            store exit
               mlc  bk8#8,rslt#8        set rslt to blanks
               bce  cnvrtx,decode-1,#   Q. no address
               bwz  noix,decode-1,2     Q. any index reg
               mlc  @*x0@,rslt
               bwz  hx1,decode-1,s      Q. X1?
               bwz  hx2,decode-1,k      Q. X2?
               a    *-6,rslt
     hx2       a    *-6,rslt
     hx1       a    *-6,rslt
     noix      mn   decode#3,rslt-3     Move hundreds digits
               mn
               mn
               za   thou#3
               bwz  thou4,decode,2,2    Test for 1-2-3 thousand
               bwz  t1,decode-2,s
               bwz  t2,decode-2,k
     t3        a    *-6,thou-1
     t2        a    *-6,thou-1
     t1        a    *-6,thou-1
     thou4     bwz  no12,decode,2       Test for 4-8-12 thousand
               bwz  t4,decode,s
               bwz  t8,decode,k
     t12       a    noix,thou-1
     t8        a    noix,thou-1
     t4        a    noix,thou-1
     no12      mcs  thou-1,tmp3#3
               mlc  tmp3,rslt-6
     cnvrtx    b    *
               ltorg*
     *
     * Alternative main line
     *
               org  nogm
               bce  exit,297,           Q. no A address
               bce  xaodd,295,%         A add not to be converted
               mlc  297,decode
               b    cnvrt
               mlc  rslt,312
     xaodd     bce  exit,301,           Q. no B address
               mlc  301,decode
               b    cnvrt
               mlc  rslt,321
               end  0