.TITLE  MCOM  LINEAR COMBINATION OF TWO MATRICES 
	.IDENT  /1.0/					;  08/15/79
;+							     ++EXTSPC>>
;.NAME MCOM
;.INDEX M3COM
;.INDEX MPCOM
;.INDEX MCOMD
;.INDEX M3COMD
;.INDEX MPCOMD
;.TITLE  SUBROUTINE MCOM 
;
;		CALL MCOM   (C,P,A,Q,B,M,N)
;
;		CALL M3COM  (C,P,A,Q,B)
;
;		CALL MPCOM  (C,P,A,Q,B,M,N,NRA,NRB,NRC)
;
;		CALL MCOMD  (C,P,A,Q,B,M,N)
;
;		CALL M3COMD (C,P,A,Q,B)
;
;		CALL MPCOMD (C,P,A,Q,B,M,N,NRA,NRB,NRC)
;
; VERSION:  VECTOR / MATRIX ROUTINES     SAM MILLER     REL 1.0  
;
; FUNCTION:
;
;	LINEAR COMBINATION OF TWO MATRICES 
;
;	C = P*A + Q*B
;
;
; LANGUAGE:  MACRO-11
;
;
; ARGUMENTS:
;
;       C   = OUTPUT MATRIX (RESULT IS STORED IN UPPER M X N SUBMATRIX)
;       P,Q = SCALARS
;       A,B = INPUT  MATRICES
;       M,N = UPPER M X N SUBMATRICES ARE USED 
;       NRA = NUMBER OF ROWS IN A
;       NRB = NUMBER OF ROWS IN B
;       NRC = NUMBER OF ROWS IN C
;
;
; COMMONS:
;
;	(NONE)
;
;
; GENERAL DESCRIPTION:
;
;	REAL ARGUMENTS: C,P,A,Q,B
;	INTEGER ARGUMENTS: M,N,NRA,NRB,NRC
;
;
;       SINGLE PRECISION -      MCOM    FOR MXN MATRICES
;                               M3COM   FOR 3X3 MATRICES
;                               MPCOM   FOR UPPER MXN SUBMATRICES
;
;       DOUBLE PRECISION -      MCOMD   FOR MXN MATRICES
;                               M3COMD  FOR 3X3 MATRICES
;                               MPCOMD  FOR UPPER MXN SUBMATRICES
;
;
;
; PERIPHERAL INPUT/OUTPUT:
;
;	(NONE)
;
;
; LOGICAL UNIT USAGE:
;
;	(NONE)
;
;
; EXTERNAL ROUTINES CALLED:
;
;	NAM$
;	$BOMB
;
;-							     --EXTSPC>>
;
; WRITTEN BY:
;
;       DENIS MAHONY AND SAM MILLER     08/15/79
;
;
; MODIFIED BY:
;
;	**********	**DATE**
;		**DETAIL**
;
;-							--EXTSPC>>
	.PAGE
	.GLOBL  MCOM, M3COM, MPCOM
	.ENABL	LSB
;
F0=R0				;DEFINE FLOATING REGISTER 0
F1=R1				;DEFINE FLOATING REGISTER 1
F2=R2				;DEFINE FLOATING REGISTER 2
F3=R3				;DEFINE FLOATING REGISTER 3
M3COM:	CMP	#5,(R5)+	;CHECK FOR 5 ARGUMENTS
	BNE	BOMB3		;BOMB IF # OF ARGS. NE 5
	MOV	#3,R0		;R0=M=3
	MOV 	#3,R1		;R1=N=3
	MOV	#3,-(SP)	;MOVE M ON STACK
	BR	20$
MCOM:	CMP	#7,(R5)+	;ARE THERE 7 ARGUMENTS?
	BNE	BOMB		;BOMB IF # OF ARGS. NE 7
	MOV	@12(R5),R0	;R0=M
	MOV	@14(R5),R1	;R1=N
	MOV 	R0,-(SP)	;MOVE M ON STACK
20$:	MOV	#0,-(SP)	;MOVE 4*(NRB-M)=0 ON STACK
	MOV	#0,-(SP)	;MOVE 4*(NRC-M)=0 ON STACK
	MOV	#0,R2		;R2=4*(NRA-M)=0
	BR	40$
MPCOM:	CMP	#12,(R5)+	;ARE THERE 10 ARGUMENTS?
	BNE	BOMBP		;BOMB IF # OF ARGS. NE 10
	MOV	@12(R5),R0	;R0=M
	MOV	@14(R5),R1	;R1=N
	MOV	R0,-(SP)	;MOVE M ON STACK
	MOV	@16(R5),R2	;GET NRA
	SUB	R0,R2		;NRA-M
	ASH	#2,R2		;R2=4*(NRA-M)
	MOV	@20(R5),R3	;GET NRB
	SUB	R0,R3		;NRB-M
	ASH	#2,R3		;4*(NRB-M)
	MOV	R3,-(SP)	;MOVE 4*(NRB-M) ON STACK
	MOV	@22(R5),R3	;GET NRC
	SUB	R0,R3		;NRC-M
	ASH	#2,R3		;4*(NRC-M)
	MOV	R3,-(SP)	;MOVE 4*(NRC-M) ON STACK
40$:	MOV	(R5)+,R3	;R3=ADDRESS OF C
	MOV	2(R5),R4	;R4=ADDRESS OF A
	SETF			;SET FLOATING MODE
	LDF	@(R5),F2	;F2=P
	LDF	@4(R5),F3	;F3=Q
	MOV	6(R5),R5	;R5=ADDRESS OF B
	BR	60$
;LOOP TO COMBINE 2 MATRICES
50$:	ADD	(SP),R3		;GO TO START OF NEXT COLUMN OF C
	ADD	R2,R4		;GO TO START OF NEXT COLUMN OF A
	ADD	2(SP),R5	;GO TO START OF NEXT COLUMN OF B
	MOV	4(SP),R0	;RESET M
60$:	LDF	(R4)+,F0	;A(I)
	MULF	F2,F0		;P*A(I)
	LDF	(R5)+,F1	;B(I)
	MULF	F3,F1		;Q*B(I)
	ADDF	F0,F1		;P*A(I)+Q*B(I)
	STF	F1,(R3)+	;C(I)=P*A(I)+Q*B(I)
	SOB	R0,60$		;DONE WITH THIS COLUMN?
	SOB	R1,50$		;DONE WITH ALL COLUMNS?
	ADD	#6,SP		;RESTORE STACK
	RTS	PC		;RETURN
BOMBP:	MOV	#57710,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#51703,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	70$
BOMB3:	MOV	#57710,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#53153,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	70$
BOMB:	MOV	#50500,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#50707,R4	;MOVE 1ST HALF OF NAME TO R4
70$:	JSR	R4,NAM$		;SUBR TO PUT NAME IN WALKBACK
	JMP	$BOMB		;ABORT, $BOMB DOES NOT EXIST
	.END