;
;	LB:[1,2]BACKUP.SAT
;
.;
.;	VERSION 88-08-02 B-E TAPPER; BACKUP P] 11M+
.;
.;
	.ENABLE ESCAPE
	.ENABLE SUBSTITUTION
	.ENABLE TIMEOUT
	.ENABLE GLOBAL
	.DISABLE DISPLAY
	.DISABLE QUIET
	.ENABLE DECIMAL
.;
	'WHILE'.IFT <TRUE>
.;
	;
	;	MENY
	;	====
	;
	;	<RET>	]TERG]/AVSLUTA
	;	<ESC>	SE BACKUPL[GE
	;	0	BACKUP 0 - SYSTEMKONTON P] SYSTEMDISKEN
	;	1	BACKUP 1 - PDISP REGISTER
	;	2	BACKUP 2 - MIMER REGISTER OCH -96 ANV[NDARKONTON, RADIODRIFT
	;	3	BACKUP 3 - PLAN.-AVD. REGISTER F\R TRAFIKLEDNINGSSYSTEMET
	;	4	BACKUP 4 - K[LLKOD RADIOSYS - FORTRAN (RD:)
	;	5	BACKUP 5 - K[LLKOD VOLVO,VOLYVA,VOLTRE (VO:,VT:,VR:)
	;	6	BACKUP 6 - DRIFTSPROGRAM, VFS-SYSTEMET, TAX/LIO-SYSTEMET SAMT
	;			   APPL-BIBLIOTEK (166,300),(110,60),(110,231),(200,147)
	;
.;
	.ASKN [0:6:0:10S] KOD DIT VAL :
.;
	'IF'.IFT <DEFAUL>
.;
		; BACKUP - INITIERING AVSLUTAD
		'BREAK'
.;
	'ELSIF'.IFT <ESCAPE>
.;
		.DISABLE QUIET
		;
		;BACKUP 0
		;
		.ENABLE QUIET
		TYP LB:[1,54]BACKUP0.LBL
		.DISABLE QUIET
		;
		;BACKUP 1
		;
		.ENABLE QUIET
		TYP LM:[166,301]BACKUP1.LBL
		.DISABLE QUIET
		;
		;BACKUP 2
		;
		.ENABLE QUIET
		TYP LB:[1,300]BACKUP2.LBL
		.DISABLE QUIET
		;
		;BACKUP 3
		;
		.ENABLE QUIET
		TYP RA:[200,120]BACKUP3.LBL
		.DISABLE QUIET
		;
		;BACKUP 4
		;
		.ENABLE QUIET
		TYP RB:[200,120]BACKUP4RB.LBL
		.DISABLE QUIET
		;
		;BACKUP 5
		;
		.ENABLE QUIET
		TYP VO:[200,142]BACKUP5VO.LBL
		TYP VT:[200,142]BACKUP5VT.LBL
		TYP VR:[200,142]BACKUP5VR.LBL
		.DISABLE QUIET
		;
		;BACKUP 6
		;
		.ENABLE QUIET
		TYP WI:[200,147]BACKUP6.LBL
		.DISABLE QUIET
.;
	'ELSIF'.IFACT BACKUP
.;
		;BACKUP - BACKUP P]G]R, F\RS\K SENARE
.;
	'ELSE'
.;
		.SETS $XSPC ""
		.TEST $XSPC
		'WHILE'.IF <STRLEN> LT 2
			.ASKS $XSPC Dina initialer, tack >
			.TEST $XSPC
		'ENDDO'
.;
		'IF'.IF <UIC> NE "[1,2]"
			; EJ TILL]TET K\RA UNDER ANNAT UIC [N 1,2
			'BREAK'
		'ENDIF'
.;
		.TESTDEVICE TI:
		.PARSE <EXSTRI> "," VAR1 VAR2
		'IF'.IF VAR1 NE "TT0:"
			; EJ TILL]TET K\RA FR]N ANNAT H]LL [N FR]N KONSOLEN
			'BREAKIF'.IF $XSPC NE "930BTA"
		'ENDIF'
.;
		'IF'.IF $XSPC EQ "930BTA"
			.SETF XPLA
		'ELSE'
			.SETT XPLA
		'ENDIF'
.;
		'PERFORM' SETDATE
		.ENABLE QUIET
.;
		'PERFORM' BACKAUPP
		'BREAK'
.;
	'ENDIF'
.;
	'ENDDO'
.;
	.EXIT
.;
;
;;;;;   # BACKAUPP ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
	'SECTION' BACKAUPP
.;
	.ENABLE QUIET
	.XQT RUN $ICP/TASK=BACKUP/CMD="@LB:[1,2]BACKUP'KOD' '$XSPC' 'KOD' 'DAT'"/EST=NO
.;
	'ENDSECT'
;
;;;;;   # SETDATE ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
	'SECTION' SETDATE
.;
	.SETS DATD <DATE>
	.SETS DAT03 DATD[8:9]		!OBS -- DECIMALT
	.SETS DAT01 DATD[1:2]
	.SETS DAT02 DATD[4:6]
	.IF DAT02 EQ "JAN" .SETS DAT00 "01"
	.IF DAT02 EQ "FEB" .SETS DAT00 "02"
	.IF DAT02 EQ "MAR" .SETS DAT00 "03"
	.IF DAT02 EQ "APR" .SETS DAT00 "04"
	.IF DAT02 EQ "MAY" .SETS DAT00 "05"
	.IF DAT02 EQ "JUN" .SETS DAT00 "06"
	.IF DAT02 EQ "JUL" .SETS DAT00 "07"
	.IF DAT02 EQ "AUG" .SETS DAT00 "08"
	.IF DAT02 EQ "SEP" .SETS DAT00 "09"
	.IF DAT02 EQ "OCT" .SETS DAT00 "10"
	.IF DAT02 EQ "NOV" .SETS DAT00 "11"
	.IF DAT02 EQ "DEC" .SETS DAT00 "12"
	.SETS DATD DAT03+DAT00+DAT01		!DEFAULT DATE
.;
	'WHILE'.IFT <TRUE>
		'IF'.IFT XPLA
			;ANGE NEDAN \NSKAT DATUM (6 SIFFROR, T.EX. 880615)
			;ELLER <RETURN> OM 'DATD' DUGER. ANGE NORMALT <RETURN>.
		'ENDIF'
		.ASKS DAT BACKUP-DATUM ('DATD')
		.TEST DAT
		'IF'.IF <STRLEN> EQ 0
			.SETS DAT DATD
		'ENDIF'
		.TEST DAT
		'IF'.IF <STRLEN> EQ 6
			.SETF SJUKT			!ANTAG EJ SJUKT
			.IF DAT00 NE DAT[3:4] .SETT SJUKT
			.IF DAT03 NE DAT[1:2] .SETT SJUKT
			.SETT GO
			'IF'.IFT SJUKT
				;ANGIVET DATUM 'DAT' VERKAR SJUKT
				.ASK GO [R DET OK
			'ENDIF'
			'BREAKIF'.IFT GO
		'ENDIF'
.;
	'ENDDO'
.;
	'ENDSECT'
.;
;
;	<EOF> LB:[1,2]BACKUP.SAT
;