.TITLE	TTYON
;
;	PROGRAM TO CAUSE TTYLOG TO START GATHERING STATISTICS
;
;
	.MCALL	EXIT$S,MRKT$S,WTSE$S,SCHD$S,GTIM$S,DIR$,SCHD$,CSRQ$S,RQST$S
;
START:	CSRQ$S	#LOG		;CANCEL ALL REQUESTS PENDING
	CSRQ$S	#DMP
	CSRQ$S	#OFF
	GTIM$S	#TIMBUF		;GET THE CURRENT TIME
	CMP	TIMBUF+G.TIHR,#18. ;IS IT AFTER 6:00 PM ?
	BLT	15$		;BRANCH IF NOT
	JMP	2$		;OUT OF BRANCH RANGE
15$:	CMP	TIMBUF+G.TIHR,#7. ;IS IT AFTER 7:00 AM ?
	BGE	1$		;BRANCH IF YES
				;WE ARE RESTARTING IN THE EARLY AM
	JSR	PC,ERASE	;ERASE THE COMMON AREA
	SCHD$S	#LOG,,,,,#7,#0,#0,#0	;RUN TIMLOG AT 7:00 AM
	SCHD$S	#DMP,,,,,#8.,#0,#0,#0,#1,#4 ;RUN DUMP PROGRAM AT 8:00, EVERY HOUR
	SCHD$S	#OFF,,,,,#18.,#0,#0,#0	;RUN TIMOFF AT 18:00 (6:00 PM)
	EXIT$S			;AND EXIT
1$:				;WE ARE RE-STARTING DURING THE DAY
				;DON'T ERASE THE BUFFER
	RQST$S	#LOG,#GEN	;RUN TIMLOG IMMEDIATELY
	MOV	TIMBUF+G.TIHR,DUMDPB+S.CHHR	;RESET THE START TIME FOR DUMP
	INC	DUMDPB+S.CHHR	;AND START HIM ON THE HOUR
	DIR$	#DUMDPB		;AND REQUEST THE DUMP PROGRAM
	SCHD$S	#OFF,,,,,#18.,#0,#0,#0	;RUN TIMOFF AT 18:00 (6:00 PM)
	EXIT$S			;AND EXIT
2$:				;WE ARE RE-STARTING AFTER 6:00 PM
	JSR	PC,ERASE	;ERASE THE BUFFER
	SCHD$S	#LOG,,,,,#7,#0,#0,#0	;RUN TIMLOG AT 7:00 AM
	SCHD$S	#DMP,,,,,#8.,#0,#0,#0,#1,#4 ;RUN DUMP PROGRAM AT 8:00, EVERY HOUR
	SCHD$S	#OFF,,,,,#18.,#0,#0,#0	;RUN TIMOFF AT 18:00 (6:00 PM)
	EXIT$S			;AND EXIT
LOG:	.RAD50	/TTYLOG/	;TASK NAME IN RAD50
DMP:	.RAD50	/TTYDUM/	;TASK NAME IN RAD50
OFF:	.RAD50	/TTYOFF/	;TASK NAME IN RAD50
GEN:	.RAD50	/GEN   /	;GEN PARTITION NAME
TIMBUF:	.BLKW	8.		;RECEIVE TIME HERE
;
;THE SEPERATE DPB FOR VARIABLE TIME STARTING
;
DUMDPB:	SCHD$	TTYDUM,,,,,8.,0,0,0,1,4	;START HIM AT 8:AM WITH HOUR POSSIBLY
					;CHANGED
;
;SUB TO ERASE THE TIMCOM COMMON AREA
;
ERASE:	MOV	#RUN,R0		;POINT TO START OF COMMON
	MOV	#3*40.+1,R1	;NUMBER OF WORDS TO R1
11$:	CLR	(R0)+		;CLEAR OUT A WORD
	SOB	R1,11$		;DO THEM ALL
	RTS	PC		;AND RETURN
	.END	START