.TITLE  MSUB  SUBTRACTION OF TWO MATRICES 
	.IDENT  /1.0/					;  08/15/79
;+							     ++EXTSPC>>
;.NAME MSUB
;.INDEX M3SUB
;.INDEX MPSUB
;.INDEX MSUBD
;.INDEX M3SUBD
;.INDEX MPSUBD
;.TITLE  SUBROUTINE MSUB 
;
;		CALL MSUB   (C,A,B,M,N)
;
;		CALL M3SUB  (C,A,B)
;
;		CALL MPSUB  (C,A,B,M,N,NRA,NRB,NRC)
;
;		CALL MSUBD  (C,A,B,M,N)
;
;		CALL M3SUBD (C,A,B)
;
;		CALL MPSUBD (C,A,B,M,N,NRA,NRB,NRC)
;
; VERSION:  VECTOR / MATRIX ROUTINES     SAM MILLER     REL 1.0  
;
; FUNCTION:
;
;	MATRIX SUBTRACTION 
;
;	C = A - B
;
;
; LANGUAGE:  MACRO-11
;
;
; ARGUMENTS:
;
;       C   = OUTPUT MATRIX (RESULT IS STORED IN UPPER M X N SUBMATRIX)
;       A,B = INPUT  MATRICES
;       M,N = UPPER M X N SUBMATRICES ARE SUBTRACTED (A - B)
;       NRA = NUMBER OF ROWS IN A
;       NRB = NUMBER OF ROWS IN B
;       NRC = NUMBER OF ROWS IN C
;
;
; COMMONS:
;
;	(NONE)
;
;
; GENERAL DESCRIPTION:
;
;  REAL ARGUMENTS: C,A,B
;  INTEGER ARGUMENTS: M,N,NRA,NRB,NRC
;
;
;       SINGLE PRECISION -      MSUB    FOR MXN MATRICES
;                               M3SUB   FOR 3X3 MATRICES
;                               MPSUB   FOR UPPER MXN SUBMATRICES
;
;       DOUBLE PRECISION -      MSUBD   FOR MXN MATRICES
;                               M3SUBD  FOR 3X3 MATRICES
;                               MPSUBD  FOR UPPER MXN SUBMATRICES
;
;
;
; PERIPHERAL INPUT/OUTPUT:
;
;	(NONE)
;
;
; LOGICAL UNIT USAGE:
;
;	(NONE)
;
;
; EXTERNAL ROUTINES CALLED:
;
;	NAM$
;	$BOMB
;
;-							     --EXTSPC>>
;
; WRITTEN BY:
;
;       DENIS MAHONY AND SAM MILLER     08/15/79
;
;
; MODIFIED BY:
;
;	**********	**DATE**
;		**DETAIL**
;
;-							--EXTSPC>>
	.PAGE
	.GLOBL  MSUB, M3SUB, MPSUB
	.ENABL	LSB
;
F0=R0				;DEFINE FLOATING REGISTER 0
F1=R1				;DEFINE FLOATING REGISTER 1
M3SUB:	CMP	#3,(R5)		;CHECK FOR 3 ARGUMENTS
	BNE	BOMB3		;BOMB IF # OF ARGS. NE 3
	MOV	#3,R0		;R0=M=3
	MOV 	R0,R1		;R1=N=3
	BR	20$
MPSUB:	CMP	#10,(R5)	;ARE THERE 8 ARGUMENTS?
	BNE	BOMBP		;BOMB IF # OF ARGS. NE 8
	MOV	@10(R5),R0	;R0=M
	MOV	@12(R5),R1	;R1=N
	MOV 	R0,-(SP)	;MOVE M ON STACK
	MOV	@14(R5),R2	;GET NRA
	SUB	R0,R2		;NRA-M
	ASH	#2,R2		;R2=4*(NRA-M)
	MOV	@16(R5),R3	;GET NRB
	SUB	R0,R3		;NRB-M
	ASH	#2,R3		;R3=4*(NRB-M)
	MOV	R3,-(SP)	;MOVE 4*(NRB-M) ON STACK
	MOV	@20(R5),R3	;GET NRC
	SUB	R0,R3		;NRC-M
	ASH	#2,R3		;4*(NRC-M)
	MOV	R3,-(SP)	;MOVE 4*(NRC-M) ON STACK
	BR	40$
MSUB:	CMP	#5,(R5)		;CHECK FOR 5 ARGUMENTS
	BNE	BOMB		;BOMB IF # OF ARGS. NE 5
	MOV	@10(R5),R0	;R0=M
	MOV	@12(R5),R1	;R1=N
20$:	MOV	R0,-(SP)	;MOVE M ON STACK
	MOV	#0,R2		;R2=4*(NRA-M)=0
	MOV	R2,-(SP)	;4*(NRB-M)=0 TO STACK 
	MOV	R2,-(SP)	;4*(NRC-M)=0 TO STACK 
40$:	MOV	2(R5),R3	;R3=ADDRESS OF C
	MOV	4(R5),R4	;R4=ADDRESS OF A
	MOV	6(R5),R5	;R5=ADDRESS OF B
	SETF			;SET FLOATING MODE
	BR	60$
;LOOP TO SUBTRACT 2 MATRICES
50$:	ADD	(SP),R3		;GO TO START OF NEXT COLUMN OF C
	ADD	R2,R4		;GO TO START OF NEXT COLUMN OF A
	ADD	2(SP),R5	;GO TO START OF NEXT COLUMN OF B
	MOV	4(SP),R0	;RESET M
60$:	LDF	(R4)+,F0	;A(I)
	LDF	(R5)+,F1	;B(I)
	SUBF	F1,F0		;A(I)-B(I)
	STF	F0,(R3)+	;C(I)=A(I)-B(I)
	SOB	R0,60$		;DONE WITH THIS COLUMN?
	SOB	R1,50$		;DONE WITH ALL COLUMNS?
	ADD	#6,SP		;RESTORE STACK
	RTS	PC		;RETURN
BOMBP:	MOV	#101620,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#51723,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	70$
BOMB3:	MOV	#101620,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#53173,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	70$
BOMB:	MOV	#6200,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#52115,R4	;MOVE 1ST HALF OF NAME TO R4
70$:	JSR	R4,NAM$		;SUBR TO PUT NAME IN WALKBACK
	JMP	$BOMB		;ABORT, $BOMB DOES NOT EXIST
	.END