.TITLE  MSUBD  SUBTRACTION OF TWO MATRICES (DOUBLE PRECISION)
	.IDENT  /1.0/					;  08/15/79
	.GLOBL  MSUBD, M3SUBD, MPSUBD
	.ENABL	LSB
;
F0=R0				;DEFINE FLOATING REGISTER 0
F1=R1				;DEFINE FLOATING REGISTER 1
M3SUBD:	CMP	#3,(R5)		;CHECK FOR 3 ARGUMENTS
	BNE	BOMB3		;BOMB IF # OF ARGS. NE 3
	MOV	#3,R0		;R0=M=3
	MOV 	R0,R1		;R1=N=3
	BR	20$
MPSUBD:	CMP	#10,(R5)	;ARE THERE 8 ARGUMENTS?
	BNE	BOMBP		;BOMB IF # OF ARGS. NE 8
	MOV	@10(R5),R0	;R0=M
	MOV	@12(R5),R1	;R1=N
	MOV 	R0,-(SP)	;MOVE M ON STACK
	MOV	@14(R5),R2	;GET NRA
	SUB	R0,R2		;NRA-M
	ASH	#3,R2		;R2=8*(NRA-M)
	MOV	@16(R5),R3	;GET NRB
	SUB	R0,R3		;NRB-M
	ASH	#3,R3		;R3=8*(NRB-M)
	MOV	R3,-(SP)	;MOVE 8*(NRB-M) ON STACK
	MOV	@20(R5),R3	;GET NRC
	SUB	R0,R3		;NRC-M
	ASH	#3,R3		;8*(NRC-M)
	MOV	R3,-(SP)	;MOVE 8*(NRC-M) ON STACK
	BR	40$
MSUBD:	CMP	#5,(R5)		;CHECK FOR 5 ARGUMENTS
	BNE	BOMB		;BOMB IF # OF ARGS. NE 5
	MOV	@10(R5),R0	;R0=M
	MOV	@12(R5),R1	;R1=N
20$:	MOV	R0,-(SP)	;MOVE M ON STACK
	MOV	#0,R2		;R2=8*(NRA-M)=0
	MOV	R2,-(SP)	;8*(NRB-M)=0 TO STACK 
	MOV	R2,-(SP)	;8*(NRC-M)=0 TO STACK 
40$:	MOV	2(R5),R3	;R3=ADDRESS OF C
	MOV	4(R5),R4	;R4=ADDRESS OF A
	MOV	6(R5),R5	;R5=ADDRESS OF B
	SETD			;SET FLOATING DOUBLE MODE
	BR	60$
;LOOP TO SUBTRACT 2 MATRICES
50$:	ADD	(SP),R3		;GO TO START OF NEXT COLUMN OF C
	ADD	R2,R4		;GO TO START OF NEXT COLUMN OF A
	ADD	2(SP),R5	;GO TO START OF NEXT COLUMN OF B
	MOV	4(SP),R0	;RESET M
60$:	LDD	(R4)+,F0	;A(I)
	LDD	(R5)+,F1	;B(I)
	SUBD	F1,F0		;A(I)-B(I)
	STD	F0,(R3)+	;C(I)=A(I)-B(I)
	SOB	R0,60$		;DONE WITH THIS COLUMN?
	SOB	R1,50$		;DONE WITH ALL COLUMNS?
	ADD	#6,SP		;RESTORE STACK
	RTS	PC		;RETURN
BOMBP:	MOV	#101624,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#51723,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	70$
BOMB3:	MOV	#101624,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#53173,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	70$
BOMB:	MOV	#6640,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#52115,R4	;MOVE 1ST HALF OF NAME TO R4
70$:	JSR	R4,NAM$		;SUBR TO PUT NAME IN WALKBACK
	JMP	$BOMB		;ABORT, $BOMB DOES NOT EXIST
	.END