.TITLE	GET - START TASK FROM DM0:[GROUP]
	.IDENT	/V02/
;+
;-
	.MCALL	CHN$T,CDBDF$,EXIT$S,ESBDF$,GMCR$,DIR$,GTSK$
	.MCALL	ISTAT$,STATE$,TRAN$
;
;
CTDB::	CDBDF$	CMDA,CMDL,TS.USE,ESB
;
ESB::	ESBDF$
;
CMD::	GMCR$
GTSK:	GTSK$	GTBUF
GTBUF:	.BLKW	16.
;
CMDA::	.ASCII	/ DM0:/
DIR:	.ASCII	/[100,100]/
CMDL=.-CMDA
;
FILE:	.BLKB	9.
	.EVEN
FLEN:	.WORD	0
;
	ISTAT$	GETFIL,KEYWD
;
GET::
	DIR$	#CMD
	CLR	R1
	MOV	#KEYWD,R2
	MOV	@#0,R3
	MOV	#CMD+2,R4
	MOV	#GETFIL,R5
	CALL	.TPARS
	CHN$T	#CTDB,,FLEN
	EXIT$S
;
;
;
	STATE$	GETFIL
	TRAN$	"GET"
;
	STATE$
	TRAN$	'$,GETNAM	; USE [100,100] FOR $FILE
	TRAN$	$LAMDA,,GETUIC	; USE [GROUP,GROUP] FOR FILE
;
	STATE$	GETNAM
	TRAN$	$RAD50,,MOVFIL
;
	STATE$
	TRAN$	$LAMDA,$EXIT
;

GETUIC:	MOV	R2,-(SP)
	MOV	R3,-(SP)
	MOV	R4,-(SP)
	DIR$	#GTSK
	MOVB	GTBUF+G.TSGC,GTBUF
	MOVB	GTBUF,GTBUF+1
	MOV	GTBUF,R3
	MOV	#1,R4		; NO 0 SUPPRESS, PUT IN DELIMITERS
	MOV	#DIR,R2
	CALL	.PPASC
	MOV	(SP)+,R4
	MOV	(SP)+,R3
	MOV	(SP)+,R2
	RETURN
;
MOVFIL:	MOV	R0,-(SP)
	MOV	R1,-(SP)
	MOV	R2,-(SP)
	MOV	.PSTCN,R1
	BEQ	2$
	MOV	R1,FLEN
	ADD	#CMDL,FLEN
	MOV	.PSTPT,R2
	MOV	#FILE,R0
1$:	MOVB	(R2)+,(R0)+
	SOB	R1,1$
2$:	MOV	(SP)+,R2
	MOV	(SP)+,R1
	MOV	(SP)+,R0
	RETURN
	.END	GET