* 77-68 BUG 1 VERSION 01. MODIFIED FOR ACIA-B.
* ( SAMPLE OF 6800 SOURCE CODE )
*
***************************************************
*
* 77-68 IS A KIT-COMPUTER SYSTEM BASED ON THE MOTOROLA
* 6800 MICROCOMPUTER CHIP.
*
* COPYRIGHT OF 77-68 BELONGS TO:
*	NEWBEAR COMPUTING STORE
*	40, BARTHOLEMEW ST.
*	NEWBURY,  BERKS.
*	ENGLAND.
*
* THIS SOFTWARE APPEARS IN THE 77-68 DESIGN MANUAL
* AND WAS PUBLISHED IN THE JOURNAL OF THE AMATEUR COMPUTER
* CLUB IN ENGLAND.
*
********************************************************
*
	ORG	$FF00
CTRL.A	EQU $F401
CTRL.B	EQU $F403
DATA.A	EQU $F400
DATA.B	EQU $F402
TOPSTK	EQU $F0F3
USRSTK	EQU $F0D0	*STOPS FUNNIES
JMPNMI	EQU $F0F5
JMPIRQ	EQU $F0F8
TMPXHI	EQU $F0FB
TMPXLO	EQU TMPXHI+1
TMPSTK	EQU $F0FD

RESET	LDS	#USRSTK
	LDAA	#$3
	STAA	CTRL.A
	STAA	CTRL.B
SWINT	STS	TMPSTK
RSTART	LDS	#TOPSTK
	LDAA	#$11
	STAA	CTRL.A
	STAA	CTRL.B
	BSR	PCRLF
	BSR	GAPCH
	CMPA	#'A
	BEQ	ALTER
	CMPA	#'C
	BEQ	CONT
	CMPA	#'G
	BEQ	GOGOGO
	CMPA	#'R
	BEQ	REGPNT
	CMPA	#'E
	BNE	RSTART
	BSR	GETADR
EXAMLP	BSR	P2HAS
	BSR	GETCH
	CMPA	#$20
	BNE	RSTART
	INX
	BRA	EXAMLP
GOGOGO	BSR	GETADR
	LDX	TMPSTK
	INX
	INX
	INX
	INX
	INX
	INX
	LDAA	TMPXHI
	STAA	,X
	LDAA	TMPXLO
	STAA	1,X
CONT	LDS	TMPSTK
	RTI
ALTER	BSR	GETADR
ALTLP	BSR	HEX2IN
	STAA	,X
	INX
	BRA	ALTLP
REGPNT	BSR	PNTSP
	LDX	TMPSTK
	BSR	IP2HAS
	BSR	IP2HAS
	BSR	IP2HAS
	BSR	IP4HAS
	BSR	IP4HAS
	LDX	#TMPSTK
	BSR	P4HAS
START2	BRA	RSTART
PCRLF	LDAA	#$0D
	BSR	PNTCH
	LDAA	#$0A
	BSR	PNTCH
	LDAA	#'*
	BRA	PNTCH
GETCH	LDAA	CTRL.B
	ASRA
	BCC	GETCH
	LDAA	DATA.B
	ANDA	#$7F
	RTS
GAPCH	BSR	GETCH
PNTCH	LDAB	CTRL.B
	BITB	#2
	BEQ	PNTCH
	STAA	DATA.B
	RTS
IP4HAS	INX
P4HAS	BSR	P2HEX
IP2HAS	INX
P2HAS	BSR	P2HEX
PNTSP	LDAA	#$20
	BRA	PNTCH
GETADR	BSR	PNTSP
	BSR	HEX2IN
	STAA	TMPXHI
	BSR	HEX2IN
	STAA	TMPXLO
	LDX	TMPXHI
	BRA	PNTSP
HEX2IN	BSR	GETHEX
	ASLA
	ASLA
	ASLA
	ASLA
	PSHA
	BSR	GETHEX
	ANDA	#$0F
	PULB
	ABA
	RTS
P2HEX	LDAA	,X
	BSR	PNTLH
	LDAA	,X
	BRA	PNTRH
PNTLH	LSRA
	LSRA
	LSRA
	LSRA
PNTRH	ANDA	#$0F
	ADDA	#$30
	CMPA	#$39
	BLS	PNTCH
	ADDA	#$7
	BRA	PNTCH
GETHEX	BSR	GAPCH
	CMPA	#$30
	BMI	START2
	CMPA	#$39
	BLE	RTS
	CMPA	#$41
	BMI	START2
	CMPA	#$46
	BGT	START2
	SUBA	#$7
RTS	RTS


	ORG	$FFF8
	FDB	JMPIRQ
	FDB	SWINT
	FDB	JMPNMI
	FDB	RESET
	END