.;
.; KOMMANDOFIL LB:[1,2]BATINS.CMD --- INSTALL P] BATCHARNA
.;
.;	VERSION 88-08-10 B-E TAPPER
.;
.;	L[SER FILEN LB:[1,2]BATTSK.DAT
.;
.;	DEN INNEH]LLER UIC-RECORDS OCH TASK-RECORDS
.;	SAMT KOMMENTARRECORDS.
.;
.;	ETT UIC-RECORD ANGER UIC F\R DE EFTERF\LJANDE TASKARNA
.;	DET IGENK[NNES P] ATT DET HAR ETT + I F\RSTA POSITION	
.;	+ddn:[guic,muic}#status#kommentar
.;	F\RUTOM UIC-INFORMATIONEN INNEH]LLER RECORDET INFO OM
.;	BATCHENS STATUS:
.;			 ALLINS=INSTALLERA ALLTID, L]T VARA I FRED
.;			 UTKINS=INSTALLERA ALLTID, L]T VARA I FRED OM BACKUP
.;			 ALLTID=INSTALLERA ALLTID, ABORT OCH REMOVE VID BATREM
.;			 RUNABT=INSTALLERAS ALDRIG, STARTAS VIA RUN ,TDX ELLER
.;				STESTA, BATSTA, BATCON eller kommandofil.
.;				SKA ABORTERAS VID NEDTAGNING OCH G\RAS REMOVE P]
.;			 UTKBEV=INSTALLERAS ALDRIG, STARTAS VIA BYTDAG. SKALL
.;				ENDAST ABORTERAS OCH REMOVAS OM EJ BACKUP.
.;			 RUN   =DITO MEN SKA INTE G\RASE ABORT ELLER REMOVE P]
.;			 GAMMAL=ANV[NDS INTE: FINNS KVAR SOM DOKUMENTATION
.;
.;	OBS ! I BATTSK.DAT M]STE ALLTD ALLTID-TASKARNA ST] F\RST EFTERSOM
.;	KOMMANDOFILEN G\R EXIT N[R F\RSTA ICKE-ALLTID UIC-RECORD HITTATS.
.;	RUNABT m}ste st} f|re RUN eftersom REMOVE-filen g|r motsv. exit.
.;
.;	ETT TASK-RECORD ANGER VILKEN PRIORITET ETT TASK SKA INSTALLERAS MED
.;	(ALLTID-PGM) SAMT OM TASKET SKA VARA SLAVAT ELLER FIXAT OCH VILKET
.;	NAMN TASKET HAR N[R DET [R INSTALLERAT, OM DETTA SKILJER SIG FR]N
.;	TASKFILNAMNET.
.;
.;	taskfilnamn#prioritet#typ#tasknamn#kommentar
.;
.;	TYP: SLV = SLAVED, FIX = FIXED AND SLAVED, "TOMT" = Varken eller.
.;
.;	ETT TASK-RECORD IGENK[NNS P] ATT DET VARKEN B\RJAR P] ; ELLER P] +
.;
.;
.;	ETT KOMMENTARRECORD [R BARA EN KOMMENTAR. IGENK[NNS P] ; I POS 1
.;
.;
	.ENABLE SUBSTITUTION
	.ENABLE GLOBAL
	.DISABLE QUIET
.;
	.SETS HASH "#"
	.SETS PLUS "+"
	.SETS COMM ";"
	.SETF <EOF>
.;
.;
	.IFNDF $PROUT .ASK $PROUT Utskrivna kommandon
.;
.;
	.IFNDF $BACKU .SETF $BACKU
.;
	'IF'.IFT $BACKU
		.DISABLE QUIET
		;
		;	BATINS - UTKINS R\RES EJ
		;
	'ENDIF'
.;
	'IF'.IFF $PROUT
		.ENABLE QUIET
	'ELSE'
		.DISABLE QUIET
	'ENDIF'
.;
.;	L[S REGISTERFILEN
.;
	.OPENR LB:[1,2]BATTSK
	'IF'.IF <FILERR> NE 1
		.DISABLE QUIET
		;BATINS KAN EJ \PPNA BATTSK.DAT -- <FILERR> = '<FILERR>'
		.STOP
	'ENDIF'
.;
	.READ INBUF
.;	;'INBUF'
	'WHILE'.IFF <EOF>
.;
		'IF'.IF <FILERR> NE 1
			.DISABLE QUIET
			;L[SFEL I BATINS -- <FILERR> = '<FILERR>'
			;INBUF='INBUF'
			.STOP
		'ENDIF'
.;
		'POSIT'		! EJ F[RDIGBEHANDLAT
.;
		'QUITIF'.IF COMM EQ INBUF[1:1]
.;
		'IF'.IF PLUS EQ INBUF[1:1]	!UIC-RECORD
.;
			.PARSE INBUF "+#" TOMT PLATS STATUS RESTEN
			'IF'.IF <STRLEN> NE 4
.;
				.DISABLE QUIET
	;Fel format p} indata i BATTSK.DAT till BATINS - UIC record.
				;INBUF='INBUF'
				;TOMT='TOMT'
				;PLATS='PLATS'
				;STATUS='STATUS'
				;RESTEN='RESTEN'
				.STOP
			'ELSIF'.IF STATUS NE "ALLINS"
			    'IF'.IF STATUS NE "UTKINS"
.;
				'BREAKIF'.IF STATUS NE "ALLTID"	!AVSLUTA
.;
			    'ENDIF'
			'ENDIF'
.;
		'ELSE'			!TASK RECORD
.;
			.PARSE INBUF "#" FILE PRIO SLAVE TNAME RESTEN
.;
			'IF'.IF <STRLEN> NE 5
				.DISABLE QUIET
	;Fel format p} indata i BATTSK.DAT till BATINS - TASK record.
				;INBUF='INBUF'
				;PLATS='PLATS'
				;STATUS='STATUS'
				;FILE='FILE'
				;PRIO='PRIO'
				;SLAVE='SLAVE'
				;TNAME='TNAME'
				;RESTEN='RESTEN'
				.STOP
			'ENDIF'
.;
.;
			.SETS TASK FILE
			.SETS NAME ""
			.TEST TNAME
			'IF'.IF <STRLEN> NE 0
				.SETS TASK TNAME
				.SETS NAME "/TASK='TNAME'"
			'ENDIF'
			'IF'.IFINS 'TASK'
				'CASE' STATUS
				'WHEN' "ALLINS"
					'QUIT'		! L[S N[STA
				'WHEN' "UTKINS"
					'QUITIF'.IFT $BACKU	!L[S N[STA
				'OTHER'
					REM 'TASK'
					.DISABLE QUIET
					;'TASK' var installerat.
					.IFF $PROUT .ENABLE QUIET
				'ENDCASE'
			'ENDIF'
.;
			'CASE' SLAVE
			'WHEN' "SLV"
				.SETS SLAVED "/SLV=YES"
				.SETS CKPD "YES"
			'WHEN' "FIX"
				.SETS SLAVED "/SLV=YES"
				.SETS CKPD "NO"
			'OTHER'
				.SETS SLAVED ""
				.SETS CKPD "YES"
			'ENDCASE'
.;
			.TEST PRIO
			'IF'.IF <STRLEN> NE 0
				.SETS PRIOW "/PRI='PRIO'."
			'ELSE'
				.SETS PRIOW ""
			'ENDIF'
.;
			'PERFORM' INSTALL
.;
		'ENDIF'
.;
		'ADMIT'
		'ENDPOSIT'
.;
		.READ INBUF
.;		;'INBUF'
.;
	'ENDDO'
.;
	.CLOSE
	.EXIT
.;
.;;;;;;;;;;;;;;;;;;  INSTALLERA ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
.;
	'SECTION' INSTALL
.;
	INS 'PLATS''FILE'/CKP='CKPD''PRIOW''SLAVED''NAME'
	'IF'.IF <EXSTAT> NE 1
.;
		.DISABLE QUIET
		;'PLATS''TASK' kunde inte installeras : Exit status '<EXSTAT>'
		.IFF $PROUT .ENABLE QUIET
.;
	'ELSIF'.IF SLAVE EQ "FIX"
		FIX 'TASK'
		'IF'.IF <EXSTAT> NE 1
.;
			.DISABLE QUIET
			;'TASK' kunde inte fixas : Exit status '<EXSTAT>'
			.IFF $PROUT .ENABLE QUIET
		'ENDIF'
	'ENDIF'
.;
	'ENDSECT'	<INSTALL
.;
;
; <EOF> BATINS.SAT
;