.TITLE	PRFANL.MAC	81D16A		14-APR-81/16-APR-81.


;	AUTHOR: N. A. BOURGEOIS, JR.
;		SYSTEMS ENGINEERING DIVISION 1738
;		SANDIA NATIONAL LABORATORIES
;		PO BOX 5800
;		ALBUQUERQUE, NM 87185
;		505-844-8088
;		AV  244-8088
;
;	THIS SOFTWARE IS ISSUED BY SANDIA NATIONAL LABORATORIES,
;	OPERATED  FOR  THE UNITED STATES DEPARTMENT OF ENERGY BY
;	SANDIA CORPORATION.
;
;				NOTICE
;
;	THIS  SOFTWARE  WAS  SPONSORED  BY  THE  UNITED   STATES
;	GOVERNMENT.   NEITHER  THE  UNITED STATES GOVERNMENT NOR
;	THE UNITED STATES DEPARTMENT OF ENERGY, NOR ANY OF THEIR
;	EMPLOYEES, NOR ANY OF THEIR CONTRACTORS, SUBCONTRACTORS,
;	OR  THEIR  EMPLOYEES  MAKES  ANY  WARRANTY,  EXPRESS  OR
;	IMPLIED,    OR    ASSUMES   ANY   LEGAL   LIABILITY   OR
;	RESPONSIBILITY  FOR  THE   ACCURACY,   COMPLETENESS   OR
;	USEFULNESS  OF  ANY  INFORMATION,  APPARATUS, PRODUCT OR
;	PROCESS DISCLOSED, OR REPRESENTS THAT ITS USE WOULD  NOT
;	INFRINGE PRIVATELY OWNED RIGHTS.
;
;	THIS WORK WAS SPONSORED AND FUNDED BY:
;
;		    HEADQUARTERS, ESD / OCB / STOP 36
;		    HANSCOM AIR FORCE BASE, MA 01731
;
;
.SBTTL                      ****************
.SBTTL                      *              *
.SBTTL                      * UNCLASSIFIED *
.SBTTL                      *              *
.SBTTL                      ****************
.SBTTL	DESCRIPTION			14-APR-81/.

;THESE FOUR PERFORMANCE ANALYSIS SUPPORT ROUTINES ARE CALLABLE AS
;SUBROUTINES.  THREE OF THEM ARE ALSO CALLABLE AS FUNCTIONS.  THIS
;MODULE IS A PART OF THE LIBRARY OF FORTRAN CALLABLE TSX/TSX-PLUS
;EMT ROUTINES.  THE CODE IS REENTRANT.

;INITIALIZE A PERFORMANCE ANALYSIS.
;
;CALLING SEQUENCES:
;
;	CALL INITPA ( IBSADR , ITPADR , ICLSZ , IFLAG [ , IERR ] )
;				OR
;	IERR = INITPA ( IBSADR , ITPADR , ICLSZ , IFLAG )
;
;WHERE:	IBSADR IS THE BASE ADDRESS OF THE REGION TO BE MONITORED.
;
;	ITPADR IS THE TOP ADDRESS OF THE REGION TO BE MONITORED.
;
;	ICLSZ IS THE NUMBER OF BYTES TO GROUP IN EACH HISTOGRAM CELL.
;
;	IFLAG IS ONE OR MORE OF THE FOLLIWING:
;
;		0	DO NOT INCLUDE I/O WAIT TIME.
;		1	INCLUDE I/O WAIT TIME.
;
;	IERR IS UNDEFINED OR ONE OF THE FOLLOWING:
;
;		0	PERFORMANCE ANALYSIS IS ALREADY IN USE.
;		1	PERFORMANCE ANALYSIS FEATURE IS NOT INCLUDED
;			IS THIS VERSION OF TSX-PLUS.

;START A PERFORMANCE ANALYSIS.
;
;CALLING SEQUENCES:
;
;	CALL ISTPA [ IERR ]
;		OR
;	IERR = ISTPA ()
;
;WHERE:	IERR IS UNDEFINED OR AS FOLLOWS:
;
;		0	PERFORMANCE ALALYSIS HAS NOT BEEN INITIALIZED.
;STOP A PERFORMANCE ANALYSIS.
;
;CALLING SEQUENCES:
;
;	CALL ISPPA [ IERR ]
;		OR
;	IERR = ISPPA ()
;
;WHRER:	IERR IS UNDEFINED OR AS FOLLOWS:
;
;		0	PERFORMANCE ANALYSIS HAS NOT BEEN INITIALIZED.

;TERMINATE A PERFORMANCE ANALYSIS.
;
;CALLING SEQUENCE:
;
;	CALL TERMPA ( IPARBF , IHSTBF , IHBSIZ [ , IERR ] )
;
;WHERE:	IPARBF IS A FOUR ELEMENT PARAMETER BUFFER AS FOLLOWS:
;
;		1	BASE ADDRESS OF MONITORED REGION.
;		2	TOP ADDRESS OF MONITORED REGION.
;		3	NUMBER OF BYTES PER HISTOGRAM CELL.
;		4	CONTROL AND STATUS FLAG WITH BIT ASSIGNMENTS
;			AS FOLLOWS:
;
;			1	I/O WAIT WAS INCLUDED.
;			100000	SOME HISTOGRAM CELL OVERFLOWED.
;
;	IHSTBF IS THE HISTOGRAM BUFFER.
;
;	IHBSIZ IS THE NUMBER OF ELEMENTS OR CELLS IN THE HISTOGRAM
;		BUFFER.
;
;	IERR IS UNDEFINED OR ONE OF THE FOLLOWING:
;
;		0	THIS JOB HAS NOT DONE A PERFORMANCE ANALYSIS.
;		1	HISTOGRAM BUFFER AREA TOO SMALL.


