;****************************************************************
;* 								*
;*								*
;*	DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY *
;*	EITHER FOR THE CREATION OR FOR THE CLINICAL EFFICACY	*
;*	OF THIS PROGRAM. USERS MUST ASSUME FULL RESPONSIBILITY	*
;*	FOR ANY RESULTS OR DIAGNOSES OBTAINED FROM THE USE	*
;*	OF THIS PROGRAM. QUESTIONS ON THE EXECUTION OF THIS	*
;*	PROGRAM MUST BE REFERRED BACK TO THE ORIGINAL AUTHOR.	*
;*								*
;* AUTHOR:	SALLY FORSTER					*
;*		C/O DEPARTMENT OF NUCLEAR MEDICINE		*
;*		GUY'S HOSPITAL					*
;*		LONDON, ENGLAND					*
;*								*
;*		TEL: 01-407-7600 EXT 2583/4			*
;*								*
;****************************************************************
;
;	REWRITTEN BY G. GUELFI DEC-83
;
;	SO LNUM CARRIES DATA BETWEEN WRITEL AND NLNE AND NOT R2
;	R1 CLEARED ON RETURN TO WRITEL

;
	.TITLE	VSVW MESSAGE ON VSV
	.MCALL	.TTYIN
	.GLOBL	WRITEL,CHPOS,VCCSR,VCPOS,VCPOSH,NLNE,LNUM
WRITEL:	MOV	%0,-(%6)
	MOV	%1,-(%6)
	MOV	%2,-(%6)
	MOV	%3,-(%6)
	MOV	%4,-(%6)
	MOVB	CHPOS,%1
	MOVB	CHPOS+1,LNUM
	MOVB	(%5),%0			;ALLOW RUBOUT IF 3 PARAM
	ADD	#2,%5
	MOV	(%5)+,%4
	MOV	@(%5)+,%3		;NO OF CHARS
	BIS	#2000,@VCCSR		;DISABLE CURSOR
1$:	TST	@VCCSR			;NEXT CHARACTER
	BPL	1$
	CMPB	(%4),#11
	BNE	11$
	MOVB	#40,(%4)
11$:	CMPB	(%4),#15
	BNE	2$
	INC	%4
	JSR	%7,NLNE
	CLR	%1
	BR	1$
2$:	CMPB	(%4),#40
	BLT	21$
	CMPB	(%4),#140
	BGT	21$
	MOVB	(%4),@VCCSR
	INC	%1
21$:	INC	%4
	DEC	%3
	BLE	3$			;LAST CHARACTER
	CMPB	#65.,%1
	BNE	1$
	JSR	%7,NLNE
	CLR	%1
	BR	1$
3$:	CMPB	#3,%0
	BNE	6$
	.TTYIN
	CMPB	#15,%0
	BEQ	4$
	CMPB	#177,%0
	BNE	5$
	MOVB	#43,@VCCSR
	JSR	%7,NLNE
	CLR	%1
	MOVB	#72,@VCCSR
	INC	%1
	MOV	#1,@(%5)
	BR	6$
4$:	.TTYIN
5$:	JSR	%7,NLNE
	CLR	%1
	CLR	@(%5)
6$:	MOVB	%1,CHPOS
	MOVB	LNUM,CHPOS+1		;RETURN POSITION
	MOV	(%6)+,%4
	MOV	(%6)+,%3
	MOV	(%6)+,%2
	MOV	(%6)+,%1
	MOV	(%6)+,%0
	RTS	%7
	.END	WRITEL