.NLIST
.MACRO	SUPER
;;;;;	V011	10-AUG-76
;
	$DIDDO=0
	$L$=0
	$T=0
	$L=0
	$LL=0
	$R=-1
	IIII=-1
	.LIST	TTM
R6=%6
R7=%7
RTNVAL=%0
;
.MACRO	..PUSH	AA1,AA2
	IIII=IIII+1
	.IRP	TT,\IIII
		TYPS'TT = AA1
		LBLS'TT = AA2
	.ENDM
.ENDM
.MACRO	..POP	AA1,AA2
	.IIF LT IIII,.ERROR IIII ;STACK UNDERFLOW!!!!!!;
	.IRP	TT,\IIII
		AA1 = TYPS'TT
		AA2 = LBLS'TT
	.ENDM
	IIII=IIII-1
.ENDM
.MACRO	..TAG	TG,WH
.EMITL	<WH''TG':;;;;;;>
.ENDM
;
.MACRO	..BRAN	BRA,TG,WH,SPLBRN
.IF NB <SPLBRN>
	.IF GE .-WH'TG-126.
		.EMIT	<JMP WH''TG>
	.IFF
		.EMIT	<BRA WH''TG>
	.ENDC
.IFF
	.EMIT	<BRA WH''TG>
.ENDC
.ENDM
;
.MACRO	.EMIT	VAL
$E$=1
	.IIF	DF	LST$$	.LIST MEB
								VAL
	.IIF	DF	LST$$	.NLIST MEB
.ENDM
;
.MACRO	.EMITL	VAL
	.IIF	DF	LST$$	.LIST
							VAL
	.IIF	DF	LST$$	.NLIST
.ENDM
;
.MACRO	.EMITR	S1,S2
	.EMIT	<S1>
	.IIF	GT	S2-1	.EMITR	<S1>,\S2-1
.ENDM
.MACRO	.IFOPR	OPRA,RELA,TTG
	.EMIT	OPRA
	.IF	GT	$R
		.IIF	EQ	$L$	.EMIT	<B'RELA L'TTG>
		.IIF	EQ	$L$-1	.EMIT	<B'RELA B'TTG>
		.IIF	EQ	$L$-2	.EMIT	<B'RELA E'TTG>
		.IIF	EQ	$L$-3	.EMIT	<B'RELA TTG>
	.IFF
		.IIF	EQ	$L$	.EMIT	<R'RELA L'TTG>
		.IIF	EQ	$L$-1	.EMIT	<R'RELA B'TTG>
		.IIF	EQ	$L$-2	.EMIT	<R'RELA E'TTG>
		.IIF	EQ	$L$-3	.EMIT	<R'RELA TTG>
	.ENDC
	..PUSH	0,$T
	$I$=1
.ENDM
.MACRO	.IS	Q1,Q2,QB,QT
$I$=0
	.IIF	IDN	<TRUE>	<Q2>,	.IFOPR <<TST'QB Q1>>,NE,QT
	.IIF	IDN	<FALSE>	<Q2>,	.IFOPR	<<TST'QB Q1>>,EQ,QT
	.IIF	NE	$I$		.MEXIT
	.IIF	DIF	<RESULT>,<Q1>,.IFOPR <<TST'QB Q1>>,Q2,QT
	.IIF	IDN	<RESULT>,<Q1>,.IFOPR <<.=.>>,Q2,QT
