;	MACRO PROGRAM TO SEE WHAT EXTERNAL PAGE ADDRESSES ARE THERE
;
		.MCALL	DIR$,QIOW$,EXIT$S,SVTK$S
;
;
START:	MOV	#160000,R5	;START AT BEGINNING
	SVTK$S	#SSTTAB,#1	;SPECIFY TRAP VECTOR TABLE
	MOV	#1,R2		;FOR $CBOMG
	MOV	#10000,R3	;SET LOOP COUNT
REGO:	MOV	R5,R1		;ADDRESS TO R1
	MOV	#MESS,R0	;POINT TO ASCII BUFFER
				;R2=1 SO NO ZERO SUPPRESSION
	CALL	$CBOMG		;CONVERT ADDRESS
	CLR	R4		;CLEAR FLAG
	MOV	(R5),R1		;TRY TO READ ADDRESS
	ADD	#2,R5		;BUMP TO NEXT ADDRESS
	TST	R4		;SEE IF ITS THERE
	BEQ	EXISTS		;BRANCH IF ADDRESS EXISTS
	SOB	R3,REGO		;GO AGAIN
EXISTS:	MOV	#YESCON,R0	;POINT TO BUFFER
	CALL	$CBOMG		;CONVERT ADDRESS
	DIR$	#YESQIO		;PRINT ADDRESS AND CONTENTS
	SOB	R3,REGO		;AND GO AGAIN
	EXIT$S			;AND EXIT
;
;SST SERVICE ROUTINE TABLE
;
SSTTAB:	.WORD	NONEX		;ONLY ONE ENTRY
;
;SST SERVICE ROUTINE
;
NONEX:	INC	R4		;SET NON-EXISTANT FLAG
	RTI			;AND EXIT
;
;
MESS:	.ASCII	/NNNNNN	/
YESCON:	.ASCII	/NNNNNN		;/
YESLEN=.-MESS
.EVEN
;
YESQIO:	QIOW$	IO.WVB,5,1,,,,<MESS,YESLEN,40>
	.END	START