.;
.; LB:[1,2]BACKUP2.SAT	---	TAR BACKUP P] ANV[NDARNAS EDT-FILER, MIMER M.M.
.;				SAMT EXTRAREGISTER & AKTUELL DATABAS RA:
.;				BACK UP TILL TAPE
.;
.;	VERSION 88-01-19 B-E TAPPER AVSEDD F\R LABAN+ - TAPEBACKUP
.;	BACKAR UPP F\LJANDE :
.;
.;		DU:[1,300]		MIMER /DB
.;		DU:[2,300]		MIMER /SH
.;		DU:[4,300]		MIMER /DB 3.2.8A, FM
.;		DU:[2,100]		EDT-FILER, allm{n slask
.;		DU:[167,301]		EXTRAREGISTREN
.;		DU:[1,101]		RADIODATABAS , G[LLANDE INDEX
.;		DU:[1,102]		RADIODATABAS , MIMER ATRSKARP
.;		DU:[200,100]		EDT-FILER, allm{n slask
.;		DU:[200,50]		EDT-FILER, cirkul{r
.;		DU:[200,51]		EDT-FILER,
.;		DU:[200,52]		EDT-FILER,
.;		DU:[200,53]		EDT-FILER,
.;		DU:[200,54]		EDT-FILER,
.;		DU:[200,55]		EDT-FILER,
.;		DU:[200,56]		EDT-FILER,
.;		DU:[200,57]		EDT-FILER,Anna-karin L|vgren
.;		DU:[200,60]		EDT-FILER,Ingemar Larsson
.;		DU:[200,61]		EDT-FILER,Birgitta Eriksson
.;		DU:[200,62]		EDT-FILER,u
.;		DU:[200,63]		EDT-FILER,u
.;		DU:[200,64]		EDT-FILER,u
.;		DU:[200,65]		EDT-FILER,u
.;		DU:[200,66]		EDT-FILER,u
.;		DU:[200,67]		EDT-FILER,u
.;		DU:[200,70]		EDT-FILER,Plan.avd, Stig & Christer
.;		DU:[200,71]		EDT-FILER, - " -, Tomas Karlsson
.;		DU:[200,72]		EDT-FILER,u
.;		DU:[200,73]		EDT-FILER,Kjell Pettersson
.;		DU:[200,74]		EDT-FILER,u
.;		DU:[200,75]		EDT-FILER,Tapper
.;		DU:[200,76]		EDT-FILER,u
.;		DU:[200,77]		EDT-FILER,Papper
.;
.;
	.ENABLE GLOBAL
	.ENABLE SUBSTITUTION
	.DISABLE QUIET
	.SETS UIC <UIC>
	.SETS ERRCSE "INGET"	!FELORSAK
	.SETS $XSPC P1
	'IF'.IF P2 NE "2"
		;BACKUP - STARTAS ENDAST VIA @BACKUP
		.EXIT
	'ENDIF'
	.SETS $DAT P3
.;
	.TEST $XSPC
	.IF <STRLEN> LT 2 .STOP
.;
	'IF'.IF <UIC> NE "[1,2]"
		.DISABLE QUIET
		; EJ TILL]TET K\RA UNDER ANNAT UIC [N [1,2]
		.EXIT
	'ENDIF'
.;
	.TESTDEVICE TI:
	.PARSE <EXSTRI> "," VAR1 VAR2
	'IF'.IF VAR1 NE "TT0:"
		.DISABLE QUIET
		; EJ TILL]TET K\RA FR]N ANNAT H]LL [N FR]N KONSOLEN
		.IF $XSPC NE "930BTA" .EXIT
	'ENDIF'
.;
	.IFNINS PIP INS $PIP
	TYP LB:[1,300]BACKUP2.LBL
;
.;
	.SETF XPLA
	.IF $XSPC NE "930BTA" .ASK XPLA VILL DU HA INSTRUKTIONER
.;
.;
	.SETF MIMER		!PONERA ATT MIMER INTE VAR AKTIVT
	'IF'.IFINS DBIOT
		.SETT MIMER		!MIMER [R AKTIVT, KOMMER ATT ]TERSTARTAS
		;	MIMER [R AKTIVT
		;	JAG STOPPAR NU MIMER
		;
		@LB:[1,2]DBSTOP
	'ENDIF'
;
	@LB:[1,2]EXTRAREM
.;
	'WHILE'.IFT <TRUE>
		'IF'.IFT XPLA
			;DU SKA MONTERA BANDET I BANDSTATIONEN.
			;KONTROLLERA ATT DET [R  R [ T T  TAPE OCH ATT DU TRYCKT IN PLATTAN.
			;TRYCK D[REFTER P] "LOAD/REWIND". N[R "BOT" T[NDS, TRYCK P] "ON LINE".
			;OBSERVERA ATT "FILE PRO" INTE F]R LYSA. OM DEN G\R DET, MONTERA
			;BANDET IGEN MED PLASTREMSAN P] BAKSIDAN KORREKT INLAGD.
			;(BANDET TAS I S] FALL BORT MED "RESET" F\LJT AV "UNLOAD".)
;
;
			;N[R DU [R KLAR OCH "ON LINE" SAMT "BOT" LYSER SVARA "Y" NEDAN
		'ENDIF'
.;
		.SETT GO
		'IF'.IFT XPLA
			.ASK GO HAR DU MONTERAT BANDET
		'ENDIF'
		'IF'.IFT GO
.;
			MOU MS:/FOR
			'BREAKIF'.IF <EXSTAT> EQ 1
		'ENDIF'
.;
		;
		; DET [R N]T GALET MED TAPEN I BANDSTATIONEN, FIXA DET !!!
		;
.;
		.SETT XPLA
	'ENDDO'
.;
.;
.;
	;
	;BACKUP - INGA FLER FR]GOR
	'IF'.IFT XPLA
		;JAG KOMMER NU ATT ARBETA C:A 1-3 TIMMAR.
	'ENDIF'
	;
.;
.;
	.OPEN LB:[1,300]BACKUP2.LBL
	.DATA MAGTAPE BACKUP AV EDT-FILER SAMT MIMER-REGISTREN M.M.
	.DATA BACKUP SENAST TAGEN '$DAT' AV '$XSPC' - LABEL: BACKUP2'$DAT'
	.DATA BACKUP F\R EDT-FILER I GRUPPER MED /BACLABEL: GRP5, GRP6, GRP7
	.DATA BACKUP F\R EXTRAREGISTER LM:[167,301],[1,101],[1,102]. /BAC:EXTRA
	.DATA '<DATE>' '<TIME>'
	.CLOSE
.;
	PIP @LB:[1,2]BACKUP2.PIP
	.SETS ERRCSE "PIP"
	.IF <EXSTAT> NE 1 .GOSUB FEL
.;
.;
	.IFNINS BRU INS $BRU
.;
	.OPEN WI:[200,142]BACKUP2.BRU
	.DATA /REW/MOU/VER/BAC:BACKUP2'$DAT' DU0:[1,300],[2,300],[200,100],[2,100],[2,67],[2,73] MS:
	.DATA /APP/MOU/VER/BAC:GRP5 DU0:[200,50],[200,51],[200,52],[200,53],[200,54],[200,55],[200,56],[200,57] MS:
	.DATA /APP/MOU/VER/BAC:GRP6 DU0:[200,60],[200,61],[200,62],[200,63],[200,64],[200,65],[200,66],[200,67] MS:
	.DATA /APP/MOU/VER/BAC:GRP7 DU0:[200,70],[200,71],[200,72],[200,73],[200,74],[200,75],[200,76],[200,77] MS:
	.DATA /APP/MOU/VER/BAC:EXTRA DU0:[167,301],[1,101],[1,102] MS:
	.CLOSE
.;
	PRI WI:[200,142]BACKUP2.TMP/CO:2/DEL
.;
	BRU @WI:[200,142]BACKUP2.BRU
	.SETS ERRCSE "BRU"
	.IF <EXSTAT> NE 1 .IF <EXSTAT> NE 0 .GOSUB FEL
.;
	PIP WI:[200,142]BACKUP2.BRU;*/DE/LD
.;
	DMO MS:/DEV
	;
	;BACKUP - BANDET F[RDIGT !
	;
	'IF'.IFT XPLA
		;DU KAN NU DEMONTERA BANDET UR BANDSTATIONEN.
		;TRYCK F\RST P] "RESET" OCH SEDAN P] "UNLOAD".
		;GL\M INTE ATT DU SKA HA MED DEN ENA DIRECTORY-LISTNINGEN MED
		;BANDET OCH ATT DEN ANDRA SKA SPARAS -- SL[NG DE GAMLA !
	'ENDIF'
.;
	SET /UIC='UIC'
.;
	@LB:[1,2]EXTRAENT	!ENTER P] REGISTER
	'IF'.IFT MIMER
		.SETF $BOO		!INGEN BOOT, MEN SYMBOLEN SKA VA DEF.
		@LB:[1,2]DBSTART	!]TERSTART AV MIMER
	'ENDIF'
.;
	.IFINS BRU REM BRU
.;
	.DISABLE QUIET
	;
	;----- BACKUP2 KLAR
	;
	.EXIT
.;
.;
.FEL:
	;'ERRCSE'
	; FAILED -- EXSTAT = '<EXSTAT>'
	.PAUSE
	.RETURN
.;
.;	<EOF> LB:[1,2]BACKUP2.SAT
.;