.TITLE	QCHK
	.IDENT	/V3.00/
	.ENABL	LC
	.NLIST	BEX

;+
; **-QCHK-Check job/queue compatibility.
;
;	This file is installation-specific, and should be tailored to
;	your own batch queue arrangement.
;
;	Inputs:
;		BATQ,BATQ+2	Radix-50 name of queue into which
;				submission is attempted.
;		TIMSUM		Sum of time limits for all sub-jobs
;				in minutes.
;		PSTAT		Unity if privileged.
;
;	Outputs:
;		Carry Clear:	Job is OK; submission can go ahead
;
;		Carry Set:	Job may not be entered into this queue
;
;
;	There are restrictions on the following queues:
;
;	BATCH	Up to 60 minutes in length.
;
;	SYSQ	Any length, privileged users only.
;
;	TAPEQ	Up to 30 minutes in length.
;
;
;	Steve Thompson, May 1983
;
;-

	.PSECT

QCHK::	CMP	#^RSYS,BATQ		; Queue=SYSQ?
	BNE	10$			; If NE no
	CMP	#^RQ  ,BATQ+2		; Maybe
	BEQ	100$			; If EQ yes

10$:	CMP	#^RBAT,BATQ		; Queue=BATCH?
	BNE	20$			; If NE no
	CMP	#^RCH ,BATQ+2		; Maybe
	BEQ	200$			; If EQ yes

20$:	CMP	#^RTAP,BATQ		; Queue=TAPEQ?
	BNE	30$			; If NE no
	CMP	#^REQ ,BATQ+2		; Maybe
	BEQ	300$			; If EQ yes

30$:	CLC				; Job is OK
	RTS	PC			;
40$:	SEC				; Job can't go in this queue
	RTS	PC			;

100$:	CMP	#1,PSTAT		; Privileged terminal?
	BEQ	30$			; If EQ yes, OK
	BR	40$			;

200$:	CMP	TIMSUM,#60.		; Time limit more than 1 hour?
	BGT	40$			; If GT, bad news on queue BATCH
	BR	30$			;

300$:	CMP	TIMSUM,#30.		; Time limit more than 30 minutes?
	BGT	40$			; If GT yes, bad news on TAPEQ
	BR	30$			;

	.END