.;
.;	LB:[1,2]MAIL.CMD f|r mottagning och s{ndning av MAIL och CIRKUL[R
.;
.;	HISTORIK:
.;	DATUM	NAMN			]TG[RD
.;	870212	B-E TAPPER		F[RDIGST[LLT F\R ALLM[NT BRUK
.;	870302	B-E TAPPER		" " I NAMN
.;	880728	B-E TAPPER		DECIMALA FILNAMNSVERSIONER + .SAT
.;	880801	B-E TAPPER		346 OKTALT = 230 DEDCIMALT !!
.;
.;
.;	V A R N I N G  ! ! ! .SAT-FIL FINNES, .CMF-FIL ANV[NDS. K\R @SAT !
.;
	.ENABLE SUBSTITUTION
	.DISABLE DISPLAY
	.ENABLE GLOBAL
	.ENABLE ESCAPE
	.DISABLE LOWERCASE
	.ENABLE DECIMAL
.;
	.SETS ALET "A"
	.SETS BLET "B"
	.SETS CLET "C"
	.SETS DLET "D"
	.SETS HLET "H"
	.SETS JLET "J"
	.SETS KLET "K"
	.SETS MLET "M"
	.SETS NLET "N"
	.SETS SLET "S"
	.SETS BLLET " "
.;
	'WHILE'.IFT <TRUE>
.;
	'POSIT'		<EJ SLUT
	;
	;MENY f|r hantering av MAIL och CIRKUL[R
	;
	;H=Hj{lp !
	;D=DEC-MAIL (Endast vissa anv{ndare)
	;C=L{sa eller h{mta in cirkul{r
	;B=L{sa, h{mta in eller makulera MAIL
	;S=Skicka MAIL eller cirkul{r
	;K=Kolla egen avs{nd MAIL (Kvittof|rteckning)
	;M=F|rteckning |ver m|jliga mottagare
	;A=Avsluta (]terg} till menyn f|r -96)
	;
	.ASKS VAD Ange bokstav>
	'QUITIF'.IF <STRLEN> EQ 0
.;
	'BREAKIF'.IF ALET EQ VAD[1:1]
	'IF'.IF HLET EQ VAD[1:1]
		'PERFORM' HELP
	'ELSIF'.IF DLET EQ VAD[1:1]
		'IF'.IFDF $MAI11
			MAI
		'ELSE'
			MAI
;DU [R INTE BEH\RIG ATT K\RA DEC-MAIL - KONTAKTA DATADRIFTEN TEL. 120
		'ENDIF'
	'ELSIF'.IF MLET EQ VAD[1:1]
		.GOSUB ANVAND
	'ELSIF'.IF KLET EQ VAD[1:1]
		'PERFORM' KOLLA
	'ELSE'
		.SETS UICS ""
		.SETF ALLA
		.ENABLE LOWERCASE
		.SETS BTYP "MAIL"
		.DISABLE LOWERCASE
		'IF'.IF BLET EQ VAD[1:1]
			'PERFORM' MAIL
		'ELSIF'.IF SLET EQ VAD[1:1]
			'PERFORM' SKICK
		'ELSE'
			.SETS UICS "DU:[200,50]"
			.SETT ALLA
			.ENABLE LOWERCASE
			.SETS BTYP "cirkul{r"
			.DISABLE LOWERCASE
			'IF'.IF CLET EQ VAD[1:1]
				'PERFORM' MAIL
			'ELSE'
	;'VAD' kunde jag inte f|rst}.
			'ENDIF'
		'ENDIF'
	'ENDIF'
.;
	'ADMIT'	<SLUT
	'ENDPOSIT'
.;
	'ENDDO'
.;
.;
	;
	.DISABLE DECIMAL
	.EXIT
.;
	'SECTION' HELP
	'POSIT'		<EJ SLUT
	;#6Litet HJ[LP med MAILhantering.
	;
	;Med MAIL kan Du kan ta emot , tabort och s{nda MAIL till/fr}n andra
	;anv{ndare av -96. Med MAIL menas i detta sammanhang ett stycke text avsett att
	;l{sas eller hanteras av en annan anv{ndare. MAIL som r|r ALLA kallas cirkul{r.
	;N{r Du "tar emot" ett MAIL f|rvandlar Du det till ett "dokument" och kan sedan
	;hantera det som vanligt. Om Du vill s{nda ett MAIL ska Du f|rst skapa ett
	;dokument p} vanligt s{tt och sedan g} in i MAILhanteringen.
	;
	;#6S[NDNING
	;MAILs{ndning tillg}r s}, att datorn kopierar ditt dokument och l{gger det p}
	;mottagarnas konton. Varje g}ng mottagaren g}r in i eller ut ur systemet kollar
	;det om MAIL finns p} hans/hennes konto. MAIL k{nns igen p} att namnet avslutas
	;med .BRV . Detta beh|ver Du inte t{nka p} - systemet sk|ter det.
	;Ett cirkul{r s{ndes p} samma s{tt som ett MAIL. Dock f}r inte mottagarna veta
	;i TRATTEN att det har kommit ett nytt cirkul{r. Vilka cirkul{r, som finnes kan
	;man bara f}r reda p} genom att titta i cirkul{rf|rteckningen. V{lj C i menyn.
	;
	;Mottagarf|rteckning kan du f} via menyn. V{lj M.
	;Mottagare f|r cirkul{r {r "ALLA". De lagras p} ett s{rskilt st{lle, och allts}
	;inte som ett MAIL f|r varje anv{ndare.
	;
.;
	.ASKS VAD Tryck <ESC> f|r }terg}ng till menyn, <RETURN> f|r mera hj{lp >
	'QUITIF'.IFT <ESCAPE>
.;
	;#6Mera HJ[LP med MAILhantering.
	;
	;#6MOTTAGNING
	;F|rst kan du skumma MAILet. Det inneb{r att texten i MAILet snabbt rullar fram.
	;Du kan stoppa f|rbifarten genom att trycka p} <NO SCROLL> och starta den igen
	;med en ny tryckning p} <NO SCROLL>.
	;Efter den snabba genoml{sningen kan Du f} MAILet utskrivet om Du vill.
	;
	;Du har sedan 3 m|jligheter:
	;	1. L}ta MAILet vara kvar f|r senare hantering.
	;	2. Kasta MAILet i papperskorgen
	;	3. F|rvandla MAILet till ett "dokument". I s} fall ska du ange det namn
	;	   som Du vill att dokumentet ska f} p} ditt konto.
	;Om du v{ljer 2) f|rsvinner MAILet. Om Du v{ljer 3) f|rvandlas MAILet till ett
	;dokument med det namn Du har gett det. Det kan sedan hanteras som alla andra
	;dokument. Hos avs{ndaren loggas vilket Du gjorde och n{r Du gjorde det.
	;EXEMPEL p} anv{ndning: Skapa brevet KALLE. Skicka det som MAIL till ANNIKA
	;f|r renskrift. ANNIKA r{ttar stavfel m.m., }s{tter diarienummer och skickar
	;KALLE som MAIL tillbaka till Dig f|r godk{nnande. Du skapar dokumentet KALLEOK
	;med ditt godk{nnande och s{nder det som MAIL till henne. Hon skriver ut det med
	;ordbehandlaren snyggt och prydligt p} Uppsalabuss brevpapper och diarief|r det
	;samt ombes|rjer postbfodran. (Det stod t.ex. i KALLEOK hur Du ville ha det.)
	.ASKS VAD Tryck <RETURN> f|r }terg}ng till menyn >
.;
	'ADMIT'
	'ENDPOSIT'
.;
	;
.;
	'ENDSECT'
.;
	'SECTION' KOLLA
	;
	'POSIT'	<EJ SLUT
	;Kvittof|rteckning |ver avs{nt mail samt kvittenser.
	;
	.TESTFILE MAI'$PUSER'.FNS;-1			![LDSTA FILEN
	'QUITIF'.IF <FILERR> NE 1
.;
	.PARSE <FILSPC> ";" A B
	.SETN JNUM 'B'
	.TESTFILE MAI'$PUSER'.FNS;0			!NYASTE FILEN
	'QUITIF'.IF <FILERR> NE 1
	.PARSE <FILSPC> ";" A B
	.SETN MNUM 'B'
.;
	'WHILE'.IF JNUM LE MNUM
;
	.TESTFILE MAI'$PUSER'.FNS;'JNUM'
	'IF'.IF <FILERR> EQ 1
		.ENABLE QUIET
		TYP MAI'$PUSER'.FNS;'JNUM'
		.DISABLE QUIET
.;
		.ENABLE LOWERCASE
		.SETS FRAG "Vill du kontrollera hos mottagaren"
		.DISABLE LOWERCASE
		.GOSUB TESTA
		'IF'.IFT JA
.;
			.OPENR MAI'$PUSER'.FNS;'JNUM'
			.SETS DISSPC <FILSPC>
			.READ FILSPC
			.CLOSE
.;
			.OPENA MAI'$PUSER'.FNS;'JNUM'
			.TESTFILE 'FILSPC'
			'IF'.IF <FILERR> EQ 1
				.OPENR #1 'FILSPC'
				.READ #1 FILSPC
				.CLOSE #1
.;
				'IF'.IF FILSPC EQ DISSPC
	;Mailet ligger kvar i inkorgen hos mottagaren.
	.DATA '<DATE>' '<TIME>' fanns mailet kvar i inkorgen hos mottagaren.
					.CLOSE
				'ELSE'
					'PERFORM' SORKOL	<INGA KVITTON
				'ENDIF'
			'ELSE'
				'PERFORM' SORKOL		<INGA KVITTON
			'ENDIF'
.;
		'ENDIF'
.;
		.ENABLE LOWERCASE
		.SETS FRAG "Vill du ta bort detta kvitto fr}n kvittof|rteckningen"
		.DISABLE LOWERCASE
		.GOSUB TESTA
		'IF'.IFT JA
			.ENABLE QUIET
			PIP MAI'$PUSER'.FNS;'JNUM'/DE
			.DISABLE QUIET
			.IF <EXSTAT> NE 1 ;KAN EJ TA BORT .FNS-FIL, Ring 120.
			.IF <EXSTAT> NE 1 .PAUSE
			;Kvittot makulerat.
			;
		'ENDIF'
.;
	'ENDIF'
.;
	.INC JNUM
.;
	'ENDDO'
.;
.;
	'ADMIT'
	'ENDPOSIT'
.;
	;
	;
	;Inga fler kvitton finns i f|rteckningen.
.;
	'ENDSECT'
.;
.;
	'SECTION' SORKOL
	.IF <FILERR> NE 1 ;Mailet {r borttaget fr}n mottagarens inkorg.
	.IF <FILERR> NE 1 .DATA '<DATE>' '<TIME>' var mailet borttaget fr}n mottagarens inkorg.
	.CLOSE
	'ENDSECT'
.;
.;
.ANVAND:
	;F|rteckning |ver m|jliga mottagare av MAIL.
	;
	;#6VARNING - Om Du s{nder MAIL till mottagare som anv{nder
	;terminalen s{llan eller aldrig, ange PAPPER s} distribueras
	;det manuellt av vaktm{staren med n{sta posttur. Spara alltid ditt original.
	;
	;INGO	= Ingemar Larsson	BIRGITTA= Birgitta Eriksson, Adm.avd.
	;BIGGAN	= Birgitta Eriksson,Dat.ANNIKA	= Annika Ekstrand
	;NALLE	= Bj|rn Bostrand	CILLA	= Cilla Franz`n
	;CHARTER= Gamla Uppsala Buss	HASSE	= Hans Lerne
	;PLANAVD= Plan & utredn.avd	SVEN	= Sven Dahlin
	;CHRIS	= Christer Lindgren	BTA	= Bj|rn-Erik Tapper
	;STIG	= Stig Broman		INGA	= Inga Zellinger
	;ROLF	= Rolf Hemlin		INGER	= Inger Andersson
	;ANNA-K	= Anna-Karin L|vgren	VTS	= VTS Transportation Systems
	;SKAF	= Sektion 5		FRIDA	= Frida, drift
	;FASS	= Fassprojektet		KJELL	= Kjell Pettersson
	;TOMAS	= Tomas Karlsson	DATAAVD	= Dataavdelningen
	;STABEN	= Staben		TIDSSKR	= Tidsskrivarna
	;ALLA	= Alla MAILanv{ndare (ej personligt, v{cks ej)
	;PAPPER	= Vem som helst. Distribueras av vaktis.
	;
	.ASKS VAD Tryck <RETURN> f|r }terg}ng till menyn >
	;
.;
	.RETURN
.;
.;
.;
	'SECTION' MAIL
.;
	'POSIT'		<EJ SLUT
.;
	'IF'.IFF ALLA
	;MAIL - MOTTAGNING '$ID'. Svara J f|r JA , N eller <RETURN> f|r NEJ.
	'ELSE'
	;CIRKUL[R - MOTTAGNING '$ID'. Svara J f|r JA , N eller <RETURN> f|r NEJ.
	'ENDIF'
.;
	.ENABLE LOWERCASE
	.SETS FRAG "Vill du se 'BTYP'f|rteckning"
	.DISABLE LOWERCASE
	.GOSUB TESTA
	.ENABLE QUIET
	.IFT JA PIP 'UICS'*.BRV;*/NM/LI
	.DISABLE QUIET
	.IFT JA .IF <EXSTAT> NE 1 ;Det finns inga 'BTYP'.
.;
	;
	;Ange nedan namnet p} det 'BTYP' du vill l{sa.
	.GOTO BNAMFL
.;
.BNAMSY:
	;Namnet 'BNAMN' inneh}ller felaktiga tecken.
	.;S}dana fel kan jag dessv{rre inte hantera. G} in igen och stava r{tt.
	.;.EXIT
.;
.BNAMFL:
	.SETS BNAMN ""
;
	.ASKS BNAMN Ange namn  (<RETURN>=]ter till menyn) >
	'QUITIF'.IF <STRLEN> EQ 0
	'IF'.IF <STRLEN> GT 9.
		;Namnet 'BNAMN' {r f|r l}ngt.
		.GOTO BNAMFL
	'ENDIF'
	.IF BLLET EQ BNAMN[<STRLEN>:<STRLEN>] .GOTO BNAMSY
	.PARSE BNAMN BLLET A B
	.IF <STRLEN> NE 1 .GOTO BNAMSY
	.ONERR BNAMSY
	.SETN <ERRCTL> 3
	.TESTFILE 'UICS''BNAMN'.BRV
	.ONERR
.;
	'IF'.IF <FILERR> EQ 230.
		;'BTYP'et 'BNAMN' finns inte.
		.GOTO BNAMFL
	'ELSIF'.IF <FILERR> NE 1
		;
		;SYSTEMFEL. Felnummer '<FILERR>'. Kontakta datadriften tel. 120.
		;
		.DELAY 5.s
		'QUIT'
	'ENDIF'
.;
	.ASKS GO Tryck <RETURN> s} visar jag 'BTYP'et snabbt >
	.ENABLE QUIET
	TYP 'UICS''BNAMN'.BRV
	.DISABLE QUIET
;
	.OPENR #1 'UICS''BNAMN'.BRV
	.READ #1 FILSPC
	.CLOSE #1
	.TEST FILSPC
	.SETF OPEN0
.;
	'IF'.IF <STRLEN> GE 24.
	'IF'.IF <STRLEN> LE 31.
.;
		.TESTFILE 'FILSPC'
		.IF <FILERR> EQ 1 .SETT OPEN0
.;
		.ENABLE LOWERCASE
		.SETS LOGMES "skummade"
		.SETS LOGME2 ""
		.IFT OPEN0 .GOSUB LOGIT
		.DISABLE LOWERCASE
.;
.;
	'ENDIF'
	'ENDIF'
.;
	.ENABLE LOWERCASE
	.SETS FRAG "Vill Du ha 'BTYP'et utskrivet p} printer"
	.DISABLE LOWERCASE
	.GOSUB TESTA
	.IFT JA .GOSUB PRNT
.;
	.ENABLE LOWERCASE
	.SETS LOGMES "printade"
	.IFT JA .IFT OPEN0 .GOSUB LOGIT
	.DISABLE LOWERCASE
.;
	'IF'.IFF ALLA
		.ENABLE LOWERCASE
		.SETS FRAG "Vill Du kasta 'BTYP'et i papperskorgen direkt"
		.DISABLE LOWERCASE
		.GOSUB TESTA
		'IF'.IFT JA
			.ENABLE QUIET
			PIP 'UICS''BNAMN'.BRV;0/DE
			.DISABLE QUIET
			'IF'.IF <EXSTAT> EQ 1
				 ;'BTYP'et makulerat.
			'ELSE'
				;Makulering av 'BTYP'et misslyckades. Ring 120.
			'ENDIF'
			.ENABLE LOWERCASE
			.SETS LOGMES "makulerade"
			.IF <EXSTAT> EQ 1 .IFT OPEN0 .GOSUB LOGIT
			.DISABLE LOWERCASE
			'QUIT'
		'ENDIF'
	'ENDIF'
.;
	.ENABLE LOWERCASE
	.SETS FRAG "Vill Du f|rvandla 'BTYP'et 'BNAMN' till ett eget dokument"
	.DISABLE LOWERCASE
	.GOSUB TESTA
	'QUITIF'.IFF JA
.;
	;'BTYP'et 'BNAMN' f|rvandlas till ett dokument p} ditt konto.
	;Ange nedan det namn Du vill att 'BTYP'et 'BNAMN' ska f} som dokument.
	;
	.GOTO NAM2FL
.;
.NAM2SY:
	;Namnet 'NAMN2' inneh}ller felaktiga tecken.
	.;S}dana fel kan jag dessv{rre inte hantera. G} in igen och stava r{tt.
.;.EXIT
.;
.NAM2FL:
	.SETS NAMN2 ""
	.ASKS NAMN2 Ange dokumentnamn (<ESC>=]ter till menyn) >
	'QUITIF'.IFT <ESCAPE>
	'IF'.IF <STRLEN> EQ 0
		;Namnet 'NAMN2' {r f|r kort.
		.GOTO NAM2FL
	'ELSIF'.IF <STRLEN> GT 9.
		;Namnet 'NAMN2' {r f|r l}ngt.
		.GOTO NAM2FL
	'ENDIF'
	.IF BLLET EQ NAMN2[<STRLEN>:<STRLEN>] .GOTO NAM2SY
.;
	.PARSE NAMN2 BLLET A B
	.IF <STRLEN> NE 1 .GOTO NAM2SY
	.ONERR NAM2SY
	.SETN <ERRCTL> 3
	.TESTFILE 'NAMN2'.TXT
	.ONERR
.;
	'IF'.IF <FILERR> NE 230.
	   'IF'.IF <FILERR> NE 1
		;
		;SYSTEMFEL. Felnummer '<FILERR>'. Kontakta datadriften tel. 120.
		;
		.DELAY 5.s
		'QUIT'
	   'ELSE'
		;Det finns redan ett gammalt dokument text med namnet 'NAMN2'.
		.ENABLE LOWERCASE
		.SETS FRAG "Vill Du f|rst|ra gamla 'NAMN2' och ers{tta den med 'BTYP'et"
		.DISABLE LOWERCASE
		.GOSUB TESTA
		.IFF JA .GOTO NAM2FL
	    'ENDIF'
	'ELSE'
		;Dokumentet 'NAMN2' finns inte.
	'ENDIF'
.;
	.IFF ALLA PIP 'NAMN2'.TXT/NV/CD/RE='BNAMN'.BRV
	.IFT ALLA PIP 'NAMN2'.TXT/NV/CD='UICS''BNAMN'.BRV
	;Nu har 'BTYP'et 'BNAMN' sparats som dokumentet 'NAMN2' p} ditt konto.
	.ENABLE LOWERCASE
	.SETS LOGMES "gjorde"
	.SETS LOGME2 " egna dokumentet 'NAMN2' av"
	.IFT OPEN0 .GOSUB LOGIT
	.DISABLE LOWERCASE
.;
	'ADMIT'
	'ENDPOSIT'
	'ENDSECT'
;
.;
.;	SUBRUTIN
.;
.PRNT:
	'POSIT'		<EJ F[RDIG
.;
	;Utskrift kan ske p}: Laserprintern, HK, CITY eller p} egen kopieprinter
.;
	.ENABLE LOWERCASE
	.SETS FRAG "Snygg utskrift p} laserskrivaren hos Gamlis"
	.DISABLE LOWERCASE
	.GOSUB TESTA
	'IF'.IFT JA
		;Utskrift sker p} laserskrivaren i korridoren vid Gamlis kontor.
		.ENABLE QUIET
		PRI NP:='UICS''BNAMN'.BRV
		'QUIT'
	'ENDIF'
	.SETS FRAG "Utskrift p} HUVUD-kontoret"
	.DISABLE LOWERCASE
	.GOSUB TESTA
	'IF'.IFT JA
		;Utskrift sker p} Huvudkontorets skrivare hos dataavdelningen
		.ENABLE QUIET
		PRI HK:='UICS''BNAMN'.BRV
		'QUIT'
	'ENDIF'
	.ENABLE LOWERCASE
	.SETS FRAG "Utskrift p} CITY-kontoret"
	.DISABLE LOWERCASE
	.GOSUB TESTA
	'IF'.IFT JA
		;Utskrift sker p} Citykontorets skrivare
		.ENABLE QUIET
		PRI CI:='UICS''BNAMN'.BRV
		'QUIT'
	'ENDIF'
	.ENABLE LOWERCASE
	;V{lj absolut inte lokal utskrift om Du inte har egen skrivare.
	.ENABLE LOWERCASE
	.SETS FRAG "Lokal utskrift p} Din egen skrivare"
	.DISABLE LOWERCASE
	.GOSUB TESTA
	'IF'.IFT JA
		;Utskrift sker p} Din egen skrivare. Den {r v{l p} ?
		.ENABLE QUIET
		SET /NOECHO=TI:
		.DISABLE QUIET
		;W
		.ENABLE QUIET
		TYP 'UICS''BNAMN'.BRV
		.DISABLE QUIET
		;X
		.ENABLE QUIET
		SET /ECHO=TI:
	'ENDIF'
	'ADMIT'
		.DISABLE QUIET
	'ENDPOSIT'
	.RETURN
.;
.TESTA:
	.SETF JA
	.ASKS TST 'FRAG' ?
	.IF <STRLEN> EQ 0 .RETURN
	.IF NLET EQ TST[1:1] .RETURN
	.IF JLET EQ TST[1:1] .SETT JA
	.IFT JA .RETURN
	;Vad} "'TST'" ?
	.GOTO TESTA
.;
.;
.;
.;
	'SECTION' SKICK
.;
	'POSIT'	<EJ SLUT
.;
	;MAIL/CIRKUL[R - S[NDNING '$ID'. Svara J f|r JA , N eller <RETURN> f|r NEJ.
	;Ange nedan namnet p} dokumentet Du vill s{nda som MAIL.
	.GOTO NAMNFL
.;
.NAMNSY:
	;Namnet 'NAMN' inneh}ller felaktiga tecken.
	.;S}dana fel kan jag dessv{rre inte hantera. G} in igen och stava r{tt.
	.;.EXIT
.;
.NAMNFL:
	.SETS NAMN ""
;
	.ASKS NAMN Ange namn  (<RETURN>=]ter till menyn) >
	'QUITIF'.IF <STRLEN> EQ 0
	'IF'.IF <STRLEN> GT 9.
		;Namnet 'NAMN' {r f|r l}ngt.
		.GOTO NAMNFL
	'ENDIF'
	.IF BLLET EQ NAMN[<STRLEN>:<STRLEN>] .GOTO NAMNSY
.;
	.PARSE NAMN BLLET A B
	.IF <STRLEN> NE 1 .GOTO NAMNSY
	.ONERR NAMNSY
	.SETN <ERRCTL> 3
	.TESTFILE 'NAMN'.TXT
	.ONERR
	'IF'.IF <FILERR> EQ 230.
		;Dokumentet 'NAMN' finns inte.
		.GOTO NAMNFL
	'ELSIF'.IF <FILERR> NE 1
		;
		;SYSTEMFEL. Felnummer '<FILERR>'. Kontakta datadriften tel. 120.
		;
		.DELAY 5.s
		'QUIT'
	'ENDIF'
.;
.;
	.ENABLE CONTROL-Z
	.SETF <EOF>
	.SETN MNUM 1
.;
	.OPEN MAI'$PUSER'.SND
	;
	;Ange nedan en eller flera mottagare, sista =<RETURN>, avbryt=<CTRL><Z> :
	'POSIT'		<EJ AVBROTT
.;
	'WHILE'.IFT <TRUE>
.;
	'POSIT'		<EJ AVBROTT OCH EJ OM IGEN
.;
	.ASKS MOTT Vilket ID har mottagare 'MNUM' , slut =<RETURN> ?
	'QUITIF'.IFT <EOF>
	'IF'.IF MNUM GE 2
		'BREAKIF'.IFT <ESCAPE>
		'BREAKIF'.IF <STRLEN> EQ 0
	'ENDIF'
.;
	.SETS UIC ""
	.IF MOTT EQ "INGO" .SETS UIC "DU:[200,60]"
	.IF MOTT EQ "BIGGAN" .SETS UIC "DU:[200,61]"
	.IF MOTT EQ "NALLE" .SETS UIC "DU:[200,62]"
	.IF MOTT EQ "CHARTER" .SETS UIC "DU:[200,62]"
	.IF MOTT EQ "SVEN" .SETS UIC "DU:[200,62]"
	.IF MOTT EQ "INGA" .SETS UIC "DU:[200,62]"
	.IF MOTT EQ "PLANAVD" .SETS UIC "DU:[200,70]"
	.IF MOTT EQ "CHRIS" .SETS UIC "DU:[200,70]"
	.IF MOTT EQ "STIG" .SETS UIC "DU:[200,70]"
	.IF MOTT EQ "TOMAS" .SETS UIC "DU:[200,71]"
	.;.IF MOTT EQ "ROFFE" .SETS UIC "HUGO::DR:[200,71]" (FULLT OK)
	.IF MOTT EQ "FASS" .SETS UIC "DU:[200,72]"
	.IF MOTT EQ "KJELL" .SETS UIC "DU:[200,73]"
	.IF MOTT EQ "FRIDA" .SETS UIC "DU:[200,61]"
	.IF MOTT EQ "PIRKKO" .SETS UIC "DU:[200,65]"
	.IF MOTT EQ "ANNIKA" .SETS UIC "DU:[200,66]"
	.IF MOTT EQ "ANNA-K" .SETS UIC "DU:[200,57]"
	.IF MOTT EQ "CILLA" .SETS UIC "DU:[200,64]"
	.IF MOTT EQ "HASSE" .SETS UIC "DU:[200,63]"
	.IF MOTT EQ "SKAF" .SETS UIC "DU:[200,74]"
	.IF MOTT EQ "BTA" .SETS UIC "DU:[200,75]"
	.IF MOTT EQ "STABEN" .SETS UIC "WI:[200,142]"
	.IF MOTT EQ "DATAAVD" .SETS UIC "WI:[200,142]"
	.IF MOTT EQ "VTS" .SETS UIC "DU:[200,67]"
	.IF MOTT EQ "ALLA" .SETS UIC "DU:[200,50]"
	.IF MOTT EQ "PAPPER" .SETS UIC "DU:[200,77]"
	.IF MOTT EQ "TIDSSKR" .SETS UIC "DU:[200,76]"
	.IF MOTT EQ "INGER" .SETS UIC "DU:[200,76]"
	.IF MOTT EQ "ROLF" .SETS UIC "DU:[200,76]"
	.TEST UIC
	'IF'.IF <STRLEN> EQ 0
		;Anv{ndaren 'MOTT' existerar inte.
		.GOSUB ANVAND
		'QUIT'
	'ENDIF'
.;
	.SETF PAPPER
	'IF'.IF MOTT EQ "PAPPER"
		.SETT PAPPER
		.ENABLE LOWERCASE
		.ASKS MOTT Ange mottagaren tillr{ckligt noggrant f|r att vaktis ska f|rst} >
		.DISABLE LOWERCASE
		'IF'.IFT <EOF>
			.SETF <EOF>
			'QUIT'
		'ELSIF'.IF <STRLEN> LE 2
			;Sk{mtare d{r.
			'QUIT'
		'ENDIF'
	'ENDIF'
.;
	.TESTFILE 'UIC'ID.USG
	'IF'.IF <FILERR> NE 1
		;Mottagarens MAIL-konto har aldrig anv{nts.
	'ELSE'
		;Mottagarens MAIL-konto anv{ndes senast enligt nedan:
	'ENDIF'
;
	.ENABLE QUIET
	TYP 'UIC'ID.USG
	.DISABLE QUIET
	.ENABLE LOWERCASE
	.SETS FRAG "Du vill s{nda MAILet 'NAMN' till 'MOTT'. [r det riktigt"
	.DISABLE LOWERCASE
	.GOSUB TESTA
	'QUITIF'.IFT <EOF>
	'IF'.IFF JA
		;MAILet s{ndes ej till denna mottagare.
		'QUIT'
	'ENDIF'
.;
	.ENABLE LOWERCASE
	.DATA 'MOTT'
	.DATA 'UIC'
	'IF'.IFF PAPPER
		.DATA EJPAP
	'ELSE'
		.DATA PAPPER
	'ENDIF'
	.DISABLE LOWERCASE
.;
	.INC MNUM
.;
	'ADMIT'		<AVBROTT ELLER OM IGEN
		'QUITIF'.IFT <EOF>
	'ENDPOSIT'
.;
	'ENDDO'
.;
	'ADMIT'		<AVBROTT
		.CLOSE
		.DISABLE CONTROL-Z
		;S[NDNING AVBRUTEN - Inget mail s{ndes.
		.ENABLE QUIET
		PIP MAI'$PUSER'.SND;*/DE
		.DISABLE QUIET
		'QUIT'	<SLUT
	'ENDPOSIT'
.;
.;
	;#3V[NTA
	;#4V[NTA
.;
	.CLOSE
	.DISABLE CONTROL-Z
.;
	.OPENR #1 MAI'$PUSER'.SND
.;
	.SETN JNUM 2		!2 F\R ETT MEDDELANDE OSV.
.;
	'WHILE'.IF JNUM LE MNUM
.;
		.READ #1 MOTT
		.READ #1 UIC
		.READ #1 PPR
.;
		.OPEN #2 MAI'$PUSER'.FNS
		.SETS FILSPC <FILSPC>
		.IF <FILERR> NE 1 ;FATAL - TEST ON MAI'$PUSER'.FNS - Ring 120
		.IF <FILERR> NE 1 .PAUSE
.;
	.OPEN 'NAMN'.TMP
	.DATA 'FILSPC'
	.DATA
	.DATA              MAIL fr}n '$ANVND' till 'MOTT' avs{nt '<TIME>' '<DATE>'
	.DATA              Avs{ndarens referens 'NAMN'. Ange detta vid svar.
	.DATA
	.CLOSE
.;
		.SETF SYSFEL
		.ENABLE QUIET
.;
		PIP 'NAMN'.TMP/AP='NAMN'.TXT
		.IF <EXSTAT> NE 1 .SETT SYSFEL
.;
		NFT 'UIC''NAMN'.BRV/NV/CD='NAMN'.TMP
		.IF <EXSTAT> NE 1 .SETT SYSFEL
.;
		.TESTFILE 'UIC''NAMN'.BRV	!UNDERS\K FILENS FULLST[NDIGA ID
		.IF <FILERR> NE 1 ;FATAL - TEST ON 'UIC''NAMN'.BRV - Ring 120.
		.IF <FILERR> NE 1 .PAUSE
.;
.;	FILNAMNET HOS MOTTAGAREN
.;
	.DATA #2 '<FILSPC>'
	.DATA #2 MAIL med namn 'NAMN' fr}n '$ANVND' till 'MOTT' avs{nt '<TIME>' '<DATE>'
	.CLOSE #2
.;
		PIP 'NAMN'.TMP;*/DE
		.IF <EXSTAT> NE 1 .SETT SYSFEL
.;
		'IF'.IFF SYSFEL
			'IF'.IF PPR EQ "PAPPER"
				NFT 'UIC'MAIL.FNS/NV=MAI'$PUSER'.FNS
				.IF <EXSTAT> NE 1 .SETT SYSFEL
			'ENDIF'
		'ENDIF'
.;
		'IF'.IFF SYSFEL
			TYP MAI'$PUSER'.FNS			!KVITTERA
		'ELSE'
			.DISABLE QUIET
		;S{ndning till 'MOTT' misslyckad. Ring 120.
			.DELAY 5.S
			.ENABLE QUIET
			PIP MAI'$PUSER'.FNS;0/DE
			.DISABLE QUIET
		'ENDIF'
.;
		.INC JNUM
	'ENDDO'
.;
.;
	.CLOSE #1
	.ENABLE QUIET
	PIP MAI'$PUSER'.SND;*/DE
	.DISABLE QUIET
	;
	;S{ndning avslutad.
	;
.;
	'ADMIT'
	'ENDPOSIT'
.;
	'ENDSECT'
.;
.;	SUBBAR
.;
.LOGIT:
	.OPENA 'FILSPC'
	.IF <FILERR> EQ 1 .GOTO LOGIOK
	;Fel vid kvittering. Ring 120. File='FILSPC' .
	.DELAY 10.S
	.SETF OPEN0
	.RETURN
.;
.LOGIOK:
	.DATA '<DATE>' '<TIME>' 'LOGMES' '$ANVND''LOGME2' 'BTYP'et.
	.CLOSE
	.RETURN
.;
.; <EOF> MAIL.CMD
.;