.TITLE	SYSSET				
	.IDENT	/RICEX1/				
	.MCALL	GLUN$S
	.PSECT	SW.SYS,GBL,OVR,D			
SYSW:	.WORD	0,0,0,0,0,0,0,0, 0,0,0,0,0,0,0,0		
	.WORD	100.,100.,100.,100.,0.,0.,0.,0.
	.PSECT				
SYSSET::	MOV	#RUNNO,R5	; DISPLAY RUN #		
	CALL	PSET			; SET UP COLOR SCOPE		
	MOV	#SWITCH,R5		; DISPLAY SYSTEM,USER SWITCHES	
	CALL	PSET			; SET UP COLOR SCOPE		
	MOV	#C2.BHQ,R5		; GET INPUT HEADER
1$:	MOV	(R5),R5			; GET HEADER
	BEQ	5$			; NO HEADER
	MOV	R5,HEAD2		; ADDRESS OF HEADER
	ADD	#BH.CNT,HEAD2		; POINTS TO INPUT COUNT
	MOVB	BH.QIO+Q.IOLU(R5),R0	; POINTS TO LUN
	CALL	HEADER
	BR	1$
5$:	MOV	#C2.BOQ,R5		; GET OUTPUT QUE
6$:	MOV	(R5),R5			; GET OUTPUT HEADER
	BEQ	10$			; NONE
	MOV	R5,HEAD2		; HEADER
	ADD	#BO.OCT,HEAD2		; POINTS TO COUNTER
	MOVB	BO.OLN(R5),R0		; LUN
	CALL	HEADER
	BR	6$
10$:	MOV	#ANAL,R5		; DISPLAY ANALYZED BUFFS.
	CALL	PSET
	RETURN
HEADER:	GLUN$S	R0,#LBUF		; GET LUN INFO
	MOV	R5,-(SP)
	MOV	LBUF+2,R1		; UNIT NUMBER
	BIC	#177600,R1		; CLEAR EXTRA BITS
	CLR	R0
	DIV	#10,R0			; DIVIDE BY 10
	MOVB	R0,LBUF+2		; HI ORDER BYTE
	MOVB	R1,LBUF+3		; LOW ORDER BYTE
	ADD	#"00,LBUF+2		; CONVERT TO NUMBER
	MOV	#IOHEAD,R5		; SET UP TO DISPLAY
	CALL	PSET
	MOV	(SP)+,R5		; RESTORE
	RETURN
ANAL:	.BYTE	10.,0			; 10 PARAM IN LIST		
	.WORD	ERROR,ZERO,ZERO,N1,N1,C2.ACT,N2,AB,ZERO,ZERO	
RUNNO:	.BYTE	10.,0			; 10 PARAM IN LIST		
	.WORD	ERROR,ZERO,ZERO,ZERO,N1,C2.RUN,N1,RUNA,N8,ZERO	
SWITCH:	.BYTE	10.,0			; 10 PARAM IN LIST		
	.WORD	ERROR,N15,ZERO,ZERO,N1,SYSW,N24,SWA,N8,ZERO	
IOHEAD:	.BYTE	10.,0			; 10 PARAMIN LIST
	.WORD	ERROR,ZERO,ZERO,N1,N1
HEAD2:	.WORD	0,N1,LBUF,ZERO,ZERO
LBUF:	.BLKW	6
ZERO:	.WORD	0				
N1:	.WORD	1				
N2:	.WORD	2
N8:	.WORD	8.				
N15:	.WORD	15.				
N24:	.WORD	24.				
RUNA:	.ASCII	/RUN#/				
AB:	.ASCII	/AB'SMTER/
SWA:	.ASCII	/SYS0REWDSYS2SYS3ZEROSYS5SYS6SYS7/		
	.ASCII	/USW0USW1USW2USW3USW4USW5USW6USW7/		
	.ASCII	/DI#0DI#1DI#2DI#3DI$0DI$1DI$2DI$3/
ERROR:	.WORD	0				
	.END