.ENDM
;
.MACRO	.GENBR	A1,B1,C1,D1,E1
$I$=0
.IIF	IDN	<SET.IN>	<B1>	.IFOPR <<BIT'D1 A1,C1>>,NE,E1
.IIF	IDN	<OFF.IN>	<B1>	.IFOPR <<BIT'D1 A1,C1>>,EQ,E1
.IIF	IDN	<NOT.SET.IN>	<B1>	.IFOPR <<BIT'D1 A1,C1>>,EQ,E1
.IIF	IDN	<#0>		<C1>	.IFOPR <<TST'D1 A1>>,B1,E1
.IIF	IDN	<#0>		<A1>	.IFOPR <<TST'D1 C1>>,B1,E1
.IIF	IDN	<IS>		<B1>	.IS A1,C1,D1,E1
.IIF	IDN	<=>		<B1>	.IFOPR <<CMP'D1 A1,C1>>,EQ,E1
.IIF	EQ	$I$			.IFOPR <<CMP'D1 A1,C1>>,B1,E1
.ENDM
.MACRO	.OPADD	V1,V2,V3
	.IIF	IDN	<V2>	<#1>	.EMIT	<INC'V3 V1>
	.IIF	NE	$E$		.MEXIT
	.IIF	IDN	<V2>	<CARRY>	.EMIT	<ADC'V3 V1>
	.IIF	NE	$E$		.MEXIT
	.EMIT	<ADD V2,V1>
.ENDM
;
;
.MACRO	.OPSUB	V1,V2,V3
	.IIF	IDN	<V2>	<#1>	.EMIT	<DEC'V3 V1>
	.IIF	NE	$E$		.MEXIT
	.IIF	IDN	<V2>	<CARRY>	.EMIT	<SBC'V3 V1>
	.IIF	NE	$E$		.MEXIT
	.EMIT	<SUB V2,V1>
.ENDM
.MACRO	RNE	LOC
.EMIT	<BEQ LOC>
.ENDM
.MACRO	REQ	LOC
.EMIT	<BNE LOC>
.ENDM
.MACRO	RLT	LOC
.EMIT	<BGE LOC>
.ENDM
.MACRO	RGE	LOC
.EMIT	<BLT LOC>
.ENDM
.MACRO	RGT	LOC
.EMIT	<BLE LOC>
.ENDM
.MACRO	RLE	LOC
.EMIT	<BGT LOC>
.ENDM
.MACRO	RPL	LOC
.EMIT	<BMI LOC>
.ENDM
.MACRO	RMI	LOC
.EMIT	<BPL LOC>
.ENDM
.MACRO	RHI	LOC
.EMIT	<BLOS LOC>
.ENDM
.MACRO	RLOS	LOC
.EMIT	<BHI LOC>
.ENDM
.MACRO	RHIS	LOC
.EMIT	<BLO LOC>
.ENDM
.MACRO	RLO	LOC
.EMIT	<BHIS LOC>
.ENDM
.MACRO	RCS	LOC
.EMIT	<BCC LOC>
.ENDM
.MACRO	RCC	LOC
.EMIT	<BCS LOC>
.ENDM
.MACRO	IF	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	.IIF	B	<A>	.MEXIT
	$F$=0
	.IIF	IDN	<BE>	<:=>	$F$=1
	.IIF	IDN	<BE>	<:B=>	$F$=1
	.IF	NE	$F$
	.IFARI A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	.MEXIT
	.ENDC
$O$=0
$I$=0
	.IIF	IDN	<LEAVE> <EE>	.LEAVE	A,BE,C,BB,F
	.IIF	NE	$I$		.MEXIT
	.IIF	IDN	<GOTO>	<EE>	.GOTO	A,BE,C,BB,F
	.IIF	NE	$I$		.MEXIT
	.IIF	IDN	<D>	<OR>	.OR	A,BE,C,BB
	.IIF	IDN	<D>	<ORB>	.OR	A,BE,C,BB
	.IF EQ	$O$
		.IIF EQ $L$-1	.GENBR A,BE,C,BB,\$T2
		.IIF NE $L$-1	.GENBR A,BE,C,BB,\$T
	.ENDC
$T=$T+1
	.IIF	B	<D>,.MEXIT
	.IIF	B	<EE>,.MEXIT
;
	D	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	.IIF	LE	$DIDDO	.MEXIT
..POP	$$T,$$T
..TAG	\$$T,L
$DIDDO=$DIDDO-1
.ENDM
.MACRO	.OR	OA,OB,OC,OD
	$R=-$R
	$O$=1
	$SV$=$L$
	$L$=0
 .IIF NE $L$-1   	.GENBR	OA,OB,OC,OD,\$T
 .IIF EQ $L$-1   	.GENBR	OA,OB,OC,OD,\$T2
	$L$=$SV$
	$R=-$R
