.;	DOKUMENTATION P] HUR MCR-FUNKTIONEN "SAT" FUNGERAR.
.;
.;	HISTORIK:
.;	DATUM	NAMN				ORSAK
.;	830216	LARS-G\RAN OLSSON VD/TEL 594438	URUPPF\RANDE
.;	830529		-"-			FLER FELKONTROLLER
.;			-"-			/TM - P] LST-FIL
.;			-"-			AUTOM. HUVUD P] CMD-FIL
.;	830927		-"-			/-WR - P] LST-FIL
.;						VARNINGAR KAN F]S
.;						EXITSTATUS S[TTS
.;						FLER SEKTION-TESTER
.;						NY LAYOUT P] LST-FIL
.;
.;	FUNKTION:
.;	SAT L[SER STRUKTURERAD INFIL OCH SKAPAR KOMMANDOFIL OCH LISTFIL.
.;
.;	ANROP:
.;	>SAT FIL1,FIL2=FIL3
.;
.;	FIL1:	UTFIL SOM SKAPAS - DEFAULT EXTENSION .CMD
.;	FIL2:	UTFIL SOM SKAPAS - DEFAULT EXTENSION .LST
.;		MINST 1 AV OVANST]ENDE UTFILER M]STE SPECIFICERAS!
.;		EV. FEL SKRIVS P] DENNA FIL.
.;	FIL3:	INFIL - DEFAULT EXTENSION .SAT
.;
.;	SAMTLIGA FILNAMN SKRIVS SOM STANDARD-FILNAMN, DVS ENLIGT:
.;	DEV:[UIC]FILSPEC.EXT
.;	DEFAULT DEVICE : SY:
.;	DEFAULT UIC    : NUVARANDE
.;
.;	SWITCHAR:
.;	/TM 	-P] LST-FILEN GER TABMARKS P] LISTAN.
.;	/-WR	-P] LST-FILEN GER INGA VARNINGAR P] LISTAN
.;
.;	INGA ANDRA SWITCHAR TILL]TNA
.;
.;	KONTROLLER:
.;	VISSA SYNTAXKONTROLLER SKER I SAT. VID FEL SKRIVS EN FELUTSKRIFT
.;	P] LISTFILEN. FELUTSKRIFTER LIGGER NORMALT P] RADEN EFTER FELET.
.;	TOTALT ANTAL FEL OCH VARNINGAR VISAS D] PROGRAMMET G\R EXIT.
.;
.;	EXITSTATUS S[TTS ENLIGT
.;	0	VARNING
.;	1	OK
.;	2	FEL
.;	4	KATASTROF
.;
.;	KOMMENTARER:
.;	KOMMENTARER P] ICKE-STRUKTURERADE KOMMANDON SKRIVS SOM I AT. , DE
.;	SKYFFLAS BARA \VER. KOMMENTARER P] STRUKTURERADE KOMMANDON SKRIVS
.;	SKRIVS MED "!KOMMENTAR". DENNA KOMMENTAR L[GGS SEDAN UT I CMD-FILEN
.;	ENLIGT - .;KOMMENTAR.
.;
.;	STRUKTURERADE KOMMANDON
.;
.;	'POSIT'-'ADMIT'-'ENDPOSIT'-'QUIT'-'QUITIF'
.;
.;	'WHILE'-'ENDDO'-'BREAK'-'BREAKIF'
.;
.;	'IF'-'ELSIF'-ELSE'-'ENDIF'
.;
.;	'CASE'-'WHEN'-'OTHER'-'ENDCASE'
.;
.;	'PERFORM'-'SECTION'-'ENDSECT'
.;
.;	'PAGE'
.;
.;	OBS: ALLA VILLKOR TILL STRUKTURERADE KOMMANDON SKALL ANGIVAS KOMPLETT!
.;
.;	     ANG. 'CASE' SE EXEMPEL NEDAN!
.;
.;	BEGR[NSNINGAR:
.;	F\LJANDE BEGR[NSNINGAR FINNS IDAG:
.;		1. MAX 200 SEKTIONER I EN MODUL
.;		2. MAX 50 NIV]ER (AKTIVA) P] VARJE STRUKTUR-TYP
.;			(POSIT-ENDPOSIT, IF-ENDIF, OSV)
.;		3. MAX CA. 7000 STRUKTURERADE KOMMANDON I EN MODUL
.;		4. MAX 255 TECKEN/RAD VID INL[SNING/UTSKRIFT
.;		5. STRUKTURERADE KOMMANDON SKALL ALLTID ST] P] POS 9 (TAB)
.;		   ELLER SENARE P] RADEN. OM DET PLACERAS SENARE [N POS 9
.;		   S] M]STE RADEN VARA BLANK FRAM TILL KOMMANDOT.
.;	SNABBHET:
.;		F\LJANDE MILJ\ VAR TILLG[MGLIG VID SNABBHETSTEST:
.;		DISK	- RA80
.;		INFIL	- 320 RADER (VARAV 80 STRUKT. KOM) - 15 BLOCK
.;		UTFIL1	- 420 RADER			- 20 BLOCK
.;		UTFIL2	- 350 RADER			- 25 BLOCK
.;
.;		EXEKVERINGSTID	- 20 SEK
.;
.;	EXEMPEL P] HUR INFILEN KAN SE UT.
.;
.;	INFILEN SATEX.SAT
.;
	.ENABLE SUBSTITUTION
	.ENABLE GLOBAL
	.SETS FIL ""
	'PERFORM' FILIN
	'WHILE'.IF FIL NE ""
		'POSIT'		!OK
			.TESTFILE 'FIL'
			'QUITIF'.IF <FILERR> NE 1	!FILEN SAKNAS
			.OPENR #0 'FIL'
			.SETN I 1.
			'PERFORM' LAESRAD
			'WHILE'.IFF <EOF>	!FLER RADER
				'PERFORM' SKRIV
				.INC I
				'BREAKIF'.IF I GT 100	!VI AVBRYTER
				'PERFORM' LAESRAD
			'ENDDO'
			.CLOSE #0
		'ADMIT'		!FEL
;			FILEN 'FIL' SAKNAS.
		'ENDPOSIT'
	'PERFORM' FILIN
	'ENDDO'
	.EXIT
	'PAGE'
	'SECTION' FILIN
.;
	.ASKS FIL :FILNAMN ..
.;
	'ENDSECT'
	'PAGE'
	'SECTION' LAESRAD
.;
	.READ #0 RAD
.;
	'ENDSECT'
	'PAGE'
	'SECTION' SKRIV
.;
	'IF'.IF I GT 10.		!SPECIALRADER
;			!TUTA
	'ELSIF'.IF I EQ 1.	! V[LDIGT SPECIELL RAD
;		***RAD 1***
;		
;		
;		
	'ELSE'
		'CASE' I
		'WHEN' 2.
			;RAD 2
		'WHEN' 3.
			;RAD 3
		'WHEN' 4.
			;RAD 4
		'OTHER'
			;NO ACTION
		'ENDCASE'
	'ENDIF'
;	'RAD'
.;
	'ENDSECT'