.SBTTL	DIRECTIVES			14-APR-81/16-APR-81.

	.IDENT	\81D16A\	;TELL LINKER OUR VERSION
	.PSECT	TSXLIB


.SBTTL	ASSIGNMENTS			14-APR-81/.

	ERRBYT	=52		;ERROR CODE LOCATION
.SBTTL	ENTRY POINTS			14-APR-81/.

;INITIALIZE A PERFORMANCE ANALYSIS.
;
INITPA::MOV	#136	,R1		;EMT CODE
	CLR	R2			;EMT ID
	JSR	PC	,DOIT		;INITIALIZE IT
	RTS	PC

;START A PERFORMANCE ANALYSIS.
;
ISTPA::	MOV	#136	,R1		;EMT CODE
	MOV	#1	,R2		;EMT ID
	JSR	PC	,DOIT1		;START IT
	RTS	PC

;STOP A PERFORMANCE ANALYSIS.
;
ISPPA::	MOV	#136	,R1		;EMT CODE
	MOV	#2	,R2		;EMT ID
	JSR	PC	,DOIT1		;STOP IT
	RTS	PC

;TERMINATE A PERFORMANCE ANALYSIS.
;
TERMPA::MOV	#136	,R1		;EMT CODE
	MOV	#3	,R2		;EMT ID
	JSR	PC	,DOIT2		;TERMINATE IT
	RTS	PC


.SBTTL	SUPPORTING SUBROUTINES		14-APR-81/16-APR-81.

DOIT:	MOV	@10(R5)	,-(SP)		;PASS ARGUMENT 4
	MOV	@6(R5)	,-(SP)		;PASS ARGUMENT 3
	MOV	@4(R5)	,-(SP)		;PASS ARGUMENT 2
	MOV	@2(R5)	,-(SP)		;PASS ARGUMENT 1
	MOV	R2	,-(SP)		;LO BYTE = EMT ID
	MOV	SP	,R0		;EMT POINTER
	MOVB	R1	,1(R0)		;HI BYTE = EMT CODE
	EMT	375			;LET TSX DO IT
	BCC	1$			; IF NO ERROR
	CLR	R0			; IF ERROR
	MOVB	@#ERRBYT,R0		;  GET CODE
1$:	CMPB	#5	,(R5)		;SUBROUTINE ERROR RETURN?
	BNE	2$			; NO
	MOV	R0	,@12(R5)	; YES
2$:	ADD	#12	,SP		;FIX THE STACK POINTER
	RTS	PC
DOIT1:	MOV	R2	,-(SP)		;LO BYTE = EMT ID
	MOV	SP	,R0		;EMT POINTER
	MOVB	R1	,1(R0)		;HI BYTE = EMT CODE
	EMT	375			;LET TSX DO IT
	BCC	1$			; IF NO ERROR
	CLR	R0			; IF ERROR
	MOVB	@#ERRBYT,R0		;  GET CODE
1$:	CMPB	#1	,(R5)		;SUBROUTINE ERROR RETURN?
	BNE	2$			; NO
	MOV	R0	,@2(R5)		; YES
2$:	TST	(SP)+			;FIX THE STACK POINTER
	RTS	PC

DOIT2:	MOV	@6(R5)	,-(SP)		;PASS ARGUMENT 3
	MOV	4(R5)	,-(SP)		;SA FOR ARGUMENT 2
	MOV	2(R5)	,-(SP)		;SA FOR ARGUMENT 1
	MOV	R2	,-(SP)		;LO BYTE = EMT ID
	MOV	SP	,R0		;EMT POINTER
	MOVB	R1	,1(R0)		;HI BYTE = EMT CODE
	EMT	375			;LET TSX DO IT
	BCC	1$			; IF NO ERROR
	CLR	R0			; IF ERROR
	MOVB	@#ERRBYT,R0		;  GET CODE
1$:	MOV	4(R5)	,R1		;POINT TO
	ADD	@6(R5)	,R1		; FIRST BYTE
	INC	R1			;  PAST END
	MOV	R1	,R2		;POINT TO
	ADD	@6(R5)	,R2		; FIRST WORD
	INC	R2			;  PAST END
2$:	MOVB	-(R1)	,-(R2)		;CONVERT ARGUMENT 2
	CLRB	-(R2)			; FROM BYTES TO WORDS
	CMP	4(R5)	,R2		;DONE?
	BNE	2$			; NO
	CMPB	#4	,(R5)		;SUBROUTINE ERROR RETURN?
	BNE	3$			; NO
	MOV	R0	,@10(R5)	; YES
3$:	ADD	#10	,SP		;FIX THE STACK POINTER
	RTS	PC
.SBTTL	EDIT RECORD			14-APR-81/16-APR-81.

;16-APR-81	ORIGINAL CREATION.


.SBTTL	END				14-APR-81/.

	.END
                                                                                                                                                                                                  