$ !
$ !
$	ASK	:= READ/END_OF_FILE=DONE SYS$COMMAND
$	DELETE	:= DELETE
$	EDIT	:= EDIT/EDT
$	IF	:= IF
$	LIBRARY	:= LIBRARY
$	SAY	:= WRITE SYS$OUTPUT
$	SET	:= SET
$ !
$	SAY ""
$	SAY "Installing FIGURE on your system."
$	SAY ""
$	SAVED_DEFAULT = F$LOGICAL("SYS$DISK") + F$DIRECTORY()
$	FIG_LOC = F$ENVIRONMENT("PROCEDURE")
$	FIG_LOC = F$EXTRACT(0,F$LOCATE("]",FIG_LOC)+1,FIG_LOC)
$	FIG_FILE = F$PARSE("FIG.EXE;",F$ENVIRONMENT("PROCEDURE"))
$	SET DEFAULT 'FIG_LOC'
$	IF F$SEARCH(FIG_FILE) .NES. "" THEN GOTO BUILT
$	SAY "Building FIG.EXE"
$	SAY ""
$	@FIGBLDVMS FALSE
$	SAY ""
$ BUILT:
$	ASK/PROMPT="Shall I insert the help in the system library? [Y/N]: " Q
$	IF .NOT. Q THEN GOTO NOHELP
$	SAY ""
$	ASSIGN/USER_MODE NL: SYS$OUTPUT
$	ASSIGN/USER_MODE NL: SYS$ERROR
$	EDIT/OUT=FIGVMS.HLP/COMMAND=SYS$INPUT FIGSOURCE.HLP
SET TE HCPY
D ALL "<<RSX>>"
S/<<VMS>>//WH/NOTY
EXIT
$	SET DEFAULT SYS$HELP
$	ASSIGN/USER_MODE NL: SYS$OUTPUT
$	ASSIGN/USER_MODE NL: SYS$ERROR
$	LIBRARY/REPLACE/LOG HELPLIB.HLB 'FIG_LOC'FIGVMS.HLP
$	SET DEFAULT 'FIG_LOC'
$	DELETE FIGVMS.HLP;*
$ NOHELP:
$	SAY ""
$	SAY "You may wish to move ''FIG_LOC'FIG.EXE"
$	SAY "to some central location (eg: SYS$MANAGER:). You may also"
$	SAY "wish to define FIGURE as a foreign VMS command in"
$	SAY "SYS$MANAGER:SYLOGIN.COM. For example:"
$	SAY "    $ FIG*URE :== $ SYS$MANAGER:FIG"
$	SAY ""
$ DONE:
$	SET DEFAULT 'SAVED_DEFAULT'