.TITLE	USEOVR
	.IDENT	/V7.04/

;***************************************************************
;
; PROCESS A "USE" COMMAND REQUEST
;
;	THIS OVERLAY IS LOADED AND CALLED WHEN THE LOGGING TASK
;	DISPATCHER RECEIVES A REQUEST FROM ...USE FOR A "SHORT"
;	STATISTICS REQUEST. THESE STATISTICS ARE KEPT INTERNALLY
;	BY THE LOGGING TASK, AND ARE UPDATED BY ANOTHER OVERLAY
;	WHEN UPD... IS EXECUTED.
;
;
;		 N O T E   W E L L
;		 -----------------
;
;	THE CODE OF THIS ROUTINE ASSUMES MUCH ABOUT THE FORMAT OF
;	THE AC.USE TRANSACTIONS CONTROL BLOCK, AND ALSO THE LAYOUT
;	OF THE STORAGE ALLOCATIONS IN THE ROOT SEGMENT. SEE MACRO
;	ACCDF$ AND LOGROT.MAC FOR MORE DETAILS.
;
;
; VERSION:	V6	MAY 1979
; VERSION:	V7	JANUARY 1981
;
;	STEVE THOMPSON	SCHOOL OF CHEMICAL ENGINEERING
;			OLIN HALL
;			CORNELL UNIVERSITY
;			ITHACA NY 14853
;
;	REVISION HISTORY
;	----------------
;
;	SMT753	 7-OCT-81	CHANGED NAMES OF CONDITIONAL ASSEMBLY
;				PARAMETERS; SEE THE FILES MODIFY.TXT AND
;				CONDEF.MAC FOR DETAILS.
;
;	SMT762	 9-OCT-81	ADDED SUPPORT FOR BATCH V3 CALLS TO THE
;				"USE" COMMAND AND USE COMMAND DISPLAY OF
;				THE BATCH SYSTEM LOAD.
;
;	SMT850	24-MAY-83	ADDED B.INTU (INTERACTIVE CPU) FIELD
;
;***************************************************************

	.MCALL	GTIM$

$$$GBL=0		; THIS IS TO DEFINE GTIM$ OFFSETS LOCALLY

	GTIM$		; DEFINE GTIM$ OFFSETS LOCALLY

$USEEP::			; OVERLAY TRANSFER ADDRESS

	.IF DF	AA$USE ! AA$BAT

	MOV	B.STCB(R5),R0	; GET TCB ADDR. OF REQUESTING TASK
	MOV	#TIME,R1	; POINT R1 TO DATA IN ROOT SEGMENT
	MOV	R5,R2		; POINT R2 TO LOCATION TO RECEIVE DATA
	ADD	#B.ELAP,R2	;
	MOV	(R1)+,(R2)+	; TRANSFER TOTAL TIME
	MOV	(R1)+,(R2)+	;
	MOV	(R1)+,(R2)+	; TRANSFER EXECUTIVE TIME
	MOV	(R1)+,(R2)+	;
	MOV	(R1)+,(R2)+	; TRANSFER NULL TIME
	MOV	(R1)+,(R2)+	;

	.IF DF	AA$LDR

	MOV	(R1)+,(R2)+	; TRANSFER LOADER REQUESTS
	MOV	(R1)+,(R2)+	;
	CMP	(R1)+,(R1)+	; SKIP SYSTEM TOTAL LOADER REQUESTS

	.ENDC	; AA$LDR

	.IF DF	AA$QIO

	MOV	(R1)+,(R2)+	; TRANSFER I/O REQUESTS
	MOV	(R1)+,(R2)+	;
	CMP	(R1)+,(R1)+	; SKIP SYSTEM TOTAL I/O REQUESTS

	.ENDC	; DF AA$QIO

	.IF DF	AA$CSW

	MOV	(R1)+,(R2)+	; TRANSFER CONTEXT SWITCHES
	MOV	(R1)+,(R2)+	;
	CMP	(R1)+,(R1)+	; SKIP TOTAL CONTEXT SWITCHES

	.ENDC	; DF AA$CSW

	.IF DF	AA$BAT

	MOV	(R1)+,(R2)+	; TRANSFER BATCH CPU TIME
	MOV	(R1)+,(R2)+	;
	ADD	#<6*2>,R1	;

	.ENDC	; DF AA$BAT

	MOV	(R1)+,(R2)+	; TRANSFER INTERACTIVE CPU TIME
	MOV	(R1)+,(R2)+	;
;	ADD	#<6*2>,R1	;

	MOV	UPTIM+G.TIHR,(R2)+	; TRANSFER HOUR OF LAST UPDATE
	MOV	UPTIM+G.TIMI,(R2)+	; TRANSFER MINUTE OF LAST UPDATE
	MOV	UPNUM,(R2)+		; TRANSFER UPDATE NUMBER
	MOV	UPNUM+2,(R2)+		;
	CALL	$SWSTK,10$	; SWITCH TO SYSTEM STATE
	CALLR	$EXRQN		;; RESTART REQUESTING TASK

	.ENDC	; DF AA$USE ! AA$BAT

10$:	RETURN			;

	.END