.ENDM
;
.MACRO	.IFARI	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	.SIMPLE A,BE,C,D,EE
	.IIF	IDN <D> <IS>	IF RESULT,IS,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	.IIF	IDN <D> <IS>	.MEXIT
	.IIF	IDN <EE> <IS>	IF RESULT,IS,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	.IIF	IDN <EE> <IS>	.MEXIT
	IF	RESULT,IS,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
.ENDM
;
;
;
.MACRO	.LEAVE	LA,LB,LC,LD,LE
	$L$=2
	.IIF	B	<LE>		$K$=$LL
	.IIF	NB	<LE>		$K$=LE
	$R=-$R
	.GENBR	LA,LB,LC,LD,\$K$
	..POP	$$TT,$$TT
	$R=-$R
	$L$=0
.ENDM
;
;
.MACRO	.GOTO	GA,GB,GC,GD,GEE
	$R=-$R
	$L$=3
	.GENBR	GA,GB,GC,GD,GEE
	..POP	$$TT,$$TT
	$R=-$R
	$L$=0
.ENDM
.MACRO	OR	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	.IIF	B	<EE>	.MEXIT
	.IIF	IDN	<H>	<OR>	..POP	$T1,$T
	.IIF	IDN	<H>	<ORB>	..POP	$T1,$T
	IF'BB	EE,F,G,H
	.IF	DIF	<H>	<OR>
	.IF	DIF	<H>	<ORB>
	..POP	$$TT,$$TT
	..POP	$$T,$$T
	..TAG	\$$T,L
	.IIF	B	<H>	..PUSH	0,$$TT
	.IIF	B	<H>	.MEXIT
	.IIF	IDN 	<H>	<THEN>  ..PUSH 0,$$TT
	.IIF	IDN	<H>	<THEN>  .MEXIT
	H	I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	..TAG	\$$TT,L
	$DIDDO=0
	.MEXIT
	.ENDC
	.ENDC
	H	I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
.ENDM
;
;
.MACRO	AND	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	.IIF	B	<EE>	.MEXIT
	$$S=0
	.IIF	IDN	<ORB>,<H>,$$S=1
	.IIF	IDN	<OR>,<H>,$$S=1
	.IF	GT	$$S
	..POP	$$T,$$T
	IF'BB	EE,F,G,H
	..TAG	\$$T,L
	H	I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	.IFF
	..POP	$T,$T
	IF'BB	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	.ENDC
.ENDM
;
;
.MACRO	DO	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	.IIF	B	<EE>,.MEXIT
		LET EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	$DIDDO=$DIDDO+1
.ENDM
;
;
.MACRO	THEN EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	.IIF	B	<EE>	.MEXIT
	EE F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	$DIDDO=$DIDDO+1
.ENDM
.MACRO	ELSE
	..POP	$T1,$T2
	.IIF	NE	$T1,.ERROR $T1 ;ELSE SEEN IN OTHER THAN IF BLOCK;
	..BRAN	BR,\$T,L
	..TAG	\$T2,L
	..PUSH	$T1,$T
	$T=$T+1
.ENDM
.MACRO	WHILE A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z,BB
	$DIDDO=-1
	..TAG	\$L,B
 IF A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z,BB
	.IF	EQ	$DIDDO
		..BRAN	BR,\$L,B
		..POP	$$T,$$T
		..TAG	\$$T,L
	.IFF
		..PUSH	1,$L
		$LL=$L
	.ENDC
	$DIDDO=0
	$L=$L+1
.ENDM
.MACRO	CASE	A,BBB,C
	.IIF	DIF	<A>	<TOP>	.EMIT	<MOV A,-(SP)>
	.EMIT	<ASL @SP>
	.IRP	TT,\$T
	.EMIT	<JSR PC,L'TT>
		.ENDM
	..PUSH	4,$T
	$T=$T+1
.ENDM
.MACRO	FOR	A,BBB,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
 .IIF DIF <F>,<BY>,FOR A,BBB,C,D,EE,BY,#1,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X
 .IIF DIF <F>,<BY>,.MEXIT
