.TITLE	DIRMSG -- DIRRECTIVE ERROR MESSAGES
	.IDENT	/X01.00/
	.ENABLE LC
	.NLIST BEX
;
;  Author:	Gilbert J. DeLeeuw
;  Date:	May 3, 1984
;  Name:	Compress and Restore Utility
;  Function:	To generate appropriate Dirrective error message
;
;  Parameters:
;
;	R2 - Returns length of message
;	R3 - Returns address of message
;
	.MACRO	MSG	ERN,TXT
	.NCHR	L,<TXT>
	.BYTE	L
	.BYTE	ERN
	.ASCII	!TXT!
	.ENDM
;
; Table size
	TSIZ=37.
;
;  I/O Messages
MTBL:	MSG	IE.UPN,<Insufficient dynamic storage>
	MSG	IE.INS,<Specified task not installed>
	MSG	IE.PTS,<Partition too small for task>
	MSG	IE.UNS,<Insufficient dynamic storage for send>
	MSG	IE.ULN,<Unassigned LUN>
	MSG	IE.HWR,<Device driver not resident>
	MSG	IE.ACT,<Task not active>
	MSG	IE.ITS,<Directive inconsistent with task state>
	MSG	IE.FIX,<Task already fixed/unfixed>
	MSG	IE.CKP,<Issuing task not checkpointable>
	MSG	IE.TCH,<Task is checkpointable>
	MSG	IE.RBS,<Receive buffer too small>
	MSG	IE.PRI,<Privilege violation>
	MSG	IE.RSU,<Resource in use>
	MSG	IE.NSW,<No swap space available>
	MSG	IE.ILV,<Illegal vector specified>
	MSG	IE.ITN,<Invalid table number>
	MSG	IE.LNF,<Logical name not found>
	MSG	IE.AST,<Directive issued/not issued from ast>
	MSG	IE.MAP,<Illegal mapping specified>
	MSG	IE.IOP,<Window has I/O in progress>
	MSG	IE.ALG,<Alignment error>
	MSG	IE.WOV,<Address window allocation overflow>
	MSG	IE.NVR,<Invalid region ID>
	MSG	IE.NVW,<Invalid address window ID>
	MSG	IE.ITP,<Invalid TI parameter>
	MSG	IE.IBS,<Invalid send buffer size>
	MSG	IE.LNL,<LUN Locked in use>
	MSG	IE.IUI,<Invalid UIC>
	MSG	IE.IDU,<Invalid device or unit>
	MSG	IE.ITI,<Invalid time parameters>
	MSG	IE.PNS,<Partition/region not in system>
	MSG	IE.IPR,<Invalid priority>
	MSG	IE.ILU,<Invalid LUN>
	MSG	IE.IEF,<Invalid event flag>
	MSG	IE.ADP,<Part of DPB out of user's space>
	MSG	IE.SDP,<DIC or DPB size invalid>
MSGU:	MSG	0,<DIR error    >
	.EVEN
;
;  - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
;  I/O Error Checking
DIRMSG::
	MOV	$DSW,R1			;DIRRECTIVE ERROR CODE
	BGE	DONE			;NOT AN ERROR
;
; SET UP OTHER REGISTERS
	CLR	R2			;INITIALIZE R2
	MOV	#MTBL,R3		;GET ADDRESS OF TABLE
;
; Search for match
10$:	ADD	R2,R3			;POINT TO NEXT MESSAGE
	MOVB	(R3)+,R2		;LENGTH OF STRING
	MOVB	(R3)+,R4		;ERROR NUMBER
	BEQ	UNKN			;END OF TABLE REACHED
	CMP	R4,R1			;COMPARE CODES
	BNE	10$			;IF CODES MATCH, WE ARE DONE
	SEC				;SET CARRY TO INDICATE ERROR
	RTS	PC			;AND LOOP
;
; Undefined code message
UNKN:	MOV	#MSGU+12.,R0		;ADDRESS
	CLR	R2			;SUPPRESS LEADING ZERO'S
	CALL	$CBDSG			;CONVERT CODE TO ASCII
	MOVB	MSGU,R2			;LENGTH
	MOV	#MSGU+2,R3		;ADDRESS
	SEC				;SET CARRY TO INDICATE ERROR
DONE:	RTS	PC
	.END