.;
; LB:[1,2]BACKUP0.SAT	---	TAR BACKUP P] SYSTEMET - LB:
.;				   BACK UP TILL TAPE
.;
.;	OBS ! .SAT,.CMF - ANV[ND @SAT
.;
.;	VERSION 88-08-03 B-E TAPPER AVSEDD F\R PDISP P] LABAN+ - TAPEBACKUP
.;	BACKAR UPP F\LJANDE :
.;
.;	[1,1],[1,2],[1,54],[3,54],[7,54],[2,101],[2,104],[110,11],[110,60],
.;	[110,231]
.;
	.ENABLE GLOBAL
	.ENABLE SUBSTITUTION
	.DISABLE QUIET
	.DISABLE ATTACH
	.SETS UIC <UIC>
	.SETS ERRCSE "INGET"	!FELORSAK
	.SETS $XSPC P1
.;
	'POSIT'		<EJ STOP
.;
	'IF'.IF P2 NE "0"
		;BACKUP - STARTAS ENDAST VIA @BACKUP
		'QUIT'
	'ENDIF'
	.SETS $DAT P3
.;
	.TEST $XSPC
	'QUITIF'.IF <STRLEN> LT 2
.;
	'IF'.IF <UIC> NE "[1,2]"
		; EJ TILL]TET K\RA UNDER ANNAT UIC [N 1,2
		'QUIT'
	'ENDIF'
.;
	.TESTDEVICE TI:
	.PARSE <EXSTRI> "," VAR1 VAR2
	'IF'.IF VAR1 NE "TT0:"
		; EJ TILL]TET K\RA FR]N ANNAT H]LL [N FR]N KONSOLEN
		'QUITIF'.IF $XSPC NE "930BTA"
	'ENDIF'
.;
;
	.IFNINS PIP INS $PIP
	TYP LB:[1,54]BACKUP0.LBL
;
.;
	.SETF XPLA
	'IF'.IF $XSPC NE "930BTA"
		.ASK XPLA VILL DU HA INSTRUKTIONER
	'ENDIF'
.;
	'WHILE'.IFT <TRUE>
.;
	'IF'.IFT XPLA
		;
		;DU SKA MONTERA BANDET I BANDSTATIONEN.
		;KONTROLLERA ATT DET [R  R [ T T  TAPE OCH ATT DU TRYCKT IN PLATTAN.
		;TRYCK D[REFTER P] "LOAD/REWIND". N[R "BOT" T[NDS, TRYCK P] "ON LINE".
		;OBSERVERA ATT "FILE PRO" INTE F]R LYSA. OM DEN G\R DET, MONTERA
		;BANDET IGEN MED PLASTREMSAN P] BAKSIDAN KORREKT INLAGD.
		;(BANDET TAS I S] FALL BORT MED "RESET" F\LJT AV "UNLOAD".)
		;
		;N[R DU [R KLAR OCH "ON LINE" SAMT "BOT" LYSER SVARA "Y" NEDAN
		;
.;
	'ENDIF'
	.SETT GO
	'IF'.IFT XPLA
		.ASK GO HAR DU MONTERAT BANDET
	'ENDIF'
	'IF'.IFT GO
.;
		MOU MS:/FOR
		'BREAKIF'.IF <EXSTAT> EQ 1
.;
	'ENDIF'
.;
	.SETT XPLA
	.DISABLE QUIET
	;
	;DET [R N]T GALET MED TAPEN I BANDSTATIONEN
	;FIXA DET !!!
	;
.;
	'ENDDO'
.;
	'IF'.IFT XPLA
		;
		;JAG KOMMER NU ATT ARBETA C:A 1/2 TIMME.
		;
	'ENDIF'
	;
	;BACKUP - INGA FLER FR]GOR
	;
.;
.;
	.OPEN LB:[1,54]BACKUP0.LBL
	.DATA MAGTAPE BACKUP AV SYSTEMKONTON P] SYSTEMDISKEN
	.DATA LB:[1,1],[1,2],[1,54],[3,54],[7,54],[2,101],[2,104],[110,11],[110,231]
	.DATA BACKUP SENAST TAGEN '$DAT' AV '$XSPC' - LABEL: BACKUP0'$DAT'
	.DATA '<DATE>' '<TIME>'
	.CLOSE
.;
	.OPEN LB:[1,2]BACKUP0.PIP
	.DATA WI:[200,142]BACKUP0.BRU;*/DE/NM
	.DATA WI:[200,142]BACKUP0.TMP=LB:[1,1],[1,2]/LI,[1,54],[3,54],[5,54]
	.DATA WI:[200,142]BACKUP0.TM2=LB:[2,101]/LI,[2,104],[110,11],[110,231]
	.DATA WI:[200,142]BACKUP0.TMP/AP=WI:[200,142]BACKUP0.TM2
	.DATA LB:[1,54]BACKUP0.LBL/PU/LD
	.DATA LB:[1,2]BACKUP0.PIP/PU/LD
	.CLOSE
.;
	PIP @LB:[1,2]BACKUP0.PIP
	.SETS ERRCSE "PIP"
	.IF <EXSTAT> NE 1 .GOSUB FEL
.;
.;
	.IFNINS BRU INS $BRU
.;
	.OPEN WI:[200,142]BACKUP0.BRU
	.DATA /REW/MOU/VER/BACK:BACKUP0'$DAT' DU:[1,1],[1,2],[1,54],[3,54],[7,54],[2,101],[2,104],[110,11],[110,231] MS:
	.CLOSE
.;
	PRI WI:[200,142]BACKUP0.TMP/CO:2/DEL
	PIP WI:[200,142]BACKUP0.TM2;*/DE
.;
	BRU @WI:[200,142]BACKUP0.BRU
	.SETS ERRCSE "BRU"
	'IF'.IF <EXSTAT> NE 1
		.IF <EXSTAT> NE 0 .GOSUB FEL
	'ENDIF'
.;
	PIP WI:[200,142]BACKUP0.BRU;*/DE
.;
	DMO MS:/DEV
	;
	;BACKUP - BANDET F[RDIGT !
	;
	'IF'.IFT XPLA
		;DU KAN NU DEMONTERA BANDET UR BANDSTATIONEN.
		;TRYCK F\RST P] "RESET" OCH SEDAN P] "UNLOAD".
		;GL\M INTE ATT DU SKA HA MED DEN ENA DIRECTORY-LISTNINGEN MED
		;BANDET OCH ATT DEN ANDRA SKA SPARAS -- SL[NG DE GAMLA !
		;
	'ENDIF'
.;
	'ADMIT'
		DMO MS:/DEV
	'ENDPOSIT'
.;
	SET /UIC='UIC'
.;
	.IFINS BRU REM BRU
.;
	.EXIT
.;
.;
.FEL:
	;'ERRCSE'
	; FAILED -- EXSTAT = '<EXSTAT>'
	.PAUSE
	.RETURN
.;
.;	<EOF> LB:[1,2]BACKUP0.SAT
.;