.TITLE	TICGRD - ROUTINE TO DISPLAY TIC MARKS ON GRIDS

.IDENT	'TICG00'

.PSECT	TICGRD

;	KEN DEMERS
;	UTRC
;	NOVEMBER 1979

;	THIS ROUTINE DISPLAYS TIC MARKS ON THE GRAPH.
;	THE TIC MARKS ARE ACTUALLY SMALL CROSSES. THEY
;	ARE DISPLAYED ONLY ALONG THE X AND Y GRIDS.
;	CALLING FORMAT:

;	CALL TICGRD(XSPACE,YSPACE)

;	WHERE:

;	XSPACE = F.P. VIRTUAL X COORDINATE SPACING BETWEEN TIC MARKS

;	YSPACE = F.P. VIRTUAL Y COORDINATE SPACING BETWEEN TIC MARKS

;	INTERNAL GLOBALS

.GLOBL	TICGRD

;	EXTERNAL GLOBALS

.GLOBL	T$ICMKG,V$IRABS,X$GRDLO,Y$GRDLO
.GLOBL	X$RANGE,Y$RANGE,X$MXCOR,Y$MXCOR
.GLOBL	M$AX,M$IN,C$HNG,X$ORY
.GLOBL	R$IDGX,R$IDGY

;	ASSIGNMENTS

AC0	= %0			;FPP ACCULUMULATOR 0
AC1	= %1
AC2	= %2



TICGRD:	TST	(R5)+		;BUMP PTR PAST # ARGS LOC
	SETF			;SET FPP MODE TO S.P.
	SETI			;SET FPP MODE TO SHORT INTEGER
	MOV	(R5)+,R0	;R0= A(VIRTUAL F.P. #)
	LDF	X$RANGE,AC1	;AC1= (X$RANGE)
	LDCIF	#X$MXCOR,AC0	;AC0= F.P. OF ABS INT X M$AX
	CALL	V$IRABS		;CONVERT IT TO INTEGER ABS. X SPACING
	MOV	R0,R2		;SAVE X SPACING
	MOV	(R5),R0		;R0= A(VIRTUAL F.P. #)
	LDF	Y$RANGE,AC1	;AC1= (Y$RANGE)
	LDCIF	#Y$MXCOR,AC0	;AC0= F.P. OF ABS INT Y M$AX
	CALL	V$IRABS		;CONVERT IT TO INTEGER ABS. Y SPACING
	MOV	R0,R3		;SAVE Y SPACING
	MOV	X$GRDLO,R0	;R0= X GRID COORD
	MOV	Y$GRDLO,R1	;R1= Y GRID COORD
	MOV	#X$MAXCO,M$AX	;M$AX= X M$AX COORD
	MOV	#R$IDGX,M$IN	;MIN= X MIN COORD
	MOV	R0,C$HNG		;X COORD WILL BE CHANGING
	CLR	X$ORY		;FLG=0= PLT X TICX
	CALL	T$ICMKG		;PUT TICS ON X GRID
	MOV	X$GRDLO,R0	;R0= X GRID  COORD
	MOV	Y$GRDLO,R1	;R1= Y GRID COORDINATE
	MOV	#Y$MAXCO,M$AX	;M$AX= Y M$AX COORD
	MOV	#R$IDGY,M$IN	;MIN= Y MIN COORD
	MOV	R3,R2		;R2= Y SPACING
	MOV	R1,C$HNG		;Y COORD WILL BE CHANGING
	MOV	#1,X$ORY	;FLG=1= PUT TICKS ON Y GRID
	CALL	T$ICMKG		;PUT TICS ON Y GRID
	RETURN
	.END