.TITLE  MCLRD  CLEARS A MATRIX  (DOUBLE PRECISION)
	.IDENT  /1.0/					;  08/15/79
	.GLOBL  MCLRD, M3CLRD, MPCLRD
	.ENABL	LSB
;
F0=R0				;DEFINE FLOATING REGISTER 0
M3CLRD:	CMP	#1,(R5)+	;CHECK FOR 1 ARGUMENTS
	BNE	BOMB3		;BOMB IF # OF ARGS. NE 1
	MOV	#3,R0		;R0=M=3
	MOV 	R0,R1		;R1=N=3
	BR	20$
MPCLRD:	CMP	#4,(R5)+	;CHECK FOR 4 ARGUMENTS
	BNE	BOMBP		;BOMB IF # OF ARGS. NE 4
	MOV	@2(R5),R0	;R0=M
	MOV	@4(R5),R1	;R1=N
	MOV	R0,R2		;R2=M
	MOV	@6(R5),R3	;GET NRC
	SUB	R0,R3		;NRC-M
	ASH	#3,R3		;R3=8*(NRC-M)
	BR	40$
MCLRD:	CMP	#3,(R5)+	;CHECK FOR 3 ARGUMENTS
	BNE	BOMB		;BOMB IF # OF ARGS. NE 3
	MOV	@2(R5),R0	;R0=M
	MOV	@4(R5),R1	;R1=N
20$:	MOV	R0,R2		;R2=M
	MOV	#0,R3		;R3=8*(NRC-M)=0 
40$:	MOV	(R5),R4		;R4=ADDRESS OF C
	SETD			;SET FLOATING DOUBLE MODE
	CLRD	F0		;F0=0
	BR	60$
;LOOP TO CLEAR MATRIX
50$:	ADD	R3,R4		;GO TO START OF NEXT COLUMN OF C
	MOV	R2,R0		;RESET M
60$:	STD	F0,(R4)+	;C(I)=0
	SOB	R0,60$		;DONE WITH THIS COLUMN?
	SOB	R1,50$		;DONE WITH ALL COLUMNS?
	RTS	PC		;RETURN
BOMBP:	MOV	#46724,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#51703,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	70$
BOMB3:	MOV	#46724,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#53153,R4	;MOVE 1ST HALF OF NAME TO R4
	BR	70$
BOMB:	MOV	#70440,-(SP)	;MOVE 2ND HALF OF NAME TO STACK
	MOV	#50704,R4	;MOVE 1ST HALF OF NAME TO R4
70$:	JSR	R4,NAM$		;SUBR TO PUT NAME IN WALKBACK
	JMP	$BOMB		;ABORT, $BOMB DOES NOT EXIST
	.END