;
	.SIMPLE	A,BBB,C
	..TAG	\$L,B
	.IF B <H>
		..PUSH	2,$L
		$LL=$L
		.IRP	TT,\<$L>
			.MACRO	$.$'TT
				D	A,EE,G,TT
			.ENDM
		.ENDM
	.IFF
		$SDO=$DIDDO
		H I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
		D A,EE,G,\$L
		.IIF GT $DIDDO-$SDO $DIDDO=$DIDDO-1
	.ENDC
	$L=$L+1
.ENDM
.MACRO	TO	A1,A2,A3,A4
	$E$=0
	.OPADD	A1,A3
	.EMIT	<CMP A1,A2>
	.EMIT	<BLE B'A4>
	.EMITL	<E'A4:;;;;;;;>
.ENDM
.MACRO	DOWNTO	A1,A2,A3,A4
	$E$=0
	.OPSUB	A1,A3
	.EMIT	<CMP A1,A2>
	.EMIT	<BGE B'A4>
	.EMITL	<E'A4:;;;;;;;>
.ENDM
.MACRO	REPEAT	A,BB,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
	.IF	IDN	<A>	<THRU>
	THRU	BB,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V
	.MEXIT
	.ENDC
	..TAG	\$L,B
	..PUSH	5,$L
	$LL=$L
	$L=$L+1
	.IIF	B	<A>	.MEXIT
	.IF	IDN	<A>	<UNTILB>	
	UNTILB BB,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
	.MEXIT
	.ENDC
	.IF	IDN	<A>	<UNTIL>	
	UNTIL BB,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
	.MEXIT
	.ENDC
	LET A,BB,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
.ENDM
.MACRO	UNTIL  A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	$L$=1
	..POP	$T1,$T2
	.IF	NE	$T1-5
	.ERROR	; UNTIL SEEN IN OTHER THAN REPEAT BLOCK;
	.MEXIT
	.ENDC
	IF A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,BB
	..POP	$$T,$$T
	..TAG	\$T2,E
	$L$=0
.ENDM
.MACRO	THRU	A,BB,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V
	.NTYPE	A3,A
	.IF	NE	A3&70
	.ERROR	; A MUST BE A REGISTER;
	.MEXIT
	.ENDC
	.IIF	NB	<BB>,LET A,BB,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V
	..TAG	\$L,B
	..PUSH	6,$L
	$LL=$L
	.IRP	TT,\$L
	.MACRO	$.$'TT
	.EMIT	<SOB A,B'TT ; **** EIS INST.>
	.ENDM
	.ENDM
	$L=$L+1
.ENDM
.MACRO	END   COMM
	..POP	$T1,$T2
	.IIF	EQ	$T1	..TAG	\$T2,L	;-0- 	IF
	.IIF	EQ	$T1	.MEXIT
;
	$LL	=	$LL -1
	.IIF	EQ	$T1-3	..TAG	\$T2,E	;-3-	BEGIN/END
	.IIF	EQ	$T1-3	.MEXIT
;
	.IIF	EQ	$T1-5	..BRAN  BR,\$T2,B,1	;-5-	REPEAT
	.IIF	EQ	$T1-5	..TAG	\$T2,E		
	.IIF	EQ	$T1-5	.MEXIT
;
	.IF	EQ	$T1-1			;-1-	WHILE
		..BRAN	BR,\$T2,B,1
		..POP	$$T,$$T
		..TAG	\$$T,L
		..TAG	\$T2,E
		.MEXIT
	.ENDC
;
	.IF	EQ	$T1-2			;-2-	REPEAT/FOR
		.IRP	TT,<\$T2>
			$.$'TT
		.ENDM
	.MEXIT
	.ENDC
;
	.IF	EQ	$T1-4			;-4-	CASE
		$LL = $LL + 1
		..TAG	\$T2,L
		.EMIT	<ADD (SP)+,@SP>
		.EMIT	<MOV @(SP)+,-(SP)>
		.EMIT	<JSR PC,@(SP)+>
		.MEXIT
	.ENDC
