; MACRO SUBROUTINE TO EXIT WITH STATUS
.LIST	MEB
;
; MAIN CALL
;	CALL "EXITST"(S)
;
; WHERE
;	"S" IS THE STATUS WORD TO BE RETURNED TO THE ISSUING TASK
;	IF "S" IS NOT PRESENT, A STATUS OF "WARNING" (0) WILL BE RETURNED
;
;	ALTHOUGH ANY STATUS CAN BE RETURNED, UNDER NORMAL CIRCUMSTANCES
;	(AS FOR USE WITH INDIRECT MCR,) ONE SHOULD RETURN ONE OF THE
;	FOLLOWING <DEC VALUES.
;
;	EX$SUC	=1		;SUCCESS !!!!
;	EX$WAR	=0		;MINOR ERRORS OCCURRED
;	EX$ERR	=2		;SEVERE-ERRORS OCCURRED
;	EX$SEV	=4		;PROGRAM FAILED
;
; IDENTIFYING INFO
	.MCALL	ULODHD	;CALL MACRO
				;IDENTIFY START OF CODE, END OF CODE
				;AND ONE ENTRY POINT
	ULODHD	EXITST,END,EXITST
;
AC0=%0
;
;
EXITST:				;LABLE ACTUAL START OF CODE
	JSR	R4,@#GTRGPI	;GO GET ARGUMENTS IN PI FASHION
	.BYTE	1,0		;ONE VALUE, (OUTPUT NUMERIC = STATUS)
	.EVEN
				;WE NOW HAVE THIS DATA ON THE STACK
				;SP>	STATUS TO RETURN (0 IF NONE SPEC'D)
	JSR	PC,@#PARCHK	;CHECK FOR TRAILING RIGHT PAREN
	SETI			;SET INTEGER MODE
	SETF			;NORMAL FLOATING
	LDF	(SP)+,AC0	;GET STATUS
	STCFI	AC0,R0		;CONVERT TO INTEGER
	MOV	R0,-(SP)	;PUSH STATUS
	MOV	(PC)+,-(SP)	;PUSH DIRECTIVE CODE AND LENGTH
	.BYTE	29.,2
	JSR	PC,@#CLSEAL	;CLOSE ALL FILES
	JSR	PC,@#DETACH	;DETACH THE TERMINAL
	EMT	377		;DO THE DIRECTIVE
	LODERR			;REPORT LOAD ERROR IF DIRECTIVE FAILS
END:	.END