.TITLE	LODFIL
.IDENT	\V02.03\

.SBTTL	COMMANDS		LOAD

;++
; FUNCTIONAL DESCRIPTION:
;	THIS COMMAND LOADS A PREVIOUSLY SAVED WORKSPACE
;--
	.PSECT	CODE

LOAD::
	MOV	#DFLTSV,R2		;THE DEFAULT BLOCK IS...
	CALL	GETNAM			;DECODE THE NAME
LOD1::
	BIS	#SY.SVL,SYSTAT		;SPECIAL SAVE/LOAD ACTIVITY
	CALL	FRESET			;RESET ALL Files
	MOV	#CHAN13,R2		;Reset UTILITY CHANNEL #1.
	CALL	RESCHN			;RESET THE CHANNEL
	MOV	#CHAN14,R2		;USE UTILITY CHANNEL #2.
	CALL	RESCHN			;RESET THE CHANNEL
	BIS	#C.NOBF,C.SBIT(R2)	;NO BUFFERS
    .IF GE RT11
	BIT	#ND.EXT,N.DESC(R4)	;CHECK WHETHER EXTENSION SPEC'D
	BNE	1$			;IT WAS
    .IFF
	TST	N.EXT(R4)		;Any Extension Specified?
	BNE	1$			;Not Yet
    .ENDC
    .IF NE RSX
	MOV	DFLTSV+N.EXT,N.EXT(R4)	;WASN'T
    .IFF
	MOV	DFLTSV,N.EXT(R4)	;Specify it Now
    .ENDC
1$:
    .IF GE RSTS
;
; Handle RSX and RT-11 )LOAD Commands
;
	CLR	R1			;Assume File exists
	CALL	OPNSET			;Open the file
	CALL	LODOVR			;Call in the LOAD overlay
	MOV	#CHAN00,OCHAN		;Point to Terminal
	QPRINT	SAVEDM			;PRINT "SAVED "
	CALL	DATIME			;SAVED MESSAGE
	CALLR	NEWLIN			;Print a <CR><LF> and Return
    .IFF

;+
; RSTS )LOAD Command
;+
	CALL	FIXNAM			;Fix the Name, in Typical RSTS Format
	.CHAIN				;CHAIN to the File
	CALL	RSTSER			;If it didn't work, then there must be
	.EXIT				;   an Error of some type
    .ENDC