;
	.IF	EQ	$T1-6			; -6- THRU (REPEAT THRU)
	.IRP	TT,\$T2
	$.$'TT
	.ENDM
	..TAG	\$T2,E
	.MEXIT
	.ENDC
;
	.ERROR		; $T STRANGE SUPER-MAC STACK VALUE;
.ENDM
;
.MACRO	BEGIN	BNAME
	.IIF NB	<BNAME>		BNAME=$L
	..PUSH	3,$L
	..TAG	\$L,B
	$LL = $L
	$L=$L+1
.ENDM
.MACRO	$$END
	.IF	GE	IIII
		.PRINT	; MISSING END
		END
		$$END
	.ENDC
.ENDM
.MACRO	LEAVE AAAA,A,BB,C,D,EE,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V
.IF B <AAAA>
	.IRP	QQ,\<$LL>
	.EMIT <BR E'QQ>
	.ENDM
	.MEXIT
.ENDC
	.IRP	QQ,\AAAA
	.EMIT	<BR E'QQ>
	.ENDM
.ENDM
;
;
.MACRO	JUMPTO	AAAA,A,B,C,D,E,F,H,G,I,J,K,L,M,N,O,P,Q,R,S,T,U,V
.EMIT	<JMP AAAA>
.ENDM
;
.MACRO	GOTO	BBBB
.EMIT	<BR BBBB>
.ENDM
;
.MACRO	PUSH	P0,P1,P2,P3,P4,P5,P6,P7,P8,P9,Q1,Q2,Q3,Q4,Q5,Q6,Q7,Q8,Q9,Q10,Q11,Q22
	.IF NB P0
	.EMIT	<MOV P0,-(SP)>
	PUSH	P1,P2,P3,P4,P5,P6,P7,P8,P9
	.ENDC
.ENDM
;
.MACRO	POP	P0,P1,P2,P3,P4,P5,P6,P7,P8,P9,Q0,Q1,Q2,Q3,Q4,Q5,Q6,Q7,Q8,Q9,Q22
	.IF NB P0
	.EMIT	<MOV (SP)+,P0>
	POP	P1,P2,P3,P4,P5,P6,P7,P8,P9
	.ENDC
.ENDM
.MACRO	SCALL	NAME,ARGS,WHERE,TYPE,A,BB,C,D,E,F,G,H,I,J,K,LL,M,N,O,P,Q,RR,S
; NOTE: **** WHERE AND TYPE NOT IMPLEMENTED ****
	.IIF	B	<ARGS>	.EMIT	<JSR PC,NAME>
	.IIF	B	<ARGS>	.MEXIT
	.IF	NB	WHERE
	.ERROR	; WHERE .... ARG'S MUST BE WITHIN <>;
	.MEXIT
	.ENDC
.$T=0
.MACRO	$GENM	BBT,BBP
	.IIF	GT	BBP-5	.ERROR	; 6 ARG MAX (R0-R5);
	.IIF	GT	BBP-5	.MEXIT
	.IIF	DIF	<BBT> <R'BBP>	.EMIT	<MOV BBT,R'BBP>
.ENDM
	.IRP	T,<ARGS>
	.IIF	NB	T	$GENM	T,\.$T
	.$T=.$T+1
	.ENDM
	.EMIT	<JSR PC,NAME>
.ENDM
.MACRO	RETURN	STA,REG,A,BE,C,D,E,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE
	.IIF	B	<STA>	.EMIT	<RTS PC>
	.IIF	B	<STA>	.MEXIT
	.IIF	IDN	<ERROR> <STA>	.EMIT	<SEC>
	.IIF	IDN	<NOERROR> <STA> .EMIT	<CLC>
	.IIF	IDN	<WITH>	<STA>	.EMIT	<MOVB REG,-(SP)>
	.IIF	IDN	<WITH>	<STA>	.EMIT	<ROLB (SP)+>
	.IIF	NB	<REG>		.EMIT	<RTS REG>
	.IIF	B	<REG>		.EMIT	<RTS PC>
.ENDM
.MACRO	LET	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V
    .IF IDN	<C>	<.>
	.SIMPLE A,BE,A,D,EE
    .IFF
	.SIMPLE	A,BE,C,D,EE
    .ENDC
	.IIF	B		<D>	.MEXIT
	.IIF	B		<EE>	.MEXIT
	.IIF	B		<F>	.MEXIT
	.IF	LT	$Y$
		LET A,BE,A,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V
		.MEXIT
	.ENDC
		LET  A,BE,A,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V
.ENDM
.MACRO	.SIMPLE	X1,X2,X3,X4,X5,X6
	.IF IDN <X2> <:B=>
	.SIMPLE	X1,:=,X3,X4,X5,B
	.MEXIT
	.ENDC
$Y$=0
$Z$=0
	.IIF	IDN	<FALSE>	<X3>	$Y$=7
	.IIF	IDN	<0>	<X3>	$Y$=7
	.IIF	IDN	<#0>	<X3>	$Y$=7
	.IIF	IDN	<TRUE>	<X3>	$Y$=4
	.IIF	IDN	<NOT>	<X3>	$Y$=-1
;
	.IIF	IDN	<?>	<X3>	$Y$=-1
	.IIF	IDN	<->	<X3>	$Y$=-2
  .IF	DIF	<X1> <X3>
	.IIF	EQ	$Y$-7		.EMIT	<CLR'X6 X1>
	.IIF	EQ	$Y$-4		.EMIT	<MOV'X6 #-1,X1>
	.IIF	EQ	$Y$		.EMIT	<MOV'X6 X3,X1>
  .ENDC
  .IF	DIF	<X1> <X4>
	.IIF	LT	$Y$		.EMIT	<MOV'X6 X4,X1>
  .ENDC
	.IIF	IDN	<+1>	<X4>	$Y$=-5
	.IIF	IDN	<-1>	<X4>	$Y$=-6
	.IF	LT	$Y$
		.IIF	EQ	$Y$+1	.EMIT	<COM'X6 X1>
		.IIF	EQ	$Y$+2	.EMIT	<NEG'X6 X1>
		.IIF	EQ	$Y$+5	.EMIT	<INC'X6 X1>
		.IIF	EQ	$Y$+6	.EMIT	<DEC'X6 X1>
		.MEXIT
	.ENDC
;
	.IIF	B	<X4>		.MEXIT
	.IIF	IDN	<X4>	<IS>	.MEXIT
$E$=0
	.IIF	EQ	$E$		.ARITH	X1,X5,X6,X4
.ENDM
;
.MACRO	.ARITH	Y1,Y2,Y3,Y4
	.IIF	IDN	<+>	<Y4>	.OPADD	Y1,Y2,Y3
	.IIF	IDN	<->	<Y4>	.OPSUB	Y1,Y2,Y3
	.IIF	NE	$E$		.MEXIT
	.IIF	IDN	<NAND>	<Y4>	.EMIT	<BIC'Y3 Y2,Y1>
	.IIF	IDN	<AND.NOT> <Y4>	.EMIT	<BIC'Y3 Y2,Y1>
	.IIF	IDN	<OFF.BY> <Y4>	.EMIT	<BIC'Y3 Y2,Y1>
	.IIF	NE	$E$		.MEXIT
	.IIF	IDN	<CLEARED.BY> <Y4> .EMIT	<BIC'Y3 Y2,Y1>
	.IIF	IDN	<CLR.BY> <Y4>	.EMIT	<BIC'Y3 Y2,Y1>
	.IIF	IDN	<SET.BY> <Y4>	.EMIT	<BIS'Y3 Y2,Y1>
	.IIF	IDN	<OR>	<Y4>	.EMIT	<BIS'Y3 Y2,Y1>
	.IIF	NE	$E$		.MEXIT
	.IIF	IDN	<L.SHIFT> <Y4>	.EMITR	<ASL'Y3 Y1>,Y2
	.IIF	IDN	<R.SHIFT> <Y4>	.EMITR	<ASR'Y3 Y1>,Y2
	.IIF	IDN	<L.ROTATE> <Y4>	.EMITR	<ROL'Y3 Y1>,Y2
	.IIF	IDN	<R.ROTATE> <Y4>	.EMITR	<ROR'Y3 Y1>,Y2
	.IIF	NE	$E$		.MEXIT
	.IF	IDN	<*>	<Y4>
		.NTYPE	MFH$T,Y1
		.IF EQ MFH$T&1
			.ERROR	;'Y1' IS NOT A SINGLE PRECISION REGESTER;;
		.IFF
			.EMIT	<MUL Y2,Y1 ; **** EIS INST.>
		.ENDC
	.ENDC
	.IF	IDN	<**>	<Y4>
		.NTYPE	MFH$T,Y1
		.IF NE MFH$T&1
			.ERROR	;'Y1' IS NOT A DOUBLE PRESISION REGESTER;;
		.IFF
			.EMIT	<MUL Y2,Y1 ; **** EIS INST.>
		.ENDC
	.ENDC
	.IIF	IDN	</>	<Y4>	.EMIT	<DIV Y2,Y1 ; **** EIS INST.>
	.IIF	IDN	<SHIFT>	<Y4>	.EMIT	<ASH Y2,Y1 ; **** EIS INST.>
	.IIF	IDN	<C.SHIFT> <Y4>	.EMIT	<ASHC Y2,Y1 ; **** EIS INST.>
	.IIF	NE	$E$		.MEXIT
	.IIF	IDN	<XOR>	<Y4>	.EMIT	<XOR Y2,Y1 ; **** EIS INST.>
	.IIF	EQ	$E$		.ERROR	; Y4 NOT A LEGAL OPERATOR;
.ENDM
;
;
;
.MACRO	ORB	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	OR	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,B
.ENDM
;
.MACRO	ANDB	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	AND	EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,B
.ENDM
;
.MACRO	IFB	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z
	IF	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,TE,U,V,W,X,Y,Z,B
.ENDM
;
;
.MACRO	UNTILB A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
	UNTIL	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z,B
.ENDM
;
.MACRO	WHILEB A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
	WHILE	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z,B
.ENDM
;
.MACRO	ON.NOERROR	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S
	IF RESULT IS,CC,A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S
.ENDM
;
.MACRO	ON.ERROR	A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S
	IF RESULT IS,CS,A,BE,C,D,EE,F,G,H,I,J,K,LL,M,N,O,P,Q,R,S
.ENDM
.MACRO	FI	COMM
	END	<COMM>
.ENDM
;
.MACRO	PROCEDURE	NAME	ARGS	COMM
	.EMIT	<.TITLE NAME>
	.EMIT	<.PSECT NAME>
	.EMIT	<.GLOBL NAME>
	.EMITL	<NAME':>
	.IIF DF DEBUG$	.EMIT	<BPT>
.ENDM
;
.MACRO 	ENDPROCEDURE	COMM
	.EMIT	<RTS PC>
.ENDM
;
.MACRO	FORMAT BUF,PIC,A,B,C,D,E,F,G,H,?LAB1,?LAB
	BR	LAB
LAB1:	.ASCIZ	\PIC\
	.EVEN
LAB:
	MOV	R0,-(SP)
	MOV	R3,-(SP)
.IIF NB <H>,	MOV	H,-(SP)
.IIF NB <G>,	MOV	G,-(SP)
.IIF NB <F>	MOV	F,-(SP)
.IIF NB <E>,	MOV	E,-(SP)
.IIF NB <D>,	MOV	D,-(SP)
.IIF NB <C>,	MOV	C,-(SP)
.IIF NB <B>,	MOV	B,-(SP)
.IIF NB <A>,	MOV	A,-(SP)
	MOV #LAB1,R1
	.GLOBL	$FORMAT
.IIF NB <BUF>,	MOV BUF,R2
	JSR PC,$FORMAT
	MOV	(SP)+,R3
	MOV	(SP)+,R0
.ENDM
.MACRO ACCEPT	BUF,LEN,NCHRS,EOF,ERR
.MCALL	QIO$S,WTSE$S
	.IF B LEN
		ACCEPT BUF,#80.,NCHRS,EOF,ERR
	.IFF
	.IF NB EOF'NCHRS'ERR
		SUB #4,SP
		MOV SP,R5
			QIO$S #IO.RLB,CONSOL,#1,,R5,,<BUF,LEN>
		WTSE$S	#1
		.IF NB NCHRS
			LET NCHRS := 2(R5)
		.ENDC
		.IF NB EOF
			IFB (R5) EQ #IE.EOF
				LET SP := SP + #4
				JUMPTO EOF
			ELSE
				LET SP := SP + #4
			END
		.ENDC
		.IF NB ERR
			IFB (R5) LT #0 THEN GOTO ERR
		.ENDC
	.IFF
			QIO$S #IO.RLB,CONSOL,#1,,,,<BUF,LEN>
		WTSE$S	#1
	.ENDC
	.ENDC
.ENDM
.MACRO	PRINT	BUF,LEN,FORMS
.MCALL	QIO$S,WTSE$S
	.IF NB FORMS
		QIO$S #IO.WLB,CONSOL,#1,,,,<BUF,LEN,FORMS>
	.IFF
		QIO$S #IO.WLB,CONSOL,#1,,,,<BUF,LEN,#"40>
	.ENDC
	WTSE$S	#1
.ENDM
.MACRO PUTLINE LUN,ADDRS,LEN,ERR
	.MCALL PUT$
	.IF B ERR
		PUTLINE LUN,ADDRS,LEN,B$IOERROR
	.IFF
		PUSH R0,R1,R2,R3
		LET R2 := LUN
		LET R3 := @#$OTSV
		SCALL $FCHNL
		LET R0 := R0 + #14
		IFB F.FACC(R0) EQ #0
			LET R1 := #ERR
			SCALL B$OPENFOR
		END
		PUT$ R0,ADDRS,LEN,ERR
		POP R3,R2,R1,R0
	.ENDC
.ENDM
.MACRO	BEGINMAIN	NAME
.PSECT NAME
NAME'::
.ENDM
.MACRO	ENDMAIN	NAME
.MCALL	EXIT$S
	EXIT$S
.ENDM
.MACRO	FCALL	NAME,A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V
$NARGS=0
$NSTK=0
$LITNO=0
	PUSH R5
	$STFARG	A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V
	PUSH	#$NARGS
	$NSTK=$NSTK+2
	MOV SP,R5
	JSR	PC,NAME
	ADD #$NSTK,SP
	POP R5
.ENDM
.MACRO	$STFARG	A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V
	.IF NB A
		.NTYPE $SYM,A
		.IF NE $SYM-67
			PUSH A
			$NSTK=$NSTK+2
			$LITNO=$LITNO+2
			$STFARG B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V
			MOV SP,R5
			ADD #$NSTK-$LITNO,R5
			PUSH R5
			$NSTK=$NSTK+2
			$LITNO=$LITNO-2
			$NARGS=$NARGS+1
		.IFF
			$STFARG B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V
			PUSH #A
			$NSTK=$NSTK+2
			$NARGS=$NARGS+1
		.ENDC
	.ENDC
.ENDM
.MACRO FORET VAL,DISP
	LET R0 := VAL
	IF (R5) GE #DISP/2
		IF DISP(R5) NE #-1
			LET @DISP(R5) := R0
		END
	END
.ENDM
.MACRO READVB	BLK,ADDR,ERR
    .IF B ERR
	READVB BLK,ADDR,B$IOERROR
    .IFF
.MCALL READ$,WAIT$
	PUSH R0
	LET IOPTR+2 := BLK
	READ$ RT.FDB(ROOT),ADDR,,#IOPTR,,#IOERR,,ERR
	WAIT$
	POP R0
    .ENDC
.ENDM
.MACRO WRITEVB	BLK,ADDR,ERR
    .IF B ERR
	WRITEVB BLK,ADDR,B$IOERROR
    .IFF
.MCALL WRITE$,WAIT$
	PUSH R0
	LET IOPTR+2 := BLK
	WRITE$ RT.FDB(ROOT),ADDR,,#IOPTR,,#IOERR,,ERR
	WAIT$
	POP R0
    .ENDC
.ENDM
.ENDM
